RechercheV x3

[Wyrda]

Bonjour,

Pardonnez-moi d'avance si le sujet a déjà été fait, j'ai cherché et n'ai pas trouvé mon bonheur, mais je l'ai peut-être loupé...

Pour éviter de divulguer des informations sur mon travail, je vais prendre un exemple totalement "bidon".

Admettons, dans mon 1er onglet, j'ai la liste des articles que nous vendons, numérotés de 1 à 84 (leur "référence"), leur intitulé et d'autres informations.

Dans 3 autres onglets, les articles sont répartis aux 3 commerciaux, un onglet pour chacun.

L'un aura par exemple les articles 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 53, 54, 55, 56, 57, 58, 59, 75, 76, 77, 78, 79.

Lorsque je mets mon tableau à jour, je le complète dans les onglets des commerciaux selon les fiches qu'ils me rendent chaque semaine.
J'aimerais que les informations complétées dans ces "tableaux individuels" soient enregistrées automatiquement dans mon 1er onglet où figurent tous les articles, tous commerciaux confondus.

Pour cela, j'avais commencé une formule excel. J'ai commencé avec les fonctions SI et RECHERCHEV imbriquées, sans résultat, puis avec OU et RECHERCHEV. Mais pas mieux.

J'aimerais que si la recherchev ne donne aucun résultat dans le 1er onglet, qu'elle tente dans le 2e, puis dans le 3e.
Un des 3 onglets retournera une valeur, sauf si la case est vide (si possible laisser la case vide dans ce cas).

Celle qui me semble "le mieux" marcher, ou qui du moins affiche le résultat dans l'évaluation de la formule est :

=OU(RECHERCHEV(B82;COMMERCIAL1!A6:AD50;12;FAUX);RECHERCHEV(B82;COMMERCIAL2!A6:AD50;12;FAUX);RECHERCHEV(B82;COMMERCIAL3!A6:AD50;12;FAUX))

B82 = le numéro de référence
A6:AD50 = plage de mes données avec, en colonne A, les numéros références notés (à la main)

Les onglets des commerciaux sont identiques, seules les données changent.

Si vous avez besoin d'informations complémentaires pour me venir en aide, n'hésitez pas.
Je vais continuer à chercher de mon côté, j'adore me turlupiner le cerveau avec des formules excel !


NB : en formules, je gère les plus faciles, seulement j'ai encore sans doute beaucoup à apprendre, et niveau matrices et autres... j'ai essayé de comprendre mais trop difficile au premier abord pour l'instant ^^


Cordialement,

Wyrda !

 

[Modeste geedee]

Re : RechercheV x3

Bonsour®

peut-être :

=SIERREUR(RECHERCHEV(B82;COMMERCIAL1!A6:AD50;12;FAUX);SIERREUR(RECHERCHEV(B82;COMMERCIAL2!A6:AD50;12;FAUX);SIERREUR(RECHERCHEV(B82;COMMERCIAL3!A6:AD50;12;FAUX);"")))

 

[Wyrda]

Re : RechercheV x3

Ca marche, merci beaucoup pour la réponse rapide et efficace ! 🙂


EDIT : je connais peu cette formule, et il est visiblement difficile de l'imbriquer avec la fonction "SI" basique...
Est-il possible, en cas de valeur nulle ("0"), de laisser la case vide ? Car j'ai des cases au format date et cela fausse mes statistiques...

 

[BOISGONTIER]

Re : RechercheV x3

Bonjour,

En 3D:
=RECHERCHEV(B82;INDIRECT("Commercial"&EQUIV(VRAI;(NB.SI(INDIRECT("Commercial"&LIGNE(1:3)&"!A6:A50");B82)>0);0)&"!A6:L50");12;FAUX)
Valider avec maj+ctrl+entrée

Si les noms des feuilles ne sont pas génériques

=RECHERCHEV(B82;INDIRECT("'"&INDEX(nf;EQUIV(VRAI;(NB.SI(INDIRECT("'"&nf&"'!A2:A50");B82)>0);0))&"'!A6:L50");12;FAUX)
Valider avec maj+ctrl+entrée

Les noms des feuilles peut être obtenu automatiquement.

JB

 

[Wyrda]

Re : RechercheV x3

Bonjour JB,

Je n'avais pas compris cette formule mais avec le classeur, c'est noté !

Cependant je garde la solution précédemment dite car les classeurs sont nommés par les prénoms...
Mais je note de côté cette formule, elle me servira bien un jour !

