Requête pour choisir la bonne formule

[iso29]

Bonjour à tous,

Je viens vers vous une dernière fois, pour la création d'une formule qui ferait la part des choses. A savoir détecter 2 lettres a et m de la colonne J dans le fichier ci-joint. Si te lest le cas, je voudrais que cela affiche " trot" en cellule i1 (juste en face de spécialité). Après je peux me débrouiller pour le choix de la formule à appliquer.

Merci pour votre aide

 

[JCGL]

Re : Requête pour choisir la bonne formule

Bonjour à tous,

Peux-tu essayer avec :

=SI(TROUVE("a";J5:J20;1);"trot";"")

A valider par Ctrl Shift Enter

A+ à tous

 

[vbacrumble]

Re : Requête pour choisir la bonne formule

Bonsoir


Voir la pièce jointe

 

[ROGER2327]

Re : Requête pour choisir la bonne formule

Bonsoir

Pas sûr d'avoir bien compris la demande, mais, sans colonne supplémentaire, peut être ça ?

=SI(SOMME(1*(ESTERR(CHERCHE("a";$J$5:$J$20))+ESTERR(CHERCHE("m";$J$5:$J$20))=2));"";"trot")

(Formule matricielle)​

ROGER2327

 

[iso29]

Re : Requête pour choisir la bonne formule

Bonjour à tous,

Merci pour les formules.

Je teste.

Il y a des colonnes supplémentaires, mais je sais faire les modifications.

Merci à vous tous.

 

[ROGER2327]

Re : Requête pour choisir la bonne formule

Re...

(...) Il y a des colonnes supplémentaires (...)

Pas nécessairement. Voir :

Bonsoir

(...) sans colonne supplémentaire, peut être ça ?

=SI(SOMME(1*(ESTERR(CHERCHE("a";$J$5:$J$20))+ESTERR(CHERCHE("m";$J$5:$J$20))=2));"";"trot")

(Formule matricielle) (...)​

ROGER2327

 

[iso29]

Re : Requête pour choisir la bonne formule

Re-bonjour à tous,

je reviens à nouveau à vous, mais les formules laissées ne fonctionnent pas comme je le souhaite.

J'ai modifier pour la cellule A2
si trouve Attelé affiche trot (ça c'est bon!) mais je n'arrive pas à rajouter Monté qui est aussi du trot. j'ai un message d'erreur en retour.

Est-il possible que l'un d'entre vous me corrige? Merci
J'avais commencé comme ceci:
SI(TROUVE("Attelé";A2:A2;1);"trot";"")

Le bout de fichier est plus haut (attelé seulement), il faut rajouter si trouve monté d'afficher trot en i1.

Merci à vous tous

iso

 

[ROGER2327]

Re : Requête pour choisir la bonne formule

Re...

J'avais lu :

Bonjour à tous,

Je viens vers vous une dernière fois, pour la création d'une formule qui ferait la part des choses. A savoir détecter 2 lettres a et m de la colonne J dans le fichier ci-joint. Si te lest le cas, je voudrais que cela affiche " trot" en cellule i1 (juste en face de spécialité). Après je peux me débrouiller pour le choix de la formule à appliquer.

Merci pour votre aide

Je lis maintenant :

(...) J'ai modifier pour la cellule A2
si trouve Attelé affiche trot (ça c'est bon!) mais je n'arrive pas à rajouter Monté qui est aussi du trot. j'ai un message d'erreur en retour.

Est-il possible que l'un d'entre vous me corrige? Merci
J'avais commencé comme ceci:
SI(TROUVE("Attelé";A2:A2;1);"trot";"")

Le bout de fichier est plus haut (attelé seulement), il faut rajouter si trouve monté d'afficher trot en i1. (...)
iso

Pas clair !
S'agit-il de faire une recherche dans la colonne J comme le dit la première demande ?
Ou bien de chercher quelque chose dans la cellule A2 ?
Posons la question autrement : quel rapport y-a-t-il entre vos deux demandes ?
On veut bien chercher, mais il faut nous dire clairement ce qu'il faut chercher !​

ROGER2327

 

[JCGL]

Re : Requête pour choisir la bonne formule

Bonjour à tous,

je reviens à nouveau à vous, mais les formules laissées ne fonctionnent pas comme je le souhaite.

Avais-tu pensé à valider par Crtl Shift Enter ?

Un essai avec ton fichier pour "a" ou "m" en colonne J

A+ à tous

 

[iso29]

Re : Requête pour choisir la bonne formule

Bonjour à tous,

Pour Roger,
il s'agit d'arriver au même point. Mais je pense que rechercher les mots "Attelé" et "Monté" en cellule A2 donnera moins ou aucune erreur au résultat souhaité qui est l'affichage du mot "trot". Il y a des colonnes supplémentaires, mais je saurais faire la sélection de la formule souhaité . Je coince juste sur l'objet de ma demande, à savoir l'affichage trot lorsque les mots Attelé et Monté sont rencontré en cellule A2.

Merci Roger pour ta contribution en tout cas.

Pour JCGL,
Merci pour cette précision, dont je ne me souvenais plus. Je n'utilise pas les formules matricielles, comme je ne sais pas les créer moi-même. C'est peut-être pour cela que je bloque sur certaines création de formules.

Merci JCGL pour ta contribution

Si l'on peut se concentrer sur la cellule A2, je préférerais et cela évitera des erreurs. C'est fichier d'automatisation pour un futur site, et elle est capitale pour la suite. J'en dirais plus quand tout sera terminé.

Merci à vous tous pour votre contribution.

Iso

 

[Monique]

Re : Requête pour choisir la bonne formule

Bonjour,

On va y arriver ?

Et "a" et "m" dans la même cellule
=SOMMEPROD(ESTNUM(TROUVE("a";$J$5:$J$20)*TROUVE("m";$J$5:$J$20))*1)>0

Soit "a" soit "m" dans la même cellule
=SOMMEPROD(ESTNUM(TROUVE({"a"."m"};$J$5:$J$20))*1)>0
(à valider par "Entrée" seulement)

 

[iso29]

Re : Requête pour choisir la bonne formule

Re-Bonjour à tous,

Bonjour Monique,
Et merci. Je vais tester......

A plus tard

iso

 

[Monique]

Re : Requête pour choisir la bonne formule

Re,

Si on ne tient compte que de A2

Contient 1 des 2 mots
=ESTNUM(TROUVE({"Attelé";"Monté"};A2))

Contient les 2 mots
=ESTNUM(TROUVE("Attelé";$A$2)*TROUVE("Monté";$A$2))

(renvoient VRAI ou FAUX)

 

[iso29]

Re : Requête pour choisir la bonne formule

Re,

Si on ne tient compte que de A2

Contient 1 des 2 mots
=ESTNUM(TROUVE({"Attelé";"Monté"};A2))

Contient les 2 mots
=ESTNUM(TROUVE("Attelé";$A$2)*TROUVE("Monté";$A$2))

(renvoient VRAI ou FAUX)

Re-bonjour Monique,
Les formules précédentes donnent également Vrai ou faux. En tout cas, ça me va. Pas de soucis là dessus.

Je croyais arriver à faire changer la formule souhaité, mais j'ai message d'erreur au final.

Si c'est vrai, la formule est la suivante:
STXT(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($J5;"(07)";"");"Ra ";"");"(08) ";"");"Deb";"");"A";"0");"T";"0");"G";"D");(COLONNE()-10)*3-2;1)

Et si c'est faux, la formule doit être:
STXT(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($J5;"(07)";"");"Ra ";"");"(08)";"");"Deb";"");"A";"0");"T";"0");"G";"D");(COLONNE()-10)*3-2;1)

qui décomposent la colonne J en colonne K et suivantes pour des calculs statistiques.

C'est l'espace qui se trouve après (08) qu'il n'y a pas dans les autres spécialités. d'ou l'importance du "a" pour attelé et du "m" pour Monté qui sont des courses de trot.

Voilà!

Merci à vous tous de m'enlever cette épine.

iso

 

[Monique]

Re : Requête pour choisir la bonne formule

Re, tous,

En admettant que "trot" soit (ou non) en F1
=STXT(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE($J5;"(07)";"");"Ra ";"");SI($F$1="trot";"(08) ";"(08)");"");"Deb";"");"A";"0");"T";"0");"G";"D");(COLONNE()-10)*3-2;1)

Mais on peut faire plus court
Substituer "(08)" ou "(08) " par rien et extraire de ce qui reste 1 caractère sur 3
à essayer en K11 et suite :
=STXT(SUBSTITUE($J11;SI($F$1="trot";"(08) ";"(08)");"");(COLONNES($K11:K11)-1)*3+1;1)

A la place de la fonction Colonne() qui embête bien quand on insère ou supprime une colonne (il vaut mieux utiliser Colonnes()),
on peut saisir 1, 4, 7, 11, etc en ligne 4
à essayer en K16 et suite :
=STXT(SUBSTITUE($J16;SI($F$1="trot";"(08) ";"(08)");"");K$4;1)

Et au lieu de saisir 1, 4, etc en ligne 4,
en K4 :
=(COLONNES($R4:R4)-1)*3+1