MFC sur epaisseur de bordure selon jour de la semaine

[patouman]

Bonjour à tous,
j'aimerais faire une MFC sur un tableau calendrier, selon les criteres suivants :
si jour = vendredi >>> faire bordure gauche de la cellule en gras
si jour = 31 >>> faire bordure droite de la cellule en gras

Je sais bien le faire pour colorer ou changer la police, mais pour la bordure je ne trouve pas

merci pour votre aide par avance

 

[mromain]

Re : MFC sur epaisseur de bordure selon jour de la semaine

Bonjour patouman,

Je crois que ce que tu cherche à faire est impossible en MFC... On ne peut pas jouer sur l'épaisseur de bordure.
Il te faudra passer par une macro.

Je pense qu'un fichier montrant la structure de ton fichier serait alors le bienvenue 😉.

A+

 

[patouman]

Re : MFC sur epaisseur de bordure selon jour de la semaine

voici en pj le fichier

 

[mromain]

Re : MFC sur epaisseur de bordure selon jour de la semaine

Re-bonjour,

Ci-dessous un code à adapter :

Sub Bordures()
Dim iRow As Long, iCol As Long, shCal As Worksheet

    Set shCal = ThisWorkbook.Sheets("A CALENDRIER REPARTITION DZ")
    
    With shCal
        'boucler sur les lignes 9, 15 et 21
         For iRow = 9 To 21 Step 6
            'boucler de la colonne B à la dernière contenant de l'information
             For iCol = 2 To .Cells(iRow, .Columns.Count).End(xlToLeft).Column
                
                'si le jour est un vendredi
                 If Weekday(.Cells(iRow, iCol), vbMonday) = 5 Then
                    'modifier la bordure (en gras)
                     .Cells(iRow, iCol).Resize(3).Borders(xlEdgeLeft).LineStyle = xlContinuous
                    .Cells(iRow, iCol).Resize(3).Borders(xlEdgeLeft).Weight = xlMedium
                Else
                    'modifier la bordure (en normal)
                     .Cells(iRow, iCol).Resize(3).Borders(xlEdgeLeft).LineStyle = xlContinuous
                    .Cells(iRow, iCol).Resize(3).Borders(xlEdgeLeft).Weight = xlThin
                End If
                
                'si le jour est un 31
                 If Day(.Cells(iRow, iCol)) = 31 Then
                    'modifier la bordure (en gras)
                     .Cells(iRow, iCol).Resize(3).Borders(xlEdgeRight).LineStyle = xlContinuous
                    .Cells(iRow, iCol).Resize(3).Borders(xlEdgeRight).Weight = xlMedium
                Else
                    'modifier la bordure (en normal)
                     .Cells(iRow, iCol).Resize(3).Borders(xlEdgeRight).LineStyle = xlContinuous
                    .Cells(iRow, iCol).Resize(3).Borders(xlEdgeRight).Weight = xlThin
                End If
            Next iCol
        Next iRow
    End With
End Sub

Si tu veux te passer de macro (surtout pour du look) et faire tout en MFC avec une seule épaisseur de bordure en jouant sur le type et la couleur de trait.

A+

 

[patouman]

Re : MFC sur epaisseur de bordure selon jour de la semaine

Merci beaucoup mromain pour ton aide

je crois que je vais m'orienter vers une MFC avec des pointillés et traits pleins, ce sera plus simple pour moi

merci encore et bonne continuation

 

[Claude38]

Re : MFC sur epaisseur de bordure selon jour de la semaine

Bonsoir tous,

Un essai en traçant les traits en épais avant de faire la Mfc

Bonne soirée