Quant à ma 2e question, j'ai décoché l'affichage du "0" pour les formules renvoyant une valeur nulle, tout simplement...

Sujet clos donc, je retourne bosser sur mon tableau.

Grand merci à vous !

 

[Modeste geedee]

Re : RechercheV x3

Bonsour®

Ca marche, merci beaucoup pour la réponse rapide et efficace ! 🙂


EDIT : je connais peu cette formule, et il est visiblement difficile de l'imbriquer avec la fonction "SI" basique...
Est-il possible, en cas de valeur nulle ("0"), de laisser la case vide ? Car j'ai des cases au format date et cela fausse mes statistiques...

cela dépend de ce que tu appelle "vide"

dans le cas présent la case ne sera jamais vide(vierge) puisqu'elle contient une formule...

si la formule renvoie un vrai zéro, l'affichage dépend cela dépend du format de la cellule( rappel : "By Design©µSoft) un nombre >=0 peut etre interprété en tant que date)

soit on laisse "" qui n'est pas vide mais NULLVAL qui est considéré comme 0
soit on met " " qui est un espace (mais cela peut porter à confusion)
soit on met une valeur très petite différente de zéro : 10^-9 (peut cependant être interprété comme 00/01/1900)
soit on met un texte quelconque : "-/-" ou "absent"

 

[Wyrda]

Re : RechercheV x3

Bonjour,

Disons que la première formule donnée :
=SIERREUR(RECHERCHEV(B82;COMMERCIAL1!A6:AD50;12;FA UX);SIERREUR(RECHERCHEV(B82;COMMERCIAL2!A6:AD50;12 ;FAUX);SIERREUR(RECHERCHEV(B82;COMMERCIAL3!A6:AD50 ;12;FAUX);"")))

me retourne "0" comme valeur. Or, le format de la case étant "date", j'ai une date assez ancienne...
Quand je veux calculer la différence entre cette date et une autre, j'ai 40 000 et quelques, au lieu de... rien.
J'ai fait en sorte que les 0 ne s'affichent pas, laissant les cases vides, mais bien qu'ils soient cachés, ils sont bel et bien là !
Du coup cela fausse quelque peu mes statistiques.

J'ai reconstitué comme j'ai pu un fichier avec un bout de mon tableau...
J'espère qu'il y a suffisamment de données pour pouvoir m'aider.

 

[Jocelyn]

Re : RechercheV x3

Bonjour le Forum,
Bonjour Wyrda, et a tous et toutes,

Tu peux peut être essayer en AF82

=SI(ET(ESTNUM(Y82);Y82>0;ESTNUM(AA82);AA82>0);AA82-Y82;"")

et en EG82

=SI(ET(ESTNUM(AC82);AC82>0;ESTNUM(AA82);AA82>0);AC82-AA82;"")

Cordialement

 

[Modeste geedee]

Re : RechercheV x3

Bonsour®

Bonjour,

Disons que la première formule donnée :
=SIERREUR(RECHERCHEV(B82;COMMERCIAL1!A6:AD50;12;FA UX);SIERREUR(RECHERCHEV(B82;COMMERCIAL2!A6:AD50;12 ;FAUX);SIERREUR(RECHERCHEV(B82;COMMERCIAL3!A6:AD50 ;12;FAUX);"")))

me retourne "0" comme valeur. Or, le format de la case étant "date
../..
Du coup cela fausse quelque peu mes statistiques.

tu peux utilisez la formule de jocelyn 🙄

ou bien corriger la tienne : (remplacer "0" par 0)
en AF82 :
=SI(OU(Y82="";Y82="?";Y82="en attente";Y82=0);"";SI(OU(AA82="";AA82="?";AA82="en attente";AA82=0);"";AA82-Y82))
en AG82 :
=SI(OU(Z82="";Z82="?";Z82="en attente";Z82=0);"";SI(OU(AB82="";AB82="?";AB82="en attente";AB82=0);"";AB82-Z82))
en AH82 :
=SI(OU(Y82="";Y82="?";Y82="en attente";Y82=0);"";SI(OU(AC82="";AC82="?";AC82="en attente";AC82=0);"";AC82-Y82))


dans les options Avancées : décocher la case concernant l'affichage des valeurs nulles :

 

[Wyrda]

Re : RechercheV x3

Bonjour,

J'avais déjà décoché la case concernant l'affichage des valeurs nulles ; cependant j'ai corrigé mes 3 formules, et ça marche !

Jocelyn, je prends note de ces formules au cas où.

Grand merci à vous deux !