faire clignoter des fleches 3d

[pancaspremium]

bonjour
j'essaie de trouver le moyen de faire clignoter les 2 fleches à côté des dates dans mon fichier annexé.

Problème est que les 2 fleches ne sont pas une celulle mais ce sont des signes 3D.

quelqu'un a une piste comment les faire clignoter en simultanée ?


merci à toutes et à tous d'avance
paulo

 

[Dranreb]

Re : faire clignoter des fleches 3d

Bonjour.

Ce code dans un module standard devrait faire l'affaire :

Option Explicit
Dim Temps As Date

Sub FaireClignoterLesFlèches()
AssumerClignotement
End Sub

Sub ArrêterLesClignotements()
Application.OnTime Temps, "AssumerClignotement", Schedule:=False
Feuil1.Shapes("Flèche gauche 1").Visible = True
Feuil1.Shapes("Flèche gauche 2").Visible = True
End Sub

Sub AssumerClignotement()
Feuil1.Shapes("Flèche gauche 1").Visible = Not Feuil1.Shapes("Flèche gauche 1").Visible
Feuil1.Shapes("Flèche gauche 2").Visible = Not Feuil1.Shapes("Flèche gauche 2").Visible
Temps = Now + TimeSerial(0, 0, 1)
Application.OnTime Temps, "AssumerClignotement"
End Sub

 

[pancaspremium]

Re : faire clignoter des fleches 3d

bonsoir DRANREB
merci pour ton retour et ta réponse

j'ai essayé d'insérer ta proposition dans l'onglet "visualiser le code" ce qui d'après ma compréhension devrait fonctionner mais rien ne bouge ??

peux tu me dire, ou carrément le faire dans mon exemple insérer ton script ou macro ?

désolé pour la terminologie sûrement éronée

bien à toi

 

[Dranreb]

Re : faire clignoter des fleches 3d

J'ai dit dans un module standard, et non pas dans un module objet.
Donc insérer un module et y coller le code.
Ensuite exécuter FaireClignoterLesFlèches.

 

[libellule85]

Re : faire clignoter des fleches 3d

Bonsoir pancasprenium, Dranreb, le forum,

Dranreb, ton code fonctionne à merveille mais comment faire pour lancer et arrêter les clignotements dans la même macro (1 clic pour démarrer et 1 clic pour arrêter).

D'avance merci

 

[Dranreb]

Re : faire clignoter des fleches 3d

Avec une seule procédure:

Sub MarcheArrêtClignotements()
If Temps = 0 Then AssumerClignotement: Exit Sub
Application.OnTime Temps, "AssumerClignotement", Schedule:=False
Feuil1.Shapes("Flèche gauche 1").Visible = True
Feuil1.Shapes("Flèche gauche 2").Visible = True
Temps = 0
End Sub

Après il faut soit l'affecter à un bouton de formulaire, soit la lancer depuis la procédure CommandButton1_Click d'un bouton ActiveX, dans le module de feuille cette fois.

 

[pancaspremium]

Re : faire clignoter des fleches 3d

Merci pour vos retours

je n'ai pas assez de connaissances pour effectuer ces manips
MON BUT est que la personne qui ouvre le fichier voit les flèches clignoter

donc pas de lancement d'une macro ou script par la personne même

est-ce possible ?

Si oui, est-ce que l'on peut l'insérer dans le fichier annexé pour que je suive la procédure ?
merci

 

[Dranreb]

Re : faire clignoter des fleches 3d

Dans ce cas gardez les deux procédures séparées et mettez dans le module ThisWorkbook :

Option Explicit

Private Sub Workbook_Open()
FaireClignoterLesFlèches
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
ArrêterLesClignotements
End Sub

 

[libellule85]

Re : faire clignoter des fleches 3d

Re Dranreb,

Un grand merci pour ton aide.

Bonne soirée

 

[pancaspremium]

ouvRe : faire clignoter des fleches 3d

Merci pour toutes les réponses et patience

je rends les armes, à aucun moment dans tous mes essais il n'y à eu... un seul clignotement.

C'est déroutant, mais je vais dès demain essayer de trouver un cours de formation adéquat pour que l'on m'explique cette manipulation. a maintes reprises dans ce forum l'on propose d'apposer un fichier avoir une solution proposée dans le fichier. Dans mon cas isolé cela semble compliqué :-(

meilleures salutations

 

[Dranreb]

Re : faire clignoter des fleches 3d

Bon. Dans ce classeur les flèches devraient clignoter dès l'ouverture si vous avez autorisé l'exécution des macros, ce qui peut ne pas être le cas si vous n'en avez jamais exécutées.

 

[pancaspremium]

Re : faire clignoter des fleches 3d

merci DRANREB

je vois dès à présent ou insérer les scripts
merci pour ton aide très appréciée
paulo