Fonction TROUVE CHERCHE associée à OU

[jalou]

Bonjour à tous
Je travaille sur un fichier contenant des milliers de lignes. J'essaye de prélever le premier mot de chaque cellule de la première colonne Le problème est que le premier mot est séparé du second soit par un "blanc" soit par un "_" (souligné) soit par un "-" (tiret) soit par un "/".
J'ai utilisé GAUCHE(B2;(TROUVE(" ";B2;1)-1)) mais cette formule n'est valable que pour le "blanc"
J'ai essayé de fusionner la recherche par GAUCHE(B8;(TROUVE(OU("_";"-";" ");B8;1)-1)) mais j'ai en retour le message d'erreur #VALEUR. La fonction CHERCHE donne le même résultat.
Je n'ai pas utilisé le "-"(moins) du pavé numérique mais le tiret de la touche "6". Sans résultat.
Pouvez-vous me donner un conseil sans passer par VBE SVP ?
Merci à tous
Jak

 

[chris]

Re : Fonction TROUVE CHERCHE associée à OU

Bonjour

=GAUCHE(B2;CHERCHE("@";SUBSTITUE(SUBSTITUE(SUBSTITUE(B2;" ";"@";1);"-";"@";1);"_";"@";1))-1)

 

[Modeste]

Re : Fonction TROUVE CHERCHE associée à OU

Bonjour jalou,

Il y a peut-être (sans doute 😱) plus simple, mais tu peux déjà tester:

=GAUCHE(B2;(MIN(SIERREUR(TROUVE(" ";B2;1);200);SIERREUR(TROUVE("-";B2;1);200);SIERREUR(TROUVE("_";B2;1);200)-1)-1))

... s'il n'y a aucun des 3 caractères dans certaines cellules, il faudra adapter ... tu nous diras ce qu'il en est?

[Edit:] Arfff, ben voilà, c'est confirmé: il y avait plus court!
Bises à chris et désolé pour le télescopage!

 

[R@chid]

Re : Fonction TROUVE CHERCHE associée à OU

Bonjour @ tous,
juste pour saluer mes chers amis
une matricielle, en C2 :

=GAUCHE(B2;MIN(SIERREUR(TROUVE({"-";"_";" "};B2);5^5))-1)

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas


@ + +

 

[jalou]

Re : Fonction TROUVE CHERCHE associée à OU

je vois que j'en apprend toujours avec Excel - Merci à tous !

 

[jalou]

Re : Fonction TROUVE CHERCHE associée à OU

Rachid dans ta formule peux-tu m'expliquer le "5^5" ?

 

[R@chid]

Re : Fonction TROUVE CHERCHE associée à OU

Re,
c'est 5 puissance 5
j'ai choisi de remplacer l'erreur par un grand nombre comme ça le min sera la valeur trouvée, tu peux remplacer par 255 ou la longueur maximale prévue dans les phrases.


@ + +

 

[jalou]

Re : Fonction TROUVE CHERCHE associée à OU

Merci R@chid,
Plus de question, Tout est clair
@+