somme.si.ens à plusieurs conditions dans une même colonne

[patfin]

Bonjour à tous,

J'aimerais faire la somme d'une colonne selon plusieurs conditions. Cependant, dans une colonne, il y aurait deux conditions. Comment faire?

J'ai l'impression que ma syntaxe n'est pas bonne dans l'utilisation de la fonction imbriquée "ou".

Voici un fichier lié démontrant ce que j'aimerais.

en i2, j'aimerais avoir la somme de la colonne d sujet aux conditions suivantes:

1. La colonne b = conso
2. la colonne a = h2
3. et la colonne d est égale à rembrsmt_K ou z_refin_rembrsmt_K

Voici ce que j'ai fait:
=+SOMME.SI.ENS(D2😀35;B2:B35;"=conso";A2:A35;"="&H2;C2:C35;"="&OU(C2:C35="rembrsmt";C2:C35="z_refinrembrsmt"))

QQn pourrais me dire où est mon erreur et me donner la solution???

Merci

 

[Mytå]

Re : somme.si.ens à plusieurs conditions dans une même colonne

Salut le Forum

Essaye comme ceci :

=SOMME.SI.ENS(D2:D35;B2:B35;"=conso";A2:A35;"="&H2;C2:C35;{"=rembrsmt_K"."=z_refinrembrsmt"})

Mytå

 

[Amilo]

Re : somme.si.ens à plusieurs conditions dans une même colonne

Bonjour le forum, Myta, patfin,

Peut-être comme ceci si j'ai bien compris :

=SOMME(SOMME.SI.ENS(D2:D35;B2:B35;"=conso";A2:A35;H2;C2:C35;{"=rembrsmt_K";"z_refin_rembrsmt_K"}))

ou alors avec sommeprod :

=SOMMEPROD((D2:D35)*(A2:A35=H2)*(B2:B35="Conso")*((C2:C35="rembrsmt_k")+(C2:C35="z_refin_rembrsmt_k")))

Cordialement

 

[chris]

Re : somme.si.ens à plusieurs conditions dans une même colonne

Bonjour

Si la colonne C ne contient la mention "rembrsmt_K" que sous la forme rembrsmt_K ou z_refin_rembrsmt_K ou peut aussi utiliser "=*rembrsmt_K" pour le critère

=SOMME.SI.ENS(D2:D35;B2:B35;"=conso";A2:A35;H2;C2:C35;"=*rembrsmt_K")

 

[patfin]

Re : somme.si.ens à plusieurs conditions dans une même colonne

Merci à tous et à toutes!

Cela a fonctionné parfaitement.