Renvoyer adresse de cellule

[Calvus]

Bonsoir le forum,

Je cherche à récupérer l'adresse d'une cellule dans un tableau, mais je ne m'en sors pas.

J'ai bien trouvé ce post qui semblait le plus près de ce que je souhaite, mais je n'arrive pas à l'adapter, évidemment sans comprendre pourquoi. Il doit me manquer l'argument colonne, mais je sèche.

Voici ce que j'ai trouvé.

https://www.excel-downloads.com/threads/trouver-coordonnees-dune-cellule.142852/

Merci

 

[Tibo]

Re : Renvoyer adresse de cellule

Bonjour Calvus,

La fonction ADRESSE devrait effectivement correspondre à ta demande.

Un petit bout de fichier exemple avec la cellule dont il faut déterminer l'adresse (avec le pourquoi du comment) serait le bienvenu.

A te (re)lire

@+

 

[Calvus]

Re : Renvoyer adresse de cellule

Bonjour Tibo,

J'ai un petit problème ( si c'était le seul...)
Voulant envoyer le fichier comme tu me l'as demandé, voyant qu'il était trop gros (4500 ko), j'ai supprimé des feuilles (une vingtaine ) pour n'en garder que 4.
Toujours trop gros !
J'ai supprimé tout un tas de formules, les mises en forme etc etc, enregistré plusieurs fois sous des nom différents, et je n'arrive pas à descendre en dessous de 4300 ko !
Impossible donc d'envoyer l'exemple.
Inutile de préciser que j'ai d'autres fichiers, nettement plus conséquents, et qui n'arrivent qu'à 500 ko.
Je ne comprends pas !
Une idée ?
Merci

 

[Tibo]

Re : Renvoyer adresse de cellule

re,

Peut-être y-a-t-il des objets (images) sur ton fichier.

Sinon, voir pour copier tes données dans un fichier tout neuf, ça permet parfois de tout remettre en place.

Sinon, pour les fichiers importants, tu peux passer par le site cijoint.fr

A te (re)lire

@+

 

[Calvus]

Re : Renvoyer adresse de cellule

Non, pas d'images, peu de choses.
J'avais bien essayé dans un nouveau classeur, même résultat.
Je ne comprends pas !

En attendant, voici un bout du fichier sur ci-joint.

Le classeur original comporte évidemment plus de feuilles.

La fonction recherche d'excel m'aurait convenu, mais elle ne marche pas puisqu'il il y a des formules.

Les explications sont sur la feuille, sachant que j'aimerais pouvoir tirer la formule recherchée vers le bas pour pouvoir afficher plusieurs résultats. Eh oui, ça se complique !

D'autre part, j'aimerais pouvoir entrer seulement une partie deu nom que je recherche, soit avec " xx* " ou encore " *xx* "

Merci

Cijoint.fr - Service gratuit de dépôt de fichiers

 

[hbenalia]

Re : Renvoyer adresse de cellule

Bonjour à tous,

Pour cela il suffit de nous donner les critères de la recherche de l'adresse de la cellule en question et la plage de recherche...


Cordialement

 

[Tibo]

Re : Renvoyer adresse de cellule

re,

En ce qui concerne la taille de ton fichier, tout semble se passer sur ton onglet Index

En faisant CTRL FIN, on arrive à la dernière cellule reconnue par Excel. Sur ton fichier, ça amène à la ligne 65536 !!!

Solution : Sélectionner la ligne 50, puis CTRL SHIFT FIN pour sélectionner jusqu'en bas, puis CTRL -

les cellules des colonnes A à D retrouvent leur couleur.

Et le fichier passe à 70 ko.

Zippé, il pouvait passer sur le Forum.

Le problème semble être lié à un souci de format, mais pas compris lequel.

Cela dit, pour revenir au centre du débat, je n'ai pas vraiment compris ce que tu voulais obtenir.

Un fichier avec exemple manuel du résultat attendu serait le bienvenu.

@+

 

[Calvus]

Re : Renvoyer adresse de cellule

Re,

En l'occurence, dans cet exemple la recherche se fait sans le tableau, à savoir : A9: D32

Les critères peuvent être n'importe quoi. Par exemple supposons que je veuille savoir dans quelle boite se trouve la 1ère Ballade de Chopin, en entrant ballade ou encore bal*, excel va me renvoyer "cellule T24", qui me permettra de regarder en début de colonne que ma Ballade est dans la boite 17.

Merci

 

[Calvus]

Re : Renvoyer adresse de cellule

Merci Tibo,

Je viens de répondre à hbenalia. Ces explications sont elles suffisantes ou veux tu que je renvoie.

Cordialement.

 

[Tibo]

Re : Renvoyer adresse de cellule

re,

Un premier jet avec une formule matricielle en A41 :

=SI(LIGNES($1:1)>SOMME(ESTNUM(CHERCHE(A$39;$A$9:$D$32))*1);"";"Boîte "&
PETITE.VALEUR(SI(ESTNUM(CHERCHE(A$39;$A$9:$D$32));ESTNUM(CHERCHE(A$39;$A$9:$D$32))
*COLONNE($A$1:$D$1));LIGNES($1:1))&" : "&INDEX($A$1:$D$32;MOD(PETITE.VALEUR(
SI(ESTNUM(CHERCHE(A$39;$A$9:$D$32));ESTNUM(CHERCHE(A$39;$A$9:$D$32))
*COLONNE($A$1:$D$1)+(ESTNUM(CHERCHE(A$39;$A$9:$D$32))*LIGNE($A$9:$A$32))/100);
LIGNES($1:1));1)*100;PETITE.VALEUR(SI(ESTNUM(CHERCHE(A$39;$A$9:
$D$32));ESTNUM(CHERCHE(A$39;$A$9:$D$32))*COLONNE($A$1:$D$1));
LIGNES($1:1))))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

