Moteur de recherche sur EXCEL 2007

Sub Recherche(ByVal What As String) 'Code d'Hasco sur XLD
    Dim Sh As Worksheet
    Dim PlgRes As Range
    Dim t
    Dim i As Long, j As Long
    Dim Msq As String

    Application.ScreenUpdating = 0
    Msq = UCase("*" & What & "*")
    Set PlgRes = Sheets("Accueil").Range("ResultatsRecherche")
    PlgRes.Hyperlinks.Delete
    PlgRes.ClearContents
    PlgRes.Offset(-1).ClearContents
    PlgRes.Rows(1).Resize(, 7) = Array("Feuille", "TCPN", "Code Simel", "Désignation", "Codet", "Cdt", "Prix")
    Set PlgRes = Sheets("Accueil").Range("ResultatsRecherche")
    j = 2

    For Each Sh In ThisWorkbook.Worksheets
        With Sh
            If Sh.Name <> PlgRes.Parent.Name Then
                t = .Range(.Cells(9, 1), .Cells(.Rows.Count, 2)).Resize(, 6).Value
                For i = 1 To UBound(t, 1)
                    If UCase(t(i, 1)) Like Msq Or t(i, 2) Like Msq Or t(i, 3) Like Msq Then
                        PlgRes(j, 1) = Sh.Name
                        If IsEmpty(t(i, 1)) Then t(i, 1) = "Non Renseigné"
                        Sh.Hyperlinks.Add PlgRes(j, 2), "", "'" & Sh.Name & "'!" & Sh.Cells(8 + i, 1).Address, "Allez à " & t(i, 1), t(i, 1)
                        PlgRes(j, 3) = "'" & t(i, 2)
                        PlgRes(j, 4) = t(i, 3)
                        PlgRes(j, 5) = t(i, 4)
                        PlgRes(j, 6) = t(i, 5)
                        PlgRes(j, 7) = t(i, 6)
                        j = j + 1
                    End If
                Next i
            End If
        End With
    Next Sh
    Sheets("Accueil").Columns("I:R").Columns.AutoFit
    Range("I6:R6").Font.Size = 9
    Range("I7:Q37").Font.Size = 8
    Range("O7:O37").NumberFormat = "#,##0.00"
    Columns("J:J").HorizontalAlignment = xlLeft
    Range("I1").Select
End Sub