Microsoft 365 Recherche sommes de produits

[vince6941]

Bonjour à tous,

Nous avons "développé" un fichier excel de création d'offre. Dans celui-ci, j'ai plusieurs "ouvrages" comprenant tous plusieurs articles.
J'aimerais un résumé que je vais appeler "Bon de matériaux" que nous avons besoin pour réaliser tous les ouvrages.
Je m'explique, par exemple pour un ouvrage "prise de courant encastrée" j'ai besoin de 1 boite d'encastrement. Pour un ouvrage "prise double encastrée" j'ai besoin de 2 boites d'encastrement.
J'aimerais une page ou je pourrais retrouver
Boite d'encastrement : 3

En sachant qu'on crée les réf "Boite d'encastrement" directement dans l'ouvrage. On ne crée pas de liste...

Est-ce possible qu'avec une formule, cette liste soit automatique et que la quantité des références nécessaires le soit aussi?
Je vous joint un petit croquis de ce que je recherche.

D'avance merci pour votre aide...

Bon week-end!

 

[mapomme]

Bonjour @vince6941 ,

Uniquement avec Office 365.
Une seule formule en L9 :

=UNIQUE(FILTRE(F9:F9999;F9:F9999<>""))

Et une formule en M10 à recopier vers le bas :

=SI(L10="";"";SOMME.SI(F$9:F$9999;L10;H$9:H$9999))

Avec la modification suggérée ci-dessous par @job75 :
Une seule formule en L9 : =UNIQUE(FILTRE(F9:F9999;ESTNUM(H9:H9999)))

Et une formule en M9 à recopier vers le bas : =SI(L9="";"";SOMME.SI(F$9:F$9999;L9;H$9:H$9999))

Voir le fichier V1a.

nota : si besoin augmenter la valeur 9999.

 

[job75]

Bonjour vince6941, mapomme,

Pour toute version Excel formule matricielle classique en L9 :

=SIERREUR(INDEX(F:F;PETITE.VALEUR(SI(NON(NB.SI(L$8:L8;F$9:F$9999))*ESTNUM(H$9:H$9999);LIGNE(F$9:F$9999));1));"")

Edit : @mapomme au lieu de ta formule :

=UNIQUE(FILTRE(F9:F9999;F9:F9999<>""))

ne faut-il pas :

=UNIQUE(FILTRE(F9:F9999;ESTNUM(H9:H9999)))

A+

 

[mapomme]

Bonjour @job75 ,

Edit : @mapomme au lieu de ta formule :

=UNIQUE(FILTRE(F9:F9999;F9:F9999<>""))

ne faut-il pas :

=UNIQUE(FILTRE(F9:F9999;ESTNUM(H9:H9999)))

A+

Tu as raison, c'est beaucoup plus propre .
Je modifie mon premier message...

 

[vince6941]

Hello!
Un grand merci pour votre rapide retour!
Ca fonctionne nicekl dans mon fichier, sauf que j'ai été bête... J'ai pas précisé que le total des références nécessaires doit être multiplié par le nombre d'ouvrage à faire.
La formule que j'ai demandé, ça additionne tout les éléments de mon fichier...

Dans le fichier que j'ai envoyé, il faudrait que le total de câble soit multiplié par le nombre de prise à installer.

J'espère que j'arrive à me faire comprendre. Je remet l'exemple en annexe.

J'ai tenté des choses... Mais là, ca dépasse clairement mes compétences!

Merci encore

 

[mapomme]

Re,

J'ai pas précisé que le total des références nécessaires doit être multiplié par le nombre d'ouvrage à faire.

Un autre fichier avec une formule en G9 à recopier vers le bas: =SI(A9<>"";A9;G8)
Et une nouvelle formule en O9 à recopier vers le bas: =SI(N9="";"";SOMMEPROD( (G$9:G$19)*(H$9:H$19=N9)*(J$9:J$19)))

 

[vince6941]

Merci Mapomme!
Ca fonctionne super!

J'ai tenté le coup de faire une feuille2 (Bon de matériaux) dans laquelle je pourrais faire un filtre du matériel nécessaire en affichant tout sauf les références au nombre 0.
Je n'arrive pas à mettre la formule dans la feuille 2... Pourtant je l'ai retapé en changeant les chemins.
Est-ce normal? C'est une fonction qui doit être active dans la même feuille?

Bon dimanche et encore merci pour votre aide.

[EDIT]

C'est ok, j'y suis arrivé ça fonctionne!!!

Encore un grand merci pour votre aide... C'est magique.

Bonne dimanche!!!