XL 2016 Recherche d'un mot dans une cellule et surlignage de la ligne

[Abi23]

Bonjour,
J'ai un listing de produits en colonne I, dont le mot"Petit-déjeuner", je précise qu'il est entouré dans la cellule d'autres mots.
Mon nombre de lignes change tous les jours.
Je voudrais donc chercher les lignes dont la cellule en colonne I contient "Petit-déjeuner" et surligner cette ligne en rose.
J'ai essayé plein de codes VBA mais sans succès.
J'y arrive pour des valeurs exactes mais pas dans une suite de mots.
Voici la formule que j'ai actuellement qui marche avec les valeurs exactes:

Dim i As Integer
Dim plage As Range
Dim Lig As Byte
With Sheets("Tri")

Sheets("Tri").Select

i = 2
While i < 100 'Cells(5, i) <> "" And
Lig = i
Set plage = .Range(Cells(Lig, 2), Cells(Lig, 9))
Select Case .Range("I" & i).Value
Case Is = "Petit-déjeuner"
plage.Interior.Color = RGB(255, 153, 204) 'Rose pour Inclus
Case Else
plage.Interior.ColorIndex = -4142 ' enlève la couleur
End Select

i = i + 1

Wend
End With

Merci d'avance !

 

[sylvanu]

Bonjour Abi,
Pourquoi ne pas le faire avec une MFC, ce serait plus simple.
Et donnez nous un petit fichier test, la aussi, ce sera plus simple.

 

[Abi23]

Bonjour sylvanu,
La macro fait partie d'une suite avec du tri de colonnes, de l'insertion de lignes, de la mise en page etc...
en ce qui concerne le fichier test, les données sont sensibles.
En I je peux avoir par exemple :

6 x Package Petit-déjeuner Prévente, 6 x Taxe de séjour

Je veux que ça me surligne la ligne car I4 contient Petit-déjeuner.

 

[sylvanu]

Re,
Un essai en PJ avec :

Sub TrouveChaine()
    Dim Chaine$, L%, Couleur, Rose
    Rose = RGB(255, 153, 204)
    Application.ScreenUpdating = False
    Chaine = "Petit-déjeuner"
    For L = 1 To Cells(Cells.Rows.Count, "I").End(xlUp).Row
        If Cells(L, "I") Like "*" & Chaine & "*" Then Couleur = Rose Else Couleur = xlNone
        Range("A" & L & ":I" & L).Interior.Color = Couleur
    Next L
End Sub

1- Un fichier test est un petit fichier sans données anonyme, ce qui évite au contributeur de le faire, et se rapproche de votre format.
2- Pour le code utilisez la balise </> c'est plus lisible. ( icone à droite de l'icone GIF )

 

[Abi23]

Merci sylvanu,
Très bien, je note pour la prochaine fois.
En tout cas ça marche nickel !
Merci pour cette intervention rapide !
Bonne soirée,