recherchev sur plusieurs onglets

[vincent50]

Bonjour le forum, voila j'aimerai realiser un fichier de classement, tout est expliqué dans le fichier joint
merci

 

[JNP]

Re : recherchev sur plusieurs onglets

Bonjour Vincent50 🙂,
Une solution en SOMMEPROD.
Bon dimanche 😎

 

[ROGER2327]

Re : recherchev sur plusieurs onglets

Bonjour à tous

Essayez :

[COLOR="DarkSlateGray"][B]Formule supprimée. Voir le message #6.[/B][/COLOR]

en C2 de la feuille classement.
(Formule matricielle : validez par Ctrl + Maj + Entrée.)​

ROGER2327
#3006

 

[Tibo]

Re : recherchev sur plusieurs onglets

Bonjour,

Un essai en C2 avec une formule adaptée du site de Jacques Boisgontier Formation Excel VBA JB :

=SOMMEPROD(SOMME.SI(INDIRECT("'"&{"finale C";"finale B";"finale A"}&"'!A2:A10");
A2;INDIRECT("'"&{"finale C";"finale B";"finale A"}&"'!C2:C10")))

Je te laisse tester

@+

Edit : Bing ! Bonjour Roger, Bon dimanche à toi

@+

 

[BOISGONTIER]

Re : recherchev sur plusieurs onglets

Bonsoir,

=SOMMEPROD(SOMME.SI(INDIRECT("'finale "&{"A";"B";"C"}&"'!b2:b6");B2;INDIRECT("'finale "&{"A";"B";"C"}&"'!c2:c6")))

Pour Finale A,Finale B,....,Finale X

=SOMMEPROD(SOMME.SI(INDIRECT("'finale "&CAR(LIGNE($65:$67))&"'!b2:b6");B2;INDIRECT("'finale "&CAR(LIGNE($65:$67))&"'!c2:c6")))

JB

 

[ROGER2327]

Re : recherchev sur plusieurs onglets

Bonsoir à tous

Une erreur dans la formule que je donnai dans le message #3...
Il fallait lire :

[COLOR="DarkSlateGray"][B]=MAX(('finale A'!B$2:B$10=B2)*'finale A'!C$2:C$10[COLOR="Red"];[/COLOR]('finale B'!B$2:B$10=B2)*'finale B'!C$2:C$10[COLOR="Red"];[/COLOR]('finale C'!B$2:B$10=B2)*'finale C'!C$2:C$10)[/B][/COLOR]

en C2 de la feuille classement.
(Formule matricielle : validez par Ctrl + Maj + Entrée.)

Le résultat obtenu est différent de ceux obtenus avec les autres formules proposées : nous n'avons pas tous interprété les renseignements de la même façon. À vincent50 de dire ce qu'il en pense...​

ROGER2327
#3012

 

[vincent50]

Re : recherchev sur plusieurs onglets

jnp, ta solution est exactement ce que je recherche,
tibo et boisgontier, votre solution est bonne aussi sauf que je ne veux pas que les résultats d'un même concurrent s'additionne mais se remplace.
roger 2327, c'est presque ca sauf que ca ne prend pas en compteles finale b et c hors je veux que toutes soient prise en compte.
merci de votre aide.
vincent

 

[BOISGONTIER]

Re : recherchev sur plusieurs onglets

Bonjour,

=RECHERCHEV(B2;INDIRECT("'finale "&CAR(64+EQUIV(VRAI;(NB.SI(INDIRECT("'finale "&{"A";"B";"C"}&"'!b2:b6");B2)>0);0))&"'!b2:c6");2;FAUX)
Valider avec maj+ctrl+entrée

ou

Si finale A, finale B,..., finale X

=RECHERCHEV(B2;INDIRECT("'finale "&CAR(64+EQUIV(VRAI;(NB.SI(INDIRECT("'finale "&CAR(LIGNE($65:$67))&"'!b2:b6");B2)>0);0))&"'!b2:c6");2;FAUX)
Valider avec maj+ctrl+entrée

ou

=RECHERCHEV(A2;INDIRECT(INDEX("'"&nf;EQUIV(VRAI;(NB.SI(INDIRECT("'"&nf&"'!a2:a6");A2)>0);0))&"'!a2:b6");2;FAUX)
Valider avec maj+ctrl+entrée

nf contient les noms des onglets



JB

 

[ROGER2327]

Re : recherchev sur plusieurs onglets

Re...

(...)
roger 2327, c'est presque ca sauf que ca ne prend pas en compteles finale b et c hors je veux que toutes soient prise en compte.
(...)
vincent

Dommage !

À tout hasard, je répète la fin de mon message :

(Formule matricielle : validez par Ctrl + Maj + Entrée.)

ROGER2327
#3015

 

[vincent50]

Re : recherchev sur plusieurs onglets

non roger2327, ca ne marche pas
boisgontier, j'essaie ce soir et je vous tiens au courant

 

[vincent50]

Re : recherchev sur plusieurs onglets

ca marche super boisgontier,
encore merci de votre aide