Microsoft 365 Demande d'aide pour calcul d'heures

[Véhuel]

Bonjour à tous,

j'ai recherché sur d'autres posts, mais en vain. je souhaite avoir un calcul en D6 et saisir du temps en colonne F ex : (0.35 pour 35 minutes ou 2.00 pour 2 heures ou -1.00 pour 1 heure en moins ou -0.40 pour moins 40 minutes ect... ) et le résultat en D6 au format heures (h:mm) , mais je n'arrive pas à ce que je veux. Pouvez-vous m'aider s'il vous plait. et surtout est-ce possible ?

 

[sylvanu]

Bonsoir Véhuel,
Je trouve -01:15 et non +01:15.
Alors un essai en PJ avec :

=SI(SIGNE(SOMME(F10:F400))=-1;"-";"") & TEXTE(ABS(SOMME(F10:F400))/14.4;"hh:mm")

Attention, le résultat est un texte non un nombre.
Ou alors en passant dans les options Xl "Utilisez le calendrier 1904", on peut obtenir des heures négatives, avec simplement en D6 :

=SOMME(F10:F400)/14.4

( voir PJ V2 )
Mais attention aux pièges du calendrier 1904 : Lien

 

[Véhuel]

Bonsoir sylvanu,
merci pour ton aide, tu as tout a fait raison sur mon résultat c'est -1:15 désolée
la première solution avec la formule me convient mieux , en revanche j'ai un résultat qui ne correspond pas. si je saisie 1.15 en F, en D6 cela devrait s'afficher 00:00, ors ça met 00:40 le résultat n'est pas bon.

 

[job75]

Bonsoir Véhuel, sylvanu,

Utiliser le calendrier depuis 1904 (menu Fichier-Options-Options avancées).

Mettre la cellule D6 au format [h]:mm

Formule en D6 =SOMME(F10:F400)/24

-0,75 est converti en -0:45

A+

 

[Véhuel]

bonsoir Job75,
merci pour ton aide , mais -0.75 correspond à -01:15 en heure, si tu regardes le temps saisi en F
bonne soirée

 

[job75]

Vous voulez dire que 0,35 en colonne F signifie 0 heure et 35 minutes ?

Ce n'est pas cohérent car dans ce cas on ne peut pas utiliser SOMME(F10:F400)

 

[job75]

Bon alors dans ce cas 0h35+1h15-1h+2h20-3h-0h45 ça fait -0h35min

On retrouve ce résultat avec la formule en D6 :

=SOMMEPROD(SIGNE(F10:F400);ENT(ABS(F10:F400))/24+100*MOD(ABS(F10:F400);1)/1440)

Bonne nuit.

 

[job75]

Bonjour Véhuel, le forum,

Plutôt que des nombres décimaux en F10:F400 il vaut mieux entrer des nombres entiers de 2, 3 ou 4 chiffres.

Format personnalisé sur F10:F400 #0"h"00;[Rouge]-#0"h"00

Formule en D6 :

=SOMMEPROD(SIGNE(F10:F400);ENT(ABS(F10:F400)/100)/24+100*MOD(ABS(F10:F400)/100;1)/1440)

Toujours avec le calendrier depuis 1904 et le format [h]:mm en D6.

A+

 

[job75]

Bien entendu plutôt qu'un tableau avec des lignes vides il vaut mieux créer un tableau structuré.

On peut alors créer le nom dynamique Heures =Tableau1[SUIVI du NOMBRE HEURES]

et l'utiliser dans la formule en D6.

 

[sylvanu]

Bonjour,
Ou sans utiliser le calendrier 1904 mais avec une colonne masquée (G), en D6:

=SI(SOMME(F10:F400)<0;"-";"") & TEXTE(ABS(SOMME(G10:G400));"hh:mm")
en G :
=SIGNE(F10)*CNUM(ENT(ABS(F10))&":"&(ABS(F10)-ENT(ABS(F10)))*100)

 

[job75]

Salut sylvanu, 02:30 en D6 n'est pas correct on doit trouver -1:50

 

[gbinforme]

Bonjour à tous,

Je pense que l'erreur de base est dans la saisie car il faudrait saisir en centième d'heure
et non en minutes comme fait le classeur sur la demande.
Ainsi pour 1:30 il ne faut pas saisir 1,30 mais 1,50 car sinon on a une erreur
car les décimales entre 60 et 100 ne sont pas prises en compte.

 

[sylvanu]

Salut sylvanu, 02:30 en D6 n'est pas correct on doit trouver -1:50

Oups ! Ma PJ n'était pas la bonne. J'ai rectifié. ( fichier avec colonne G supprimée.)

Cependant une autre approche sans ajout de colonne et sans calendrier 10904 avec simplement en D6 :

=SI(SOMME(F10:F400)<0;"-";"") & TEXTE(ABS(ENT(SOMME(F10:F400))/24+(SOMME(F10:F400)-ENT(SOMME(F10:F400)))/14.4);"hh:mm")

Et ça à l'air de coller.

 

[job75]

Hello gbinforme,

Je pense que l'erreur de base est dans la saisie car il faudrait saisir en centième d'heure

C'est ce que j'ai pensé au départ, d'où mon post #6.

Mais ensuite mes solutions se font avec des minutes, comme le désire Véhuel.

 

[Véhuel]

Bon alors dans ce cas 0h35+1h15-1h+2h20-3h-0h45 ça fait -0h35min

On retrouve ce résultat avec la formule en D6 :

=SOMMEPROD(SIGNE(F10:F400);ENT(ABS(F10:F400))/24+100*MOD(ABS(F10:F400);1)/1440)

Bonne nuit.

Bonjour job 75,
je viens de regarder le tableau avec ta solution, qui m'a l'air très bien. je te remercie, tout est ok apparemment