XL 2010 calcul du nombre de jours en fonction des dates

[hdparcs]

Bonjour à tous,
Dans un fichier, j'ai une colonne avec des dates.
Une même date peut être répétée sur plusieurs ligne.
Peut-on utiliser une formule pour calculer le nombre de jours en fonction des dates mentionnées dans ladite colonne ?
Merci à ceux qui prendront le temps de me répondre.

 

[Cousinhub]

Bonjour,
Supposant les dates dans les cellules A1:A31

=SOMMEPROD(1/NB.SI(A1:A31;A1:A31))

Bonne journée

 

[hdparcs]

Bonjour,
Supposant les dates dans les cellules A1:A31

=SOMMEPROD(1/NB.SI(A1:A31;A1:A31))

Bonne journée

Ca c'est super ! Merci !
Et si je souhaite que cette formule fonctionne comme "SOUS.TOTAL", en ne comptabilisant que les cellules filtrées. Est-ce possible ? Merci d'avance,

 

[tbft]

Bonjour.

Un fichier exemple avec une architecture et des données représentatives mais non sensible serait le bienvenu.

 

[job75]

Bonjour hdparcs, Cousinhub, tbft,

Avec le titre "Dates" en A1 et les dates filtrées en A2:A100 :

=SOMMEPROD(SOUS.TOTAL(3;DECALER(A1;LIGNE(A1:A100);)))

A+

 

[Cousinhub]

Re-,
Perso, je pense que le filtre s'opère sur une autre colonne... (mais c'est un avis perso)
D'après le regretté JBoisgontier (Rubrique Sommeprod), cette formule matricielle (la zone Nom couvre les dates de A1 à A25 dans le fichier joint)

=SOMME(--(FREQUENCE(SI(SOUS.TOTAL(3;INDIRECT("A"&LIGNE(Nom)));EQUIV(Nom;Nom;0));LIGNE(INDIRECT("1:"&LIGNES(Nom))))>0))

Bonne fin d'apm

 

[job75]

Perso, je pense que le filtre s'opère sur une autre colonne... (mais c'est un avis perso)

Avec ma formule le filtrage peut se faire sur n'importe quelle colonne, voyez le fichier joint.

Edit : ah oui, je ne me suis pas occupé des doublons...

 

[job75]

Bon voici une formule pour éliminer les doublons des dates :

=SOMMEPROD(ST*(EQUIV(A2:A101&" "&ST;A2:A101&" "&ST;0)=LIGNE(A1:A100)))

Avec le nom défini ST :

=SOUS.TOTAL(3;DECALER(Feuil1!$A$1;LIGNE(Feuil1!$A$1:$A$100);))

 

[job75]

Bonjour le forum,

Pour tester j'ai mis 100 dates qui se suivent et non filtrées en A2:A101.

La formule du post #8 se recalcule chez moi en 0,92 milliseconde.

Celle du post #6 se recalcule en 0,46 milliseconde, c'est 2 fois plus rapide.

A+