Autres Ventilation d'heures en Jours heures et minutes

[Caninge]

bonjour à tous,

En ce moment difficile, je voudrais exprimer ma plus grande sympathie à tous les personnels soignants, des services d'ordre, des gens qui sont obligés de travailler
pour nous fournir en alimentation sans oublier tous les autres services de fonctionnement. UN GRAND BRAVO !

Confinement oblige je me suis fait un tableau pour connaitre en jours heures minutes la durée en deux dates.

Merci de m'aider

Bon courage à tous.

 

[Caninge]

J'ai oublié...ma question comment arriver au résultat dans la cellule E4

 

[dg62]

Bonjour Caninge
il y a surement plus simple (pour B5)

=B5&" est confiné depuis "& ENT($D$1-C5) &" jours "& ENT((($D$1-C5)-ENT($D$1-C5))*24 )& " heures et "

 

[Caninge]

Dg62,

merci d'avoir répondu.
Je pense qu'il manque la fin de la formule.

Merci

 

[dg62]

&ENT((((($D$1-C4)-ENT($D$1-C4))*24)-ENT((($D$1-C4)-ENT($D$1-C4))*24))*60)&" minutes"

 

[Caninge]

J'ai vu qu'il y avait une erreur : les 2 personnes ont un écart de 30 minutes.
Dans la colonne E il y a une heure.

 

[dg62]

La deuxième partie est basée sur B4 alors que la première est sur B5

Formule complète pour E4

=B4&" est confiné depuis "&ENT($D$1-C4)&" jours "&ENT((($D$1-C4)-ENT($D$1-C4))*24)&" heures et "&ENT((((($D$1-C4)-ENT($D$1-C4))*24)-ENT((($D$1-C4)-ENT($D$1-C4))*24))*60)&" minutes"

 

[jmfmarques]

Bonjour
- je n'ouvre jamais un classeur tiers
- ma réponse avec un exemple (date début en A1 et date fin en B1
Formule en C1 :

=ENT(B1-A1) & " j " & TEXTE(B1-A1;"h  \h mm")

EDIT / et même ainsi :

= TEXTE(B1-A1;"j \j h  \h mm \m")

Mais je trouve assez optimiste de ne pas prévoir de compter également en mois

 

[Caninge]

Bonjour à jmfmarques.

Vous n'ouvrez jamais un fichier c'est cela. Je voulais savoir pourquoi ?
Vous avez raison, il faudra peut-être rajouter dans la formule "mois". Je n'espère pas...

c'est bon pour la réponse dg62.

merci et à bientôt

 

[jmfmarques]

Vous n'ouvrez jamais un fichier c'est cela. Je voulais savoir pourquoi ?

Pour des raisons (celles que j'estime) de sécurité. On ne les partage pas forcément ? Peut-être. Elles sont toutefois les miennes (comme, d'ailleurs, est la mienne, ma machine .. .)
Ceci étant : lorsqu'il m'arrive de demander un conseil à tel ou tel autre homme de l'art, je ne discute pas les conditions qu'il met à l'apport de son aide.

 

[Caninge]

Ok ! Bonne après-midi et à la prochaine.

 

[jmfmarques]

Bon après-midi à toi également.
Pour t'y aider, v'la les mois :

= TEXTE(B1-A1;"m \moi\s j \jour\s h  \h  mm \m")

Tu ne crois pas qu'il serait également prudent d'aller jusqu'aux années, avec ce conn...ard de virus ?

 

[dg62]

et pour les mois sans aller jusque l'année...

=SI(DATEDIF(C4;$D$1;"ym")<1;B4&" est confiné depuis "&ENT($D$1-C4)&" jours "&ENT((($D$1-C4)-ENT($D$1-C4))*24)&" heures et "&ENT((((($D$1-C4)-ENT($D$1-C4))*24)-ENT((($D$1-C4)-ENT($D$1-C4))*24))*60)&" minutes";B4&" est confiné depuis "&DATEDIF(C4;$D$1;"ym")&" mois "&DATEDIF(C4;$D$1;"md")& " jours "&ENT((($D$1-C4)-ENT($D$1-C4))*24)&" heures et "&ENT((((($D$1-C4)-ENT($D$1-C4))*24)-ENT((($D$1-C4)-ENT($D$1-C4))*24))*60)&" minutes")

 

[Modeste geedee]

Bonsour®

= TEXTE(B1-A1;"m \moi\s j \jour\s h  \h  mm \m")

Utiliser un format de date pour une durée n'est pas adéquat sachant qu'il n'y a pas de mois "0"
et que 12 mois et x jours font plus un an


=ANNEE(B1-A1)-1900 & " a(s) " & MOIS(B1-A1)-1 & " m " & JOUR(B1-A1) & " j(s)"

on pourra éventuellement compliquer la formule en testant les valeurs respectives égales à 0
pour optimiser l'affichage et gérer les pluriels

D'aucuns ici savent ce que je pense de cette façon d'utiliser les années et mois en tant que unités mathématiques alors que ce ne sont pas des constantes !!!

 

[jmfmarques]

Bonjour Modeste geedee
Il est en effet bien de mettre cet aspect en exergue.
Mais il s'agit en l'occurrence de la volonté de déterminer une durée calendaire (un peu comme l'âge) et non une durée temporelle, du type que l'on doit utiliser dans des formules de calcul (salaires, etc...). Le résultat est donc, comme tu le constates, une chaîne de caractères et non une valeur numérique
Tu comprendras parfaitement la différence en comparant ce confinement avec une peine d'emprisonnement, qui est elle également exprimée en durée calendaire et non temporelle.