Microsoft 365 Définir des plages de dates

[Zazagally]

Bonjour,

J'ai besoin de faire figurer sur un publipostage des plages de dates qu'on extrait à partir de cellules de mon fichier excel.
J'ai plusieurs dates qui se suivent pour des périodes de mi temps thérapeutique, exemple dans mon fichier pour le premier dossier :

Période de temps partiel thérapeutique 1 : de E2 à F2
Période de temps partiel thérapeutique 2 : de H2 à I2
Période de temps partiel thérapeutique 3 : de K2 à L2

Je cherche à extraire chaque date manquante entre ces périodes dans les cellules de V2 à AZ2 puis de concaténer les périodes consécutives.

Pouvez vous m'aider?

Je vous joint le fichier ce sera plus parlant.

Un grand merci !

 

[sylvanu]

Bonjour zazagally,
Pour le premier point un essai en PJ avec pour V2 par ex :

=SI(OU(ET(V$1>=$E2;V$1<=$F2);ET(V$1>=$H2;V$1<=$I2);ET(V$1>=$K2;V$1<=$L2);ET(V$1>=$N2;V$1<=$O2);ET(V$1>=$Q2;V$1<=$R2));"";V$1)

Point bizarre : dans votre fichier pour V2 pour avez une date manquante alors que cette date ( 01/08/2025 ) figure en E2 donc non manquantes.
est une erreur ou une incompréhension de ma part.

Pour le second point, je sèche pour l'instant.
NB: Le VBA est il autorisé ?

 

[Zazagally]

Bonjour zazagally,
Pour le premier point un essai en PJ avec pour V2 par ex :

=SI(OU(ET(V$1>=$E2;V$1<=$F2);ET(V$1>=$H2;V$1<=$I2);ET(V$1>=$K2;V$1<=$L2);ET(V$1>=$N2;V$1<=$O2);ET(V$1>=$Q2;V$1<=$R2));"";V$1)

Point bizarre : dans votre fichier pour V2 pour avez une date manquante alors que cette date ( 01/08/2025 ) figure en E2 donc non manquantes.
est une erreur ou une incompréhension de ma part.

Pour le second point, je sèche pour l'instant.
NB: Le VBA est il autorisé ?

Bonjour Sylvanu,

Déjà un grand merci pour la 1ère formule.
Désolée je n'ai pas bien compris le point qui pose question, je ne vois pas pas de date manquante c'est quelle cellule ?

Pour la seconde formule, je ne peux pas intégrer de VBA, c'est interdit par mon entreprise.

Merci beaucoup

 

[sylvanu]

Désolée je n'ai pas bien compris le point qui pose question, je ne vois pas pas de date manquante c'est quelle cellule ?

Dans votre fichier, dans la cellule V2 vous avez 01/08/2025 donc c'est une date manquante.
Or, en E2 vous avez 01/08/2025, donc elle est présente et non manquante.
C'est ce point que je ne comprends pas.

 

[Zazagally]

Dans votre fichier, dans la cellule V2 vous avez 01/08/2025 donc c'est une date manquante.
Or, en E2 vous avez 01/08/2025, donc elle est présente et non manquante.
C'est ce point que je ne comprends pas.
Regarde la pièce jointe 1222560

oui je confirme c'est bien une erreur, désolée

 

[Hecatonchire]

Bonjour Zazagally, sylvanu,

Pour la formule 2
En BA2

=LET(p;$E2:$S2;
s;SEQUENCE(;4;;3);
f;"jj/mm/aaaa";
t;MAP(s;LAMBDA(v;"Du " & TEXTE(INDEX(p;v+1)+1;f) & " au " &  TEXTE(INDEX(p;v+3)-1;f)));
SIERREUR(t;""))

 

[Zazagally]

Bonjour Zazagally, sylvanu,

Pour la formule 2
En BA2

=LET(p;$E2:$S2;
s;SEQUENCE(;4;;3);
f;"jj/mm/aaaa";
t;MAP(s;LAMBDA(v;"Du " & TEXTE(INDEX(p;v+1)+1;f) & " au " &  TEXTE(INDEX(p;v+3)-1;f)));
SIERREUR(t;""))

Merci Hacatonchire mais malheureusement ça ne fonctionne pas, j'ai bien vérifié la formule pourtant et elle est bien en BA2

 

[Hecatonchire]

Quel est le problème ?

Fichier exemple de ma formule

 

[Zazagally]

Quel est le problème ?

Fichier exemple de ma formule

Je regarde toute à l'heure, merci beaucoup !

 

[Zazagally]

Quel est le problème ?

Fichier exemple de ma formule

Bonjour Hecatonchire,

Ca fonctionne ! un grand merci !!!

 

[Zazagally]

Bonjour Hecatonchire,

Ca fonctionne ! un grand merci !!!

Quel est le problème ?

Fichier exemple de ma formule

