combobox sans doublon

[fosters]

Bonsoir a tous,

A tous les gens du forum a tous ceux qui l'anime je vous présente mes meilleurs vœux pour cette nouvelle année.

Probablement que la demande a déjà été faite, mais je souhaite savoir comment avoir les donnée d'une plage dans Excel, retrouver ces données dans une combobox sans en avoir les doublons.

Merci pour vos aides.

Cordialement

Fosters

 

[Cousinhub]

Re : combobox sans doublon

Bonjour,

Probablement que la demande a déjà été faite

Ben, disons qu'en tapant "combobox sans doublons" dans l'outil de recherche, on trouve en gros 160 réponses....

Notamment celle de Boisgontier (voir son site), qui permet de plus de trier par ordre alphabétique les valeurs de ton combobox.

Attention, pour que ce code fonctionne sur ton exemple, il faut que tu effaces le "RowSource" nommé "NOM" dans les propriétés de ton "Combobox1".

Private Sub UserForm_Initialize()
   Set MonDico = CreateObject("Scripting.Dictionary")
   For Each c In Range([A6], [A65000].End(xlUp))
     If c.Value <> "" Then MonDico.Item(c.Value) = c.Value
   Next c
   temp = MonDico.items
   Call Tri(temp, LBound(temp), UBound(temp))
   Me.ComboBox1.List = temp
End Sub

Sub Tri(a, gauc, droi) ' Quick sort
  ref = a((gauc + droi) \ 2)
  g = gauc: d = droi
  Do
     Do While a(g) < ref: g = g + 1: Loop
     Do While ref < a(d): d = d - 1: Loop
     If g <= d Then
        temp = a(g): a(g) = a(d): a(d) = temp
        g = g + 1: d = d - 1
     End If
   Loop While g <= d
   If g < droi Then Call Tri(a, g, droi)
   If gauc < d Then Call Tri(a, gauc, d)
End Sub

Pense à l'outil de recherche....😉

Bonne journée

 

[fosters]

Re : combobox sans doublon

Bonjour bhbh,

Merci pour ta réponse, j'avoue ne pas avoir pensé à l'outil de recherche.

Bonne journée a toi aussi.

Fosters