Ctrl F vers un autre document Excel

[Roland2008]

Bonjour,

J'aimerais insérer dans une feuille Excel un lien qui ouvre un autre document Excel avec sa boite de dialogue "Ctrl+F" vers un mot prédéfini.

Je crois qu'il existe déjà un moyen de faire un raccourci Ctrl+F vers un autre onglet au sein d'un même classeur (à l'aide de macros notamment), mais il s'agit ici de faire un lien vers un fichier distinct.

Pourriez-vous m'aider ?

Je suis sous Excel 2007.

Roland

 

[job75]

Re : Ctrl F vers un autre document Excel

Bonjour Roland2008, bienvenue sur XLD,

Téléchargez les 2 fichier joints dans un même répertoire (le bureau par exemple).

La macro dans la 1ère feuille du fichier Source.xlsm :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row < 5 Or Target.Row > 7 Then Exit Sub 'à adapter
Cancel = True
ThisWorkbook.FollowHyperlink [A2]
Application.Goto ActiveWorkbook.Sheets(Cells(Target.Row, 1).Text).[A1], True
Application.Dialogs(xlDialogFormulaFind).Show Cells(Target.Row, 2)
End Sub

A+

 

[job75]

Re : Ctrl F vers un autre document Excel

Re,

On peut aussi créer des liens hypertexte, voyez les fichiers joints et ces macros :

Private Sub Worksheet_Change(ByVal Target As Range)
'crée les liens hypertexte
Dim r As Range, fichier As String
Set r = Intersect(Target, Range("A2:A" & Rows.Count), Me.UsedRange)
If r Is Nothing Then Exit Sub
fichier = ThisWorkbook.Path & "\Cible.xlsx" 'à adapter
For Each r In r 'si entrées multiples (copier-coller par exemple)
  r.Hyperlinks.Delete
  If r <> "" Then Hyperlinks.Add r, fichier
Next
End Sub

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
Application.Goto ActiveWorkbook.Sheets(Target.Parent.Text).[A1], True
Application.Dialogs(xlDialogFormulaFind).Show Target.Parent(1, 2)
End Sub

A+