Décompte de mois (et/ou années)

[anthoYS]

Bonjour,

Je souhaite que selon la date de réalisation, soit projetté le nombre de mois qui ce sont écoulés. A savoir si l'on avait prévu l'acquisition en mars 2009 et qu'il a lieu en juin 2009, on fait apparaître 3 mois après.
Car la réalisation à eu lieu 3 mois après la date prévu. Et "avant", si la date de réalisation à eu lieu plus tôt que prévu.

Voyez le fichier joint ci-dessous.

Lien hypertexte car fichier même zippé trop lourd pour ce site

Merci, bonne fin de journée.

 

[Jiheme]

Re : Décompte de mois (et/ou années)

Bonjour Anthoys

Formule a mettre en I5 et tirer vers le bas

=SI(OU(F5="";H5="");"";SI(MOIS(F5)>MOIS(H5);MOIS(F5)-MOIS(H5)&" "&"mois"&" "&"avant";SI(MOIS(F5)=MOIS(H5);"comme prévu";SI(MOIS(F5)<MOIS(H5);MOIS(H5)-MOIS(F5)&" "&"mois"&" "&"après";""))))

Désolé, je viens de m'apercevoir que j'avais lu trop vite et pas pris en compte le cas >12

A+

 

[anthoYS]

Re : Décompte de mois (et/ou années)

Merci beaucoup.

 

[Jiheme]

Re : Décompte de mois (et/ou années)

Re à tous

Celle-ci me semble mieux correspondre à ton besoin, fais lui tous les essais possible et dis nous,

=SI(H5="";"";SI((F5)>(H5);MOIS(F5)-MOIS(H5)&" "&"mois"&" "&"avant";SI(FIN.MOIS(F5;0)=FIN.MOIS(H5;0);"comme prévu";SI(ET(MOIS(F5)<MOIS(H5);(H5-F5)<365);MOIS(H5)-MOIS(F5)&" "&"mois"&" "&"après";ENT(((H5-F5)/365))&" "&"an"&" "&(ENT(MOD(H5-F5;365)/30)&" "&"mois")))))

Je rajoute le fichier, au cas où cela aide quelqu'un ou mieux si les Maîtres es formules ont une meilleure solution.

A+

 

[anthoYS]

Re : Décompte de mois (et/ou années)

ok, nickel, encore mieux.

 

[C@thy]

Re : Décompte de mois (et/ou années)

Bonjour le fil,

Jiheme, je suis comme toi, à la recherche d'une meilleure solution,
mais je ne suis pas maître(sse) es formules,
j'ai essayé ceci :
(voir fichier joint)
mais ne marche pas tout à fait très bien je n'arrive pas à mettre "après"

 

[C@thy]

Re : Décompte de mois (et/ou années)

zut validé trop tôt,

si je mets 2 ans et 2 mois ça va pas bien non plus je n'affiche pas les mois...

Biz

C@thy

 

[Jiheme]

Re : Décompte de mois (et/ou années)

Bonjour Cathy Le forum

Je me demande si en voulant automatiser le pluriel de "an" on ne dépasse pas le nombre de SI.

De plus on ne peut pas utiliser "l'évaluation de formule" il mets #nom sitôt commencer, je pense à cause des fonctions FIN.MOIS, mais j'aimerais bien avoir un avis éclairé là dessus.

Du coup je reste avec mon "an(s)" qui à l'avantage de donner les bons chiffres.

A+

 

[C@thy]

Re : Décompte de mois (et/ou années)

Exact, Jiheme, si tu n'as pas coché Utilitaire d'analyse dans Outils Macros complémentaires il ne reconnait pas FIN.MOIS du coup il te met #NOM!

Quant au nombre de SI imbriqués tu as droit à 7, pour plus il faut remettre des parentèses et on peut en refaire 7. Ex. avec 7 et 6 SI:
=SI(C2<=6;SI(C2=1;"Janvier";SI(C2=2;"Février";SI(C2=3;"Mars";SI(C2=4;"Avril";SI(C2=5;"Mai";SI(C2=6;"Juin"))))));SI(C2=7;"Juillet";SI(C2=8;"Août";SI(C2=9;"Septembre";SI(C2=10;"Octobre";SI(C2=11;"Novembre";SI(C2=12;"Décembre")))))))