Bonsoir Hecatonchire,
J'ai presque terminé mon fichier automatisé.
J'ai tout de même une incohérence avec les périodes de congés qui ne s'incrémentent pas correctement, peux tu regarder à nouveau ?
J'ai mis en valeur et anonymisé mes données.
Pour mémoire je cherche à trouver des périodes de congés en colonne BA => BD à partir des absences connues de la colonne E à la colonne S.
Un grand merci !!

 

[Hecatonchire]

Bonsoir,

Désolé pour la réponse plus tardive. J'espère avoir compris le problème.

Je me suis focalisé sur le fait des 5 périodes donc 4 intervalles (cf les 4 formules demandées) mais en faite il peut y avoir 2 intervalles de plus (Plage avant Date de début TPT -période 1 et plage après Date de fin TPT -période 5)

Je propose :
=LET(p;$E2:$S2;
mC;{1;2;4;5;7;8;10;11;13;14};
mD;FRACTIONNER.TEXTE(REDUCE("";mC;LAMBDA(c;v;c&SI(INDEX(p;v)<>0;INDEX(p;v)&";";"")));";";;VRAI)*1;
nbP;NB(pD)/2;
dM;(JOUR(MIN(mD))<>1)*1;
fM;(JOUR(MAX(mD))<>31)*1;
f;"jj/mm/aaaa";
tDm;SI(dM;"Du " & TEXTE(FIN.MOIS(MIN(mD);-1)+1;f) & " au " & TEXTE(MIN(mD)-1;f);"");
tFm;SI(fM;"Du " & TEXTE(MAX(mD)+1;f) & " au " & TEXTE(FIN.MOIS(MAX(mD);0);f);"");
tmD;SI(nbP>1;REDUCE("";SEQUENCE(;nbP-1);LAMBDA(c;v;c&";"&"Du " & TEXTE(INDEX(pD;2*v)+1;f) & " au " & TEXTE(INDEX(pD;2*v+1)-1;f)));"");
tR;SIERREUR(FRACTIONNER.TEXTE(tDm&tmD&";"&tFm;";";;VRAI);"");
tR)

Description rapide des valeurs
mc : matrice des colonnes a utiliser
mD : matrice des dates des périodes
nbP : nombre de paires de dates dans mD
dM : Test si début mois présent dans mD
fM : Test si fin mois présent dans mD
f : format d'affichage des dates
tDm: Texte pour le début de mois (Plage avant Date de début TPT -période 1 )
tFm : Texte pour la fin de mois (Plage avant Date de fin TPT -période 5 )
tmD: Texte pour la plage dates de mD (texte pour les intervalles)
tR: Texte Résultat

 

[Zazagally]

Bonsoir,

Désolé pour la réponse plus tardive. J'espère avoir compris le problème.

Je me suis focalisé sur le fait des 5 périodes donc 4 intervalles (cf les 4 formules demandées) mais en faite il peut y avoir 2 intervalles de plus (Plage avant Date de début TPT -période 1 et plage après Date de fin TPT -période 5)

Je propose :
=LET(p;$E2:$S2;
mC;{1;2;4;5;7;8;10;11;13;14};
mD;FRACTIONNER.TEXTE(REDUCE("";mC;LAMBDA(c;v;c&SI(INDEX(p;v)<>0;INDEX(p;v)&";";"")));";";;VRAI)*1;
nbP;NB(pD)/2;
dM;(JOUR(MIN(mD))<>1)*1;
fM;(JOUR(MAX(mD))<>31)*1;
f;"jj/mm/aaaa";
tDm;SI(dM;"Du " & TEXTE(FIN.MOIS(MIN(mD);-1)+1;f) & " au " & TEXTE(MIN(mD)-1;f);"");
tFm;SI(fM;"Du " & TEXTE(MAX(mD)+1;f) & " au " & TEXTE(FIN.MOIS(MAX(mD);0);f);"");
tmD;SI(nbP>1;REDUCE("";SEQUENCE(;nbP-1);LAMBDA(c;v;c&";"&"Du " & TEXTE(INDEX(pD;2*v)+1;f) & " au " & TEXTE(INDEX(pD;2*v+1)-1;f)));"");
tR;SIERREUR(FRACTIONNER.TEXTE(tDm&tmD&";"&tFm;";";;VRAI);"");
tR)

Description rapide des valeurs
mc : matrice des colonnes a utiliser
mD : matrice des dates des périodes
nbP : nombre de paires de dates dans mD
dM : Test si début mois présent dans mD
fM : Test si fin mois présent dans mD
f : format d'affichage des dates
tDm: Texte pour le début de mois (Plage avant Date de début TPT -période 1 )
tFm : Texte pour la fin de mois (Plage avant Date de fin TPT -période 5 )
tmD: Texte pour la plage dates de mD (texte pour les intervalles)
tR: Texte Résultat

Ne t'excuse pas pour le délai c'est adorable de ta part de te repencher sur mon sujet ! merci bcp je regarde ce week end !! bon week end à toi