XL 2021 Exporter des données vers une autre feuille...

[Constantin]

Bonjour à tous,
Dans le fichier joint (liste d'adhérents d'une association), un adhérent souhaite quitter l'association.
Il me faut alors copier les données de la ligne le concernant (colonnes A à M) dans le fichier départ à la suite des autres départs dans la colonne G (donc dans le cas présent en G14)
A ce jour, je le fais manuellement en me trompant une fois sur deux. J'ai donc fait une macro (macro1) qui s'active avec le bouton rouge. Évidemment, j'ai fait cette macro avec l'enregistreur donc il ne sait faire que sélectionner les cellules A à M de la ligne 18... Serait-il possible de créer une macro qui prenne en compte la ligne saisie (qui apparait en bleu) et copier ces données automatiquement dans la feuille départs dans le 1er G libre (ici G14) ?
Ci-dessous le code de la macro. Fichier en PJ.
Bien cordialement,
Sub Macro1()
'
' Macro1 Macro
'

'
Range("A18:M18").Select
Selection.Copy
Sheets("départs").Select
ActiveCell.Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
End Sub

 

[sylvanu]

Bonjour Constantin,
Un essai en PJ avec :

Sub Macro1()
Dim L%, DL%
L = Selection.Row                                                               ' Ligne sélectionnée
With Sheets("départs")
    DL = 1 + .Cells(Rows.Count, "G").End(xlUp).Row                              ' Première ligne vide
    .Range(.Cells(DL, "G"), .Cells(DL, "S")) = Range("A" & L & ":M" & L).Value  ' Copie des valeurs
End With
End Sub

Ensuite que faire après la copie ? On supprime la ligne dans base de données ou on laisse ainsi ?

 

[Constantin]

D'abord un grand merci ! C'est tout bonnement super...
Je vais essayer d'ajouter un MsgBox (oui, non) parce que la macro va tellement vite qu'une maladresse de saisie pourrait faire des dégâts...
Dans l'immédiat je préfère ne pas enlever les adhérents en partance automatiquement.
Je vais aussi d'ajouter un Range final qui cible le fichier départs. J'ai réussi à comprendre le code, inutile de dire que je n'y serai pas arrivé.
Bon, je m'y mets et comme d'habitude, je crie si je n'y arrive pas (à mon avis, je vais galérer avec le Msgbox)
Remarque : Il n'est pas question de supprimer la ligne (ce qui supprimerait un jardin mais uniquement effacer le contenu des cellules (colonnes E à CS)
A bientôt...

 

[Constantin]

J'ai pondu ceci mais ça plante
Sub Macro1()
Dim L%, DL%
L = Selection.Row ' Ligne sélectionnée
With Sheets("départs")
DL = 1 + .Cells(Rows.Count, "G").End(xlUp).Row ' Première ligne vide
.Range(.Cells(DL, "G"), .Cells(DL, "S")) = Range("A" & L & ":M" & L).Value ' Copie des valeurs
End With
Sheets("départs").Select
Range(.Cells(DL, "G")).Select
End Sub
Au secours !

 

[sylvanu]

ajouter un MsgBox (oui, non) parce que la macro va tellement vite qu'une maladresse de saisie pourrait faire des dégâts

Testez cette PJ avec :

Sub Macro1()
Dim L%, DL%, Rep$
L = Selection.Row                                                               ' Ligne sélectionnée
Rep = MsgBox("Voulez vous exporter la ligne " & L & " concernant " & Cells(L, "E") & " " & Cells(L, "F") & " ?", _
        vbExclamation + vbYesNo, "Demande de confirmation.")
If Rep = vbNo Then Exit Sub
With Sheets("départs")
    DL = 1 + .Cells(Rows.Count, "G").End(xlUp).Row                              ' Première ligne vide
    .Range(.Cells(DL, "G"), .Cells(DL, "S")) = Range("A" & L & ":M" & L).Value  ' Copie des valeurs
End With
End Sub

Cela donne :

Une bonne aide pour les msgbox :

VBA - Boîte de Dialogue Oui-Non (Msgbox)

Ce tutoriel explique comment utiliser la fonction VBA MsgBox pour afficher des boîtes de message aux utilisateurs (y compris la boîte de message YesNo).

www.automateexcel.com

 

[sylvanu]

Range(.Cells(DL, "G")).Select

Supprimez le point avant Cells.
Le point est à utiliser lors d'un with pour référencer l'origine.
Comme ici vous avez selectionner la feuille Départ, il n'a pas de raison d'être.
Ensuite la syntaxe est :

Range("G" & DL).Select
ou
Cells(DL, "G").Select

Mais pas le mélange des deux.

 

[Constantin]

Je ne pouvais pas rêver mieux !
Encore un point pour le Dr Sylvanu.
A bientôt