recherchev sur 2 colonnes: est ce possible?

[andreaG]

Bonjour à tous
J'aimerai savoir s'il est possible de faire une recherche sur 2 colonnes
sans passer par la fonction concatener
Ci joins mon fichier exemple
Un grand merci au forum pour toute l'aide apportée

 

[Monique]

Re : recherchev sur 2 colonnes: est ce possible?

Bonjour,

Avec ou sans doublons
Index Equiv ou SommeProd

Index Equiv dans ce cas : formule matricielle, à valider pat ctrl, maj et entrée

 

[andreaG]

Re : recherchev sur 2 colonnes: est ce possible?

Bonjour Monique et merci pour ta réponse
Hélas j'ai beau essayé tes 3 solutions dns tous les sens, j'obtiens #nombre pour les 2 premieres et une cellule vide pour la formule "sans doublon"
En faite je ne connais pas du tout les fonctions sommeprod, equiv.......
Peux tu me les expliquer pour cet exemple (si c'est possible)
Un grand merci encore une fois.
AndreaG

 

[Monique]

Re : recherchev sur 2 colonnes: est ce possible?

Bonjour,

Pour les 2 premières
On obtient #N/A si les plages de la formule SommeProd ne sont pas de la même longueur
=INDEX('2009'!$L$1:$L$20;SOMMEPROD(('2009'!B$2:B$10=B2)*('2009'!C$2:C$20=C2)*(LIGNE('2009'!L$2:L$20))))&""

On obtient #NOMBRE! Si on demande à la formule de prendre en compte des colonnes entières
=INDEX('2009'!L:L;SOMMEPROD(('2009'!B:B=B2)*('2009'!D: D=C2)*(LIGNE('2009'!L:L))))&""

Pour la 3ème, on obtient une cellule vide si on valide simplement par "Entrée"
C'est une formule matricielle, elle est à valider
en appuyant simultanément sur ctrl, maj et entrée

Le fonctionnement de SommeProd... si c'est possible, comme tu dis
Sur 4 lignes seulement pour que ce soit lisible
=SOMMEPROD(('2009'!B$2:B$5=B2)*('2009'!C$2:C$5=C2)*(LIGNE('2009'!L$2:L$5)))

On sélectionne la formule par petits bouts dans la barre de formule et on appuie sur F9 :
=SOMMEPROD(({VRAI;FAUX;FAUX;FAUX})*({VRAI;FAUX;FAUX;FAUX})*(LIGNE('2009'!L$2:L$5)))

=SOMMEPROD(({VRAI;FAUX;FAUX;FAUX})*({VRAI;FAUX;FAUX;FAUX})*({2;3;4;5}))

=SOMMEPROD({1;0;0;0}*({2;3;4;5}))

=SOMMEPROD({2;0;0;0})

=2

=INDEX('2009'!$L$1:$L$5;2) ---> bbbbb c’est à dire le contenu de la 2ème ligne de la plage L1:L5

 

[andreaG]

Re : recherchev sur 2 colonnes: est ce possible?

Bonjour Monique
ça y est apres plusieurs essais et ajustements et grace à tes dernieres explications c'est bon
un grand merci encore
AndreaG