Creer une feuille nommee selon un model

[Ilino]

Bonsoir Forum
Je souhaite créer des feuilles a partir de la feuille (Etudes) selon un model (masqué) si la cellule de A12 est non vide alors créer une feuille nommée N° 1 du 12.03.2014 et ainsi de suite a chaque fois que je remplis la colonne A du mon tableau j’ai une feuille
A+

 

[Ilino]

Re : Creer une feuille nommee selon un model

Bonsoir Forum
est ce que mon souci est claire ?
merci
A+

 

[Dull]

Re : Creer une feuille nommee selon un model

Salut Ilino, le Forum

Avec ce que j'ai compris déclenchement de la copie de la feuille au remplissage de la ColR

Private Sub Worksheet_Change(ByVal Target As Range)
Dim DerLig As Long, i As Long ' Déclaration des Variable
Application.ScreenUpdating = False ' Empeche le rafraichissement de l'écran
DerLig = Feuil1.Range("A" & Rows.Count).End(xlUp).Row 'recherche de la dernière ligne non vide de la colA
Sheets("Model").Visible = xlSheetVisible 'rend visible la feuille Model
If Not Intersect(Feuil1.Range("R" & DerLig), Target) Is Nothing Then 'si changement dans la dernière cellule de la ColR
Sheets("Model").Copy After:=Feuil1 'Copy de la feuille Model
    With ActiveSheet ' avec la nouvelle feuille
        .Name = Sheets("Etudes").Range("A11") & " " & Sheets("Etudes").Range("A" & DerLig) & " -" & Replace(Sheets("Etudes").Range("G" & DerLig), "/", "-")
        'la renomme avec les cellules données
        .Range("E2") = Sheets("Etudes").Range("A" & DerLig) 'met en E2 la cellule de la colA
        .Range("G2") = Sheets("Etudes").Range("G" & DerLig) 'met en EG2 la cellule de la colG
        .Range("O2") = Sheets("Etudes").Range("P" & DerLig) & " " & Sheets("Etudes").Range("R" & DerLig) 'met en O2 la cellule de la ColP et ColR
    End With ' fin de With
End If ' fin de Condition
Sheets("Model").Visible = False 'rend invisible la feuille Model
Application.ScreenUpdating = True 'Remet le raffraichissement de l'écran
End Sub

Attention feuille Model Cachée

Bonne Journée

 

[Ilino]

Re : Creer une feuille nommee selon un model

BONJOUR DULL
GRAZIE c'est super , Pblm résolut
A+

 

[Ilino]

Re : Creer une feuille nommee selon un model

Bonsoir Forum
dans le meme exemple de notre ami Dull, je souhaite completer mon code par des liens de la feuille " Etudes" vers les autres feuilles crées par un double clique sur les cellules; exemple si je clique sur la cellule A12 alors aller vers la feuille crée ( N° 1 - 12 03 2014 ) et ainsi de suite
A+

 

[Dull]

Re : Creer une feuille nommee selon un model

Salut Ilino, le Forum

Peut être comme cela au Double click dans la ColA
Code à copier dans le Module de la feuille "Etudes"

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim DerLig As Long, X As Variant
DerLig = Feuil1.Range("A" & Rows.Count).End(xlUp).Row
If Not Intersect(Range("A12:A" & DerLig), Target) Is Nothing Then
Cancel = True
X = Range("A11") & " " & Range("A" & Target.Row) & " -" & Replace(Range("G" & Target.Row), "/", "-")
Sheets(X).Activate
End If
End Sub

Bonne Journée

 

[Ilino]

Re : Creer une feuille nommee selon un model

Bonjour Dull
MERCI CA FONCTIONNE TRES BIEN ..... PBLM RESOLUT
BONNE SOIREE