Fonction SI qui identifie un mot dans une cellulaire et renvoie une valeur

[bouclesdor]

Bonjour,

Ça fait 2 jours que je cherche et sans succès alors je fais appel à vous les pros d'excel....

Au bureau j'ai un fichier dans lequel j'aimerais ajouter une formule qui reconnait un mot (collect) dans une cellule qui contient du texte mais je ne sais pas comment faire ma fonction SI mais en ne tenant pas compte des mots avant ou après "collect".

J'ai essayé avec des * avant et après "*collect*" et ça ne fonctionne pas je ne sais pas s'il y a d'autres symboles pour trouvé le mot peut importe ou il est situé dans le texte...

Voir ci joint le fichier (PS j'ai pris seulement les champs qui m'intéressait sinon le fichier était trop gros...)

Merci à l'avance de votre aide.
Bouclesdor

 

[Tibo]

Re : Fonction SI qui identifie un mot dans une cellulaire et renvoie une valeur

Bonsoir,

Essaye avec :

=SI(NB.SI(A2;"*collect*")>0;"CDN";"USD")

@+

 

[KenDev]

Re : Fonction SI qui identifie un mot dans une cellulaire et renvoie une valeur

Bonjour le fil,

.. et en incluant A2 ou A3

=SI(NB.SI(A2;"*collect*")>0;"CDN";SI(NB.SI(A3;"*collect*")>0;"CDN";"USD"))

Je ne savais pas qu'on pouvait inclure des caractères génériques avec nb.si.. 🙂 J'étais arrivé à :

=SI(SI(ESTERREUR(CHERCHE("collect";A2))=VRAI;0;CHERCHE("collect";A2))+SI(ESTERREUR(CHERCHE("collect";A3))=VRAI;0;CHERCHE("collect";A3))>0;"CND";"USD")

🙄 Trops long!

Cordialement

KD

 

[Tibo]

Re : Fonction SI qui identifie un mot dans une cellulaire et renvoie une valeur

Bonjour,

En reprenant l'idée de KenDev, on peut appliquer le NB.SI sur la plage de cellules A2:A3 :

=SI(NB.SI(A2:A3;"*collect*")>0;"CDN";"USD")

@+

 

[KenDev]

Re : Fonction SI qui identifie un mot dans une cellulaire et renvoie une valeur

Bonjour le fil,

En m'inspirant de l'amélioration de Tibo, je peux raccourcir ma solution :

=SI(ESTERREUR(CHERCHE("collect";CONCATENER(A2;".";A3)))=VRAI;"USD";"CDN")

(toujours trop long... )

Cordialement

KD

 

[hoerwind]

Re : Fonction SI qui identifie un mot dans une cellulaire et renvoie une valeur

Bonjour, salut Tibo et KenDev,

La dernière formule de Tibo peut aussi s'écrire comme suit :
=SI(NB.SI(A$2:A$3;"*collect*");"CDN";"USD")
Le >0 n'est pas nécessaire.
Si le résultat du NB.SI est égal à 0, cela équivaut à FAUX, toute autre valeur numérique équivaut à VRAI

Autre possibilité, qui "affiche" le résultat dans la cellule sans le "contenir" :
=NB.SI(A$2:A$3;"*collect*") au format personnalisé : [=0]"USD";"CDN"'
Si on fait référence à cette cellule dans une formule d'une autre cellule, ne pas oublier que la condition sera =0 ou >0

 

[bouclesdor]

Re : Fonction SI qui identifie un mot dans une cellulaire et renvoie une valeur

Un gros MERCI à vous tous!!

Enfin j'ai réussi à faire ma formule avec toutes vos réponses!! Vous êtes géniale!

Bonne journée,

Bouclesdor!