Formule avec dates

[dedel74]

Bonjour à tous,
J'ai encore un problème avec une formule et j'aurai besoin de vos connaissances.
J'ai créé un tableau de suivi de visite :
- en colonne A : j'ai les dates de visite sous le format 01/09/2011
- en colonne E : j'ai différentes catégories de visites (critère1, critère2, critère3...)
Je souhaiterais avoir sur une autre feuille un tableau m'indiquant combien de visites ont été effectuées pour le critère 1 entre le 01/09/2011et le 30/09/2011 idem pour le critère 2 et idem pour le critère 3, etc...)

voila la formule que j'ai réalisé et qui ne fonctionne pas :
=SI(ET('NB VISITE CATEGORIE'!A2:A65535>=DATEVAL("1/9/2011");'(NB VISITE CATEGORIE'!A2:A65535<=DATEVAL("30/09/2011"));NB.SI('SUIVI DE VISITE'!E:E;'NB VISITE CATEGORIE'!A23);0)

Merci beaucoup de votre aide
dedel74

 

[Misange]

Re : Formule avec dates

Bonjour
=sommeprod((A1:A1000>=1/9/2011)*(A1:A1000<=30/9/2011)*(E1:E1000="critere1")
idem pour les deux autres critères

Attetnion à ne pas effectuer le calcul sur un nombre de lignes inutilement élevé. Si le nombre dans un tableau est appelé à augmenter, utiliser la fonction "transformer en tableau" qu'on trouve sur l'onglet accueil et qui permet de rajouter automatiquement des lignes dans un tableau en appliquant les formules dans chaque colonne

 

[dedel74]

Re : Formule avec dates

Merci pour vodra réponse,
je viens de faire un essai mais il m'indique toujours 0.
Y aurait il un problème au niveau du format date peut être ? Est ce que cela peut jouer?
Merci d'avance
dedel74

 

[Misange]

Re : Formule avec dates

joins un exemple ce sera plus facile

 

[JCGL]

Re : Formule avec dates

Bonjour à tous,

Peux-tu essayer :

=SOMMEPROD((A1:A1000>=DATEVAL("1/9/2011"))*(A1:A1000<=DATEVAL("30/9/2011"))*(E1:E1000="critere1"))

A+ à tous

 

[Victor21]

Re : Formule avec dates

Bonjour.

Plutôt que de rentrer les dates dans la formule sous le format 1/9/2011, ce qu'Excel traduit par 1 divisé par 9, divisé par 2011, deux solutions :
1° la date 1/9/2011 en cellule F1, la date 30/9/2011 en F2, et la formule devient :

=sommeprod((A1:A1000>=$f$1)*(A1:A1000<=$f$2)*(E1:E1000="critere1"))

2° la valeur de la date, soit (affichage standard )40787 pour la première, 40816 pour la seconde, et la formule devient :

=sommeprod((A1:A1000>=40787)*(A1:A1000<=40816)*(E1:E1000="critere1"))

Edit : bonjour, Jean-Claude🙂

 

[Monique]

Re : Formule avec dates

Bonjour,

Si la date est dans la formule :
=SOMMEPROD((A1:A1000>=--"1/9/2011")*(A1:A1000<=--"30/9/2011")*(E1:E1000="critere1"))

=SOMMEPROD((A1:A1000>="1/9/2011"*1)*(A1:A1000<="30/9/2011"*1)*(E1:E1000="critere1"))

=SOMMEPROD((A1:A1000>="1/9/11"*1)*(A1:A1000<="30/9/11"*1)*(E1:E1000="critere1"))

Si le critère date est de l’année en cours (mais faut peut-être pas exagérer) :
=SOMMEPROD((A1:A1000>="1/9"*1)*(A1:A1000<="30/9"*1)*(E1:E1000="critere1"))

 

[dedel74]

Re : Formule avec dates

Bonjour à tous,
Merci pour votre aide.
C'est parfait.
Merci beaucoup

dedel74