Re,
Ecrire 'ext' ou 'dom' en A1 revient exactement au même,
le seul avantage, c'est que les formules des 2 feuilles sont exactement identiques.
Mais ça ne vaut le coup que quand on a un peu plus de 2 feuilles, quand même.
=STXT(CELLULE('filename';A1);TROUVE(']';CELLULE('filename';A1))+1;32)
Il y a déjà eu des posts à ce sujet, sur le forum.
C'est une formule d'extraction du nom de l'onglet
Chemin complet :
=CELLULE('filename';A1)
Répertoire :
=GAUCHE(CELLULE('filename';A1);TROUVE('[';CELLULE('filename';A1))-2)
Nom du classeur :
=STXT(CELLULE('filename';A1);TROUVE('[';CELLULE('filename';A1))+1;SOMME(TROUVE({'[';']'};CELLULE('filename';A1))*{-1;1})-1)
Nom de la feuille : (32 = nb max ce caractères dans le nom d'une feuille)
=STXT(CELLULE('filename';A1);TROUVE(']';CELLULE('filename';A1))+1;32)
Répertoire + classeur :
=SUBSTITUE(GAUCHE(CELLULE('filename';A1);TROUVE(']';CELLULE('filename';A1))-1);'[';'')
Nom du classeur et de la feuille :
=STXT(CELLULE('filename';A1);TROUVE('[';CELLULE('filename';A1));300)
Pour que ces formules fonctionnent, le classeur doit être enregistré.
La formule matricielle Petite.Valeur(Si(
Petite.Valeur(A1:A10;1) te renvoie la 1ère petite valeur
Petite.Valeur(A1:A10;2) te renvoie la 2ème petite valeur
Etc…
Si on remplace 1, 2 et la suite par la fonction Lignes(), on n'a pas besoin de modifier l'argument à chaque formule, il suffit de copier-coller
Lignes(A$1:A1) renvoie 1
Lignes(A$1:A2) renvoie 2
A la fonction Petite.Valeur(plage;n°), on peut mettre une condition de critère à respecter dans une autre plage
Petite.Valeur(si(G1:G10=100;A1:A10);1)
Cette formule renverra la plus petite valeur de la plage A1:A10 si, dans la colonne G, sur la même ligne, il y a un 100
Elle fait un 'pré-tri' entre les lignes qui contiennent ou non 100 en colonne G,
et ne renvoie que la plus petite valeur de la colonne A,
puis la 2ème plus petite valeur, etc… que s'il y a un 100 en colonne G.