Microsoft 365 copie automatique d'une feuille excel vers une autre en rentrant le nom par exemple

[Delaye JC]

Bonjour, j'ai un tableau d'adherents sur plusieurs années.
j'aimerais quand j'entre les nom sur l'année en cours que excel recopie automatiquement les données sur les années precedentes.
Pouvez vous m'aider

 

[Dand87]

Bonjour,
Avez-vous un fichier Excel avec des données anonymisées?
Avec une formule Excel, c'est possible, par contre si vous voulez que les données se copient vraiment dans l'autre fichier ou feuille, je crois qu'il vous faudra une solution VBA.

 

[Delaye JC]

Voici un tableau il faudrait arriver a recopier les colonnes de D à O de la feuille 2024/2025 en rentrant le Nom de l'adherent sur la feuille 2025/2026

 

[Dan]

Bonjour,
Votre problème est que vous avez des noms identiques qu'excel va considérer comme doublons (exemple pour Delaye)
Le mieux serait d'utiliser le chiffre que vous avez en colonne A ou mieux la colonne O qui dispose d'un numéro unique
Il vous suffirait d'entrer ce numéro en colonne O pour avoir les infos demandées
Est-ce possible pour vous ?

Crdlt

 

[Dand87]

Bonjour,
Je suis d'accord avec Dan.
Ici, on copie les informations du premier qu'on trouve dans la liste. On peux aussi copier les informations du dernier...
On ramène les infos colonne pas colonne!

La formule est stricte, on ramène les informations que du 2024_2025! Par contre on peut changer la formule pour prendre les infos de l'année précédente (voir MDR)

 

[Delaye JC]

Salut, merci pour vos reponse, effectivement, on pourrais utiliser la colonne O

 

[Delaye JC]

encore une question, imaginons que j'ai des données sur plusieurs années, 2024/2025; 2025/2026; est il possible de rechercher les données sur 2 feuilles?

 

[Delaye JC]

Voici un tableau test,
Donc pour résumer,
prennons la Colonne D pour rentrer un numero unique, afin de recuperer les info des colonnes E à N sur les 2 feuille precedente.
Ex: je rentre le numero colonne D sue l'année 2025/2026, la formule recupere les données sur les feuille 2023/2024 et 2024/2025.

 

[Nain porte quoi]

hello,

une solution

 

[Dand87]

hello,

une solution

Bonjour, tu as proposé une bonne solution, je ne mettrai pas ma proposition à jour pour répondre aux autres demandes.
Peux-tu en 2026-2027 aller lire dans 2025-2027 et si tu ne trouves rien, aller dans 2024-2025 et ainsi de suite?

 

[job75]

Bonjour à tous,

Une solution VBA, voyez le fichier .xlsm joint et cette macro dans ThisWorkbook :

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim an%, preced1 As Worksheet, preced2 As Worksheet, i&, j&, lig&, r As Range, col%
an = Val(Sh.Name)
If an = 0 Then Exit Sub
Set Target = Intersect(Target, Sh.Range("D3:D" & Sh.Rows.Count), Sh.UsedRange)
If Target Is Nothing Then Exit Sub
Application.ScreenUpdating = False
Application.EnableEvents = False 'désactive les évènements
On Error Resume Next
Set preced1 = Sheets(an - 1 & "_" & an)
Set preced2 = Sheets(an - 2 & "_" & an - 1)
For Each Target In Target 'si entrées multiples (copier coller)
    i = 0: j = 0: lig = Target.Row
    i = Application.Match(Target, preced1.Columns(4), 0)
    j = Application.Match(Target, preced2.Columns(4), 0)
    Set r = Sh.Cells(lig, 5).Resize(, 10) 'colonnes E à N
    For Each r In r
        col = r.Column
        If IsEmpty(r) Then r = preced1.Cells(i, col): If IsEmpty(r) Then r = preced2.Cells(j, col)
Next r, Target
Application.EnableEvents = True 'réactive les évènements
End Sub

Elle se déclenche quand on entre ou efface des valeurs en colonne D.

A+

 

[Nain porte quoi]

Bonjour, tu as proposé une bonne solution, je ne mettrai pas ma proposition à jour pour répondre aux autres demandes.
Peux-tu en 2026-2027 aller lire dans 2025-2027 et si tu ne trouves rien, aller dans 2024-2025 et ainsi de suite?

Je n'ai pas voulu faire ça car quand on ajoute une "année" il faut tout refaire et je me doute aussi que Delaye JC va écraser des formules en ajoutant des noms, donc ça ne me semble pas non plus une bonne solution, juste un dépannage pour cette année et la suivante mais ça n'est pas viable s'il y a d'autres saisies

 

[job75]

Pour tester j'ai copié la plage '2024_2025'!D3: D200 et l'ai collée sur '2025_2026'!D3 : la macro s'exécute en 0,48 seconde.

 

[job75]

Autre solution avec des tableaux VBA pour gagner du temps :

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim an%, preced1 As Worksheet, preced2 As Worksheet, PlageFormule As Range, formule$, i&, j&, zone As Range, tablo, n&, lig&, r As Range, a, b, k%
an = Val(Sh.Name)
If an = 0 Then Exit Sub
Set Target = Intersect(Target, Sh.Range("D3:D" & Sh.Rows.Count), Sh.UsedRange)
If Target Is Nothing Then Exit Sub
Application.ScreenUpdating = False
Application.EnableEvents = False 'désactive les évènements
On Error Resume Next
Set preced1 = Sheets(an - 1 & "_" & an)
Set preced2 = Sheets(an - 2 & "_" & an - 1)
Set PlageFormule = Intersect(Sh.Columns(13), Target.EntireRow) 'colonne M
formule = PlageFormule(1).FormulaR1C1 'mémorise
PlageFormule = False 'supprime les formules
For Each zone In Intersect(Target.EntireRow, Sh.Columns(5).Resize(, 10)).Areas 'colonnes E à N
    tablo = zone 'matrice, plus rapide
    n = 0
    For Each r In zone.Rows
        n = n + 1
        i = 0: j = 0: lig = r.Row
        i = Application.Match(r.Cells(1, 0), preced1.Columns(4), 0)
        j = Application.Match(r.Cells(1, 0), preced2.Columns(4), 0)
        a = "": b = ""
        a = preced1.Range(Replace(r.Address, lig, i))
        b = preced2.Range(Replace(r.Address, lig, j))
        For k = 1 To 10
            If IsEmpty(tablo(n, k)) Then tablo(n, k) = a(1, k): If IsEmpty(tablo(n, k)) Then tablo(n, k) = b(1, k)
    Next k, r
    zone = tablo 'restitue le tableau modifié
Next zone
PlageFormule = formule 'restitue les formules
Application.EnableEvents = True 'réactive les évènements
End Sub

Avec le copier-coller du post précédent cette macro s'exécute en 0,04 seconde, c'est 12 fois plus rapide !

 

[Nain porte quoi]

@job75 vous ne seriez pas un peu monomaniaque du temps ? Vous vivez avec un chrono implanté dans la main ? 🙃🤣 (rien de méchant, juste un taquinerie)