Fonction INDIRECT dans une formule conditionnelle

[BD62]

Bonjour à toutes et à tous.
Je découvre petit à petit les formules conditionnelles.
Je suis coincé en voulant dans ma formule conditionnelle ajouter le résultat d'une liste de choix.
Cette formule fonctionne
{=SOMME(SI(RESULTATS!$C$7:$C$40=E4;(RESULTATS!$D$7:$D$40)))+SOMME(SI(RESULTATS!$G$7:$G$40=E4;(RESULTATS!$H$7:$H$40)))}
mais celle-ci me retourne une erreur #valeur!
{=SOMME(SI(INDIRECT("RESULTATS!C"&O12):$C$40=E4;(INDIRECT("RESULTATS!D"&O12):$D$40)))...
O12 étant le résultat dépendant de ma liste de choix.
Je vous joins un extrait de mon fichier pour mieux comprendre.
D'avance merci de votre aide.

 

[Tibo]

Re : Fonction INDIRECT dans une formule conditionnelle

Bonjour,

Essaye avec ceci en F4 :

=SOMME(SI(INDIRECT("RESULTATS!C"&O12&":$C$445")=E4;(INDIRECT("RESULTATS!D"&O12&":$D$445"))))

Cela dit, pas testé, car je ne sais pas quel est le résultat attendu

@+

Edit :

A voir, mais il me semble que la matricielle n'est pas nécessaire. Un simple SOMME.SI pourrait (devrait) suffire :

=SOMME.SI(INDIRECT("RESULTATS!C"&O12&":$C$445");E4;INDIRECT("RESULTATS!D"&O12&":$D$445"))

Je te laisse tester.

@+

Re Edit :

Une autre approche avec la fonction DECALER : on suppose que tu as toujours 10 équipes et que tes tableaux sont toujours disposés les uns en dessous des autres, de façon régulière.

en F4 :

=SOMME.SI(DECALER(RESULTATS!$C$7;(CLASSEMENT!$E$1-1)*12;;(CLASSEMENT!$F$1)*12-2);$E4;DECALER(RESULTATS!$D$7;(CLASSEMENT!$E$1-1)*12;;10))

Grâce à cette formule, plus besoin des données en Feuil1, ni des formules en O12 et O18.

Toujours à tester

@+

 

[BD62]

Re : Fonction INDIRECT dans une formule conditionnelle

Merci à Tibo ça fonctionne très bien.
Edit: dès que j'aurais un peu de temps j'étudie tes solutions.
Merci encore à vous deux😱