Export Userform HTML

[rudymagny]

Bonjour le forum,
Voilà j'ai une petite question concernant l'export d'un USF en HTML.
J'avais eu un coup de main de MichelXLD sur le fait d'exporter une feuille au format html avec le code suivant:

ActiveWorkbook.PublishObjects.Add(xlSourceSheet, fichier, WSName, "", xlHtmlStatic, "", "").Publish

Mais est il possible de faire la même chose avec un USF, c'est dire quand on ouvre le fichier.html, on voit le userform avec les valeurs qui sont dans les textsbox.

??????

Merci d'avance

 

[rudymagny]

Re : Export Userform HTML

Re,
Après avoir cherché sur XLD et sur le net, j'ai pas trouvé d'infos, c'est que ça doit pas être possible?

Dommage ça m'aurais bien servi.

 

[Staple1600]

Re : Export Userform HTML

Bonsoir

Est-ce que le code ci-dessous correspond à ce que tu souhaites?

Source: Ivan F Moala

Groupes de discussion : microsoft.public.excel.programming
De : (Ivan F Moala)
Date : 23 Jul 2004 01:52:18 -0700
Local : Ven 23 juil 2004 10:52
Objet : Re: Saving Userform as Gif

Option Explicit
 
Private Declare Sub keybd_event Lib "user32" ( _
    ByVal bVk As Byte, _
    ByVal bScan As Byte, _
    ByVal dwFlags As Long, _
    ByVal dwExtraInfo As Long)
 
Private Const VK_LMENU = &HA4
Private Const VK_SNAPSHOT = &H2C
Private Const VK_CONTROL = &H11
Private Const VK_V = &H56
Private Const VK_0x79 = &H79
Private Const KEYEVENTF_EXTENDEDKEY = &H1
Private Const KEYEVENTF_KEYUP = &H2
 
Private Sub UserForm_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    Dim sAppOs As String
    Dim wks As Worksheet
    'get oparating system
    sAppOs = Application.OperatingSystem
 
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
 
    If Mid(sAppOs, 18, 2) = "NT" Then
    ' WinNT,Windows2000,WindowsXP - Using Win32API
        Call keybd_event(VK_LMENU, VK_V, KEYEVENTF_EXTENDEDKEY, 0)
        Call keybd_event(VK_SNAPSHOT, VK_0x79, KEYEVENTF_EXTENDEDKEY, _
0)
        Call keybd_event(VK_LMENU, VK_V, KEYEVENTF_EXTENDEDKEY Or _
KEYEVENTF_KEYUP, 0)
        Call keybd_event(VK_SNAPSHOT, VK_0x79, KEYEVENTF_EXTENDEDKEY _
Or KEYEVENTF_KEYUP, 0)
    Else
    ' Windows95,Windows98,WindowsME
        Call keybd_event(VK_SNAPSHOT, 0, KEYEVENTF_EXTENDEDKEY, 0)
        Call keybd_event(VK_SNAPSHOT, 0, KEYEVENTF_EXTENDEDKEY Or _
KEYEVENTF_KEYUP, 0)
    End If
    DoEvents
    Unload Me
    Set wks = Workbooks.Add.Sheets(1)
    Application.Goto wks.Range("A1")
    ActiveSheet.Paste
    wks.SaveAs Filename:="C:\myfile.htm", FileFormat:=xlHtml
    wks.Parent.Close False
 
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
    MsgBox "Have a look at C:\myfile.files folder."
End Sub

Trouvé sur le net

Ce lien n'existe plus


edit (houps mal lu ta question)

 

[rudymagny]

Re : Export Userform HTML

Bonsoir Staple1600, je regarde ça et je te tiens au courant

merci beaucoup

 

[Staple1600]

Re : Export Userform HTML

Re

J'ai testé avec XL2000 sous W98SE

Aucun problème ca fonctionne

Voir fichier joint

 

[rudymagny]

Re : Export Userform HTML

Re, Staple 1600,
J'allais poster pour ton post d'avant avec l'exemple que tu as trouvé sur le net mais cela ne fait (en moins bien) que reproduire le code que m'a donné MichelXLD;

Mais alors là ton dernier post, excuse moi du terme mais c'est de la balle!!!
Il faut que je le test dans ma conf et mon appli mais franchement bravo et merci !
Je te tiens au courant sur son fonctionnement chez moi.

MERCI

 

[rudymagny]

Re : Export Userform HTML

Bonjour Staple1600,
Bon bah nickel, ça marche impec chez moi!
Je te remercie, à plus tard