RechercheV MULTICritères

[pdelattre]

Bonjour à tous,

Sujet maintes et maintes fois évoqué, à tel point que je n'arrive pas à trouver réponse à ma question.

J'ai un tableau d'utilisateur appartenant à une équipe entre une date de début et une date de fin :
Prénom Equipe Date-début date-Fin
Pierre Equipe1 01/01/2012 15/01/2012
Pierre Equipe2 16/01/2012 31/12/2012


Je cherche l'équivalent d'un recherchev multicritères pour pouvoir ramener le nom de l'équipe correspondant à une date pour Pierre

Ci-après l'exemple : Regarde la pièce jointe Exemple.xlsx


Merci d'avance pour votre aide !

Pierre

 

[tototiti2008]

Re : RechercheV MULTICritères

Bonjour pdelattre,

en I7

=INDEX($B$2:$B$4;EQUIV(SOMMEPROD(($C$2:$C$4<=H7)*($D$2:$D$4>=H7)*($A$2:$A$4=G7)*$C$2:$C$4);$C$2:$C$4;0))

à recopier vers le bas

 

[Tibo]

Re : RechercheV MULTICritères

Bonjour,

Un essai avec une formule matricielle en I7 :

=INDIRECT(ADRESSE(SOMME(($C$2:$C$4<=H7)*($D$2:$D$4>=H7)*($A$2:$A$4=G7)*LIGNE($A$2:$A$4));2))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

N'oublie pas de remettre ton fichier en calcul automatique.

@+

Edit : Salut Marc, content de te croiser sur ce post. Bonne journée à toi 🙂

@+

Edit 2 : Belle rencontre ! Salut Jean-Noël 🙂

@+

Edit 3 : ça se bouscule 😉 ! Salut Rachid

@+

 

[JNP]

Re : RechercheV MULTICritères

Bonjour Pdelattre, salut Marc et Tibo 🙂,
Une autre matricielle :

=INDEX($B$1:$B$4;PETITE.VALEUR(SI(H7>=$C$1:$C$4;SI(H7<=$D$1:$D$4;LIGNE($B$1:$B$4)));1))

Bonne journée 😎

 

[R@chid]

Re : RechercheV MULTICritères

Salut,
en I7 :

=INDEX($B$2:$B$4;PETITE.VALEUR(SI(($A$2:$A$4=G7)*($C$2:$C$4<=H7)*($D$2:$D$4>=H7);LIGNE(INDIRECT("1:"&LIGNES($B$2:$B$4))));1))

@ valider en matricielle par Ctrl+maj+Entree
@ recopier vers le bas
@ + +

Edit : Salut JNP

 

[pdelattre]

Re : RechercheV MULTICritères

Merci mais cela ne fonctionne pas...

ci-joint un contre exemple : Regarde la pièce jointe 839733

Bonjour pdelattre,

en I7

=INDEX($B$2:$B$4;EQUIV(SOMMEPROD(($C$2:$C$4<=H7)*($D$2:$D$4>=H7)*($A$2:$A$4=G7)*$C$2:$C$4);$C$2:$C$4;0))

à recopier vers le bas

Edit : Désiolé plein de réponse entre temps, je regarde vos réponses et vous dfit... merci les gars !

 

[tototiti2008]

Re : RechercheV MULTICritères

Bonjour à tous 😉

Oui, les autres propositions devraient marcher 🙂

 

[JNP]

Re : RechercheV MULTICritères

Re 🙂,
Non, pas la mienne, j'avais oublié le prénom 😱...

=SIERREUR(INDEX($B$1:$B$5;PETITE.VALEUR(SI(H7>=$C$1:$C$5;SI(H7<=$D$1:$D$5;SI($A$1:$A$5=G7;LIGNE($B$1:$B$5))));1));"")

toujours en matriciel sera mieux 😛...
Bonne suite 😎

 

[pdelattre]

Re : RechercheV MULTICritères

j'ai pris celle de Tibo, ça marche Nickel !!! Merci à vous !!!
Pierre