vérrouillage ligne après une entrée

[elodiebulle]

Bonjour à tous,

Après de nombreuses pertes de données suite a des fautes de frappe je souhaiterais vérouiller les lignes d'un fichier lorsque un mot spécifique est rentrée dans une cellule du tableau. C'est à dire aucune modification est possible sauf avec un mot de passe par exemple.

Par exemple lorsque l'on rentre une date de cloture l'Etat affiche clos et si'lon met une date de paiement l'etat affiche payé et clos.
Je souhaiterais vérouiller toute la ligne à partir du moment où l'on a payé et clos.

Je ne suis pas du tout familière avec VBA...

Merci d'avance pour votre aide.

Elodie

 

[job75]

Re : vérrouillage ligne après une entrée

Bonsoir elodiebulle,

Voyez le fichier joint et cette macro dans le code de la feuille (clic droit sur l'onglet et Visualiser le code) :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range
Set r = Intersect(Target, [G:H], Me.UsedRange)
If Not r Is Nothing Then
  For Each r In r.Rows 'si entrées multiples
    If Cells(r.Row, "F") = "Payé et Clos" Then
      Unprotect "toto" 'votre mot de passe
      r.EntireRow.Locked = True
      Protect "toto" 'votre mot de passe
    End If
  Next
End If
End Sub

Elle se déclenche quand on modifie le contenu des cellules en colonne G ou H.

A+

 

[elodiebulle]

Re : vérrouillage ligne après une entrée

Merci pour tout!
c'est génial et excatement ce que je voulais. Fini les pertes de données....
Merci encore

 

[job75]

Re : vérrouillage ligne après une entrée

Bonjour elodiebulle, le forum,

L'inconvénient de la solution précédente c'est qu'une entrée erronée (ou manquante) ne peut plus être modifiée sans intervention de l'Administrateur.

On peut autoriser cette modification par un double-clic :

Private Sub Worksheet_Change(ByVal Target As Range)
'---code précédent---
'---cellule jaune---
If Target(1).Interior.ColorIndex = 6 And Target(1) <> "" Then
  Unprotect "toto" 'votre mot de passe
  Target(1).Locked = True 'verrouillage
  Target(1).Interior.ColorIndex = xlNone 'pas de couleur
  Protect "toto" 'votre mot de passe
End If
End Sub

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Row > 1 And Target.Column <> 6 And Target.Locked Then
  Cancel = True
  Unprotect "toto" 'votre mot de passe
  Target.Locked = False 'déverrouillage
  Target.Interior.ColorIndex = 6 'jaune
  Protect "toto" 'votre mot de passe
End If
End Sub

A vous de voir l'intérêt de cette solution.

Fichier (2).

A+

 

[elodiebulle]

Re : vérrouillage ligne après une entrée

C'est très bien que l'on ne puisse pas modifier sans l'accord de l'administrateur sinon c'est une ouverture à beaucoup de choses.
En revanche je n'arrive pas à faire fonctionner le code dans d'autres fichiers.
J'ai fait un copier-coller du code mais je ne pense pas que ce soit la bonne solution
Quelle est la procédure à effectuer?

Merci

 

[job75]

Re : vérrouillage ligne après une entrée

Re,

Le code doit être comme je l'ai dit dans le code de la feuille (clic droit sur l'onglet et Visualiser le code).

A+