J'avais fait une erreur de position de parenthèses,
comme ça, ça fonctionne mieux :
=SI(H2="";"";SI((F2)>(H2);MOIS(F2)-MOIS(H2)&" mois avant";SI(FIN.MOIS(F2;0)=FIN.MOIS(H2;0);"comme prévu";SI(ET(MOIS(F2)<MOIS(H2);(H2-F2)<365);MOIS(H2)-MOIS(F2)&" mois après";ENT((H2-F2)/365)&" an"&SI(ENT((H2-F2)/365)>1;"s ";" ")&SI(ENT(MOD(H2-F2;365)/30)>0;"et "&ENT(MOD(H2-F2;365)/30)&" mois";"")&" après"))))

Cela dit, tu peux éviter ton FIN.MOIS en utilisant TEXTE :
=SI(H2="";"";SI((F2)>(H2);MOIS(F2)-MOIS(H2)&" mois avant";SI(TEXTE(F2;"ma")=TEXTE(H2;"ma");"comme prévu";SI(ET(MOIS(F2)<MOIS(H2);(H2-F2)<365);MOIS(H2)-MOIS(F2)&" mois après";ENT((H2-F2)/365)&" an"&SI(ENT((H2-F2)/365)>1;"s ";" ")&SI(ENT(MOD(H2-F2;365)/30)>0;"et "&ENT(MOD(H2-F2;365)/30)&" mois";"")&" après"))))

Comme ça, pas besoin de cocher et même nombre de caractères.

Bises et bonne journée

C@thy

 

[Tibo]

Re : Décompte de mois (et/ou années)

Bonjour ma chère Cathy,

Pas lu tout le fil ni regardé les fichiers.

Pour la 1ère formule de ton dernier fil, je te propose ceci :

=SI(C2="";"";TEXTE("1/"&C2;"mmmm"))

Retourne le mois en toutes lettres

Pas regardé les autres formules. Je repasserais dans la journée (si j'ai le temps)

Bonne journée à toi

@+

 

[C@thy]

Re : Décompte de mois (et/ou années)

Coucou Tibo, bonjour à toi.

Un des super maîtres ès formules est là!...

Il fait beau à Maubeuge??? Parcequ'à Paris, c'est la tristesse : grisaille et pluie, et pas chaud brrrr....

Bises

C@thy

 

[C@thy]

Re : Décompte de mois (et/ou années)

Pour la formule, tu as super raison, tibo, ce n'est pas la plus courte, mais juste un exemple bidon que j'utilise pour montrer qu'on peut faire plus de 7 SI dans une formule.

Pendant que je te tiens...
comment ferait-on l'inverse?
(à part =SI(SI(E2="Janvier";1;SI(E2="Février";2;SI(E2="Mars";3;SI(E2="Avril";4;SI(E2="Mai";5;SI(E2="Juin";6;0))))));SI(E2="Janvier";1;SI(E2="Février";2;SI(E2="Mars";3;SI(E2="Avril";4;SI(E2="Mai";5;SI(E2="Juin";6;0))))));SI(E2="Juillet";7;SI(E2="Août";8;SI(E2="Septembre";9;SI(E2="Octobre";10;SI(E2="Novembre";11;SI(E2="Décembre";12;"Gné?"))))))) qui est plutôt looooonnnnnnnnng et qui est mon 2ème exemple d'imbrication de + de 7 fonctions SI.

je créerais bien la liste des mois, puis =EQUIV(E2;ListeMois;0). Tu vois autrechose???

Big Bisous

C@thy

 

[Tibo]

Re : Décompte de mois (et/ou années)

re bonjour Cathy,

En un peu plus court 😛 :

(à la condition que les mois soient écrits sans faute (je pense aux mois avec accents) :

=MOIS("1/"&A1)

On peut ajouter un test pour A1 vide ou ne contenant pas un nom de mois.

@+

P.S. : le temps à Maubeuge ? : à mon avis pareil qu'à Paris 😱

@+

 

[C@thy]

Re : Décompte de mois (et/ou années)

Super BRAVOOOOOOO!!!

Et désolée pour le temps!

Bisous

C@thy

 

[hoerwind]

Re : Décompte de mois (et/ou années)

Bonjour,

Avec un peu de retard, une proposition de formule en pièce jointe.

Les années et les mois ne s'affichent pas s'ils sont égaux à 0
Le "an" devient "ans" si supérieur à 1
Le "et" ne s'affiche que si nécessaire.

Le principe retenu est de ne pas tenir compte des "avant" et "après" lors des calculs (voir MIN et Max dans DATEDIF) et de n'appliquer ces termes qu'en fin de formule.