Je joins le fichier

@+

 

[Calvus]

Re : Renvoyer adresse de cellule

Tibo, t'es trop fort !!

Et comme on pourrait l'entendre dans la vérité si je mens, en plus " Tiébeau !"

MERCI !

Je vais tenter d'adapter tout ça, ça ne devrait pas être trop compliquer.
Et en plus, je peux même faire une recherche sur une partie du nom seulement. Génial !

Je reviendrai vers toi si j'ai des soucis.

Merci encore. 🙂

 

[david84]

Re : Renvoyer adresse de cellule

Bonjour,
une variante de la formule proposée par Tibo que je salue et félicite au passage :
=SI(LIGNES($1:1)<=SOMMEPROD((N($A$9:$D$32<>"")*(ESTNUM(CHERCHE($A$39;$A$9:$D$32)))));"Boîte "&PETITE.VALEUR(SI(ESTNUM(CHERCHE(A$39;$A$9:$D$32));ESTNUM(CHERCHE(A$39;$A$9:$D$32))*COLONNE($A$1:$D$39));LIGNES($1:1))&" : "&INDIRECT(ADRESSE(PETITE.VALEUR(SI(ESTNUM(CHERCHE($A$39;$A$9:$D$32));LIGNE($A$9:$D$32));LIGNES($1:1));MOD(PETITE.VALEUR(SI(ESTNUM(CHERCHE($A$39;$A$9:$D$32));LIGNE($A$9:$D$32)+ESTNUM(CHERCHE($A$39;$A$9:$D$32))*COLONNE($A$9:$D$32)/100);LIGNES($1:1));1)*100));"")
Formule matricielle à valider par ctrl, maj et entrée
A+

 

[Calvus]

Re : Renvoyer adresse de cellule

Hello David,

Merci pour ton intervention.

Vu qu'à ce stade il serait plus facile pour moi de traduire du chinois vers du biélo-russe, en soulignant les nuances de la poésie byzantine inspirée de l'empire autro-hongrois pré-colombien, que de comprendre ces formules excel, pourrais tu me dire, ou Tibo évidemment s'il en a encore la patience, comment apdapter ça à mon fichier, qui comprend beaucoup plus de feuilles.
Quels sont les champs que je dois étirer ?

J' essaye depuis tout à l'heure, mais la formule me renvoie inéxorablement la boite 3, alors qu'elle devrait afficher un autre numéro.

Par ailleurs, que dois-je modifier dans la formule pour pouvoir afficher d'autres noms que les boites. Le titre peut aussi être carton ou tiroir...

Espérant être assez clair.

Merci

 

[Calvus]

Re : Renvoyer adresse de cellule

J'ai résolu le premier problème, j'avais 2 feuilles avant la feuille " Boite 1", ce qui posait problème au niveau de l'index.

Me reste à voir comment je peux ajouter des noms autres que boite.

merci

@+

 

[Tibo]

Re : Renvoyer adresse de cellule

re,

Pour gérer l'ajout d'onglets, je te propose ceci :

Nommer tablo :
Fait référence à :

=DECALER(Index!$A$9;0;0;24;NBVAL(Index!$2:$2))

Ensuite, une deuxième version de la formule proposée un peu plus haut, qui gère les boîtes, les paquets ou tout autre nom que tu donneras à tes onglets :

en A41 :

=SI(LIGNES($1:1)>SOMME(ESTNUM(CHERCHE(A$39;tablo))*1);"";INDEX($A$2:$D$2;
PETITE.VALEUR(SI(ESTNUM(CHERCHE(A$39;tablo));ESTNUM(CHERCHE(A$39;tablo))*
COLONNE($A$1:$D$1));LIGNES($1:1)))&" : "&INDEX(DECALER($A$1;0;0;24;NBVAL($2:$2))
;MOD(PETITE.VALEUR(SI(ESTNUM(CHERCHE(A$39;tablo));ESTNUM(CHERCHE(A$39;tablo))*
COLONNE($A$1:$D$1)+(ESTNUM(CHERCHE(A$39;tablo))*LIGNE($A$9:$A$32))/100);
LIGNES($1:1));1)*100;PETITE.VALEUR(SI(ESTNUM(CHERCHE(A$39;tablo));ESTNUM(
CHERCHE(A$39;tablo))*COLONNE($A$1:$D$1));LIGNES($1:1))))

Toujours matricielle, donc validation par CTRL + MAJ + ENTREE

à recopier vers le bas

Je te laisse tester


@+

Edit : en nommant plus finement des formules :

Nommer test_présence
Fait référence à :

=ESTNUM(CHERCHE(Index!A$39;DECALER(Index!$A$9;0;0;24;NBVAL(Index!$2:$2))))

On peut raccourcir la formule ainsi :

=SI(LIGNES($1:1)>SOMME(test_présence*1);"";INDEX($A$2:$D$2;PETITE.VALEUR(SI(
test_présence;ESTNUM(CHERCHE(A$39;tablo))*COLONNE($A$1:$D$1));LIGNES($1:1)))&
" : "&INDEX(DECALER($A$1;0;0;24;NBVAL($2:$2));MOD(PETITE.VALEUR(SI(
test_présence;test_présence*COLONNE($A$1:$D$1)+(test_présence*LIGNE($A$9:$A$32))
/100);LIGNES($1:1));1)*100;PETITE.VALEUR(SI(test_présence;test_présence*
COLONNE($A$1:$D$1));LIGNES($1:1))))

Voilou

@+