creation de feuilles par macro

[eduraiss]

Bonjour au forum

je viens avec le problème ci-dessus.
dans un classeur j'ai deux feuilles nommée "codedate" et "semaine 25" je voudrais a partir de la feuille "codedate" creer 6 feuilles "lundi" mardi" "mercredi" "jeudi" vendredi"samedi" toutes identiques a la feuille "semaine 25"
j'aimerais que l' onglet de la feuille lundi soit "lundi 18" pour celle du "mardi 19" ect.

je ne sais pas si je suis assez clair

Merci a vous
Cordialement

 

[Pierrot93]

Re : creation de feuilles par macro

Bonjour Eduraiss


code ci dessous à remplacer :

Sub test2()
Dim s As Byte, j As String, k As Byte
Dim p As Date, d As Date, x As Date
Application.ScreenUpdating = False
s = Range("B5").Value
j = Range("B8").Value

Select Case j
    Case "lundi"
        k = 1
    Case "mardi"
        k = 2
    Case "mercredi"
        k = 3
    Case "jeudi"
        k = 4
    Case "vendredi"
        k = 5
    Case "samedi"
        k = 6
Case Else
    MsgBox "cellule b8 non valide"
    Exit Sub
End Select

p = DateSerial(Year(Date), 1, 1)
d = DateSerial(Year(Date), 12, 31)
For x = p To d
    If DatePart("ww", x, vbMonday, vbFirstFourDays) = s Then
        If Weekday(x, vbMonday) = k Then
            Sheets("Semaine " & s).Copy after:=ActiveWorkbook.Sheets(Worksheets.Count)
            ActiveSheet.Name = j & " " & Format(x, "dd")
            ActiveSheet.Range("J1").Value = Sheets("Codedate").Range("B11").Value
            ActiveSheet.Range("F1").Value = Sheets("Codedate").Range("B15").Value
            Exit For
        End If
    End If
Next x
Application.ScreenUpdating = True
End Sub

bonne journée
@+

 

[eduraiss]

Re : creation de feuilles par macro

Bonjour au forum

Bonjour a toi Pierrot et merci cela fonctionne super voir même plus.

Bonne journée et un grand merci

Cordialement.