Besoin d'aide pour finaliser ma formule

Dugenou

XLDnaute Barbatruc

• 27 Août 2013

• #2

Re : Besoin d'aide pour finaliser ma formule

Bonjour,
Tu as donc deux critères : la valeur CP et le N° du jour dans la semaine.
Pour faire le calcul sur une plage et avec un double SI il faut une formule matricielle. (impossible d'utiliser sommeprod avec joursem comme critère).
Les formules matricielles ne sont pas possibles dans des cellules fusionnées.
donc : dé fusionner W7 puis en w7 :

Code:

=SI($H$4="1 - SD";SOMME(SI($G$15:$AN$45="CP";SI(JOURSEM($E$15:$AL$45;2)>=6;2,5;1);0));NB.SI($E$15:$AN$45;"CP"))

à valider par ctrl+majtemp+enter

voir pj
Cordialement

 

Pièces jointes

• fenecpointage.xls

  97 KB · Affichages: 48

Vote positif 0 Vote négatif

fenec

XLDnaute Impliqué

• 27 Août 2013

• #3

Re : Besoin d'aide pour finaliser ma formule

Bonjour Dugenou

Merci pour ton aide cela fonctionne mais sans vouloir abuser encore besoin de tes lumières, en effet ayant en "H4" 3 tournantes pour le SD.
Est-il possible de combiner les tournantes afin que ta formule fonctionne en fonction de la tournante sélectionnée ?

J’ai essayé comme ceci mais la réponse est : FAUX

Code:

=SI($H$4="SD"; SI($H$4="1 - SD"; SI($H$4="2 - SD";SOMME(SI($G$15:$AN$45="CP";SI(JOURSEM($E$15:$AL$45;2)>=6;2,5;1);0));NB.SI($E$15:$AN$45;"CP"))

Et comme ceci mais sans plus de succès

Code:

=SI($H$4="SD";SOMME(SI($G$15:$AN$45="CP";SI(JOURSEM($E$15:$AL$45;2)>=6;2,5;1);0));NB.SI($E$15:$AN$45;"CP") ;SI($H$4="1 - SD";SOMME(SI($G$15:$AN$45="CP";SI(JOURSEM($E$15:$AL$45;2)>=6;2,5;1);0));NB.SI($E$15:$AN$45;"CP");SI($H$4="2 - SD";SOMME(SI($G$15:$AN$45="CP";SI(JOURSEM($E$15:$AL$45;2)>=6;2,5;1);0));NB.SI($E$15:$AN$45;"CP"))))

Cordialement

 

Vote positif 0 Vote négatif

Dugenou

XLDnaute Barbatruc

• 27 Août 2013

• #4

Re : Besoin d'aide pour finaliser ma formule

Bonjour,
Que faut-il faire pour 2-SD ? je ne vois pas de différence avec le 1-SD dans tes formules ! Dans ce cas on pourrait réunir les 2 possibilités.
Pour Modeste : j'ai seulement testé une formule sommeprod en mettant joursem(plage;2)>=6 ai j'ai eu le résultat #valeur : je n'ai pas cherché plus loin. Je vais creuser.
Edit : j'ai creusé ; dans le cas de ce fichier le joursem (e15:an45 ..) renvoie des "#valeur" pour les plages qui ne sont pas des dates. Donc on peut bien utiliser sommeprod et joursem, mais pas dans ce cas car il faudrait faire le calcule plage de date par plage de date.

 

Pièces jointes

• fenecpointageV2.xls

  103 KB · Affichages: 42

Dernière édition: 27 Août 2013

Vote positif 0 Vote négatif

Modeste

XLDnaute Barbatruc

• 27 Août 2013

• #5

Re : Besoin d'aide pour finaliser ma formule

Bonsoir,

Dugenou à dit:

Pour Modeste [...] j'ai creusé [...]

Cliquez pour agrandir...

🙂 Et bien, merci pour les fouilles! 😀

 

Vote positif 0 Vote négatif

fenec

XLDnaute Impliqué

• 27 Août 2013

• #6

Re : Besoin d'aide pour finaliser ma formule

Bonsoir Dugenou

Une fois encore merci tu as parfaitement compris mon désir, à savoir réunir les deux possibilités.
Je suis même allé plus loin en réunissant les trois en fonction de la tournante que j’occupe.
Tu as raison pas de différence dans les formules simplement la tournante à savoir SD, 1 – SD ou 2 – SD mais le résultat dois être le même pour les trois. Dans ta première solution si je changeais de tournante exemple 2 – SD, j’obtenais 2 et non 3.5

Code:

=SI(OU($H$4="SD";$H$4="1 - SD";$H$4="2 - SD");SOMME(SI($G$15:$AN$45="CP";SI(JOURSEM($E$15:$AL$45;2)>=6;2.5;1);0));NB.SI($E$15:$AN$45;"CP"))

Cordialement
Bonne fin de soirée

Philippe

 

Vote positif 0 Vote négatif

fenec

XLDnaute Impliqué

• 27 Août 2013

• #7

Re : Besoin d'aide pour finaliser ma formule

re,

par contre pas tout compris par rapport à Modeste

Edit : j'ai creusé ; dans le cas de ce fichier le joursem (e15:an45 ..) renvoie des "#valeur" pour les plages qui ne sont pas des dates. Donc on peut bien utiliser sommeprod et joursem, mais pas dans ce cas car il faudrait faire le calcule plage de date par plage de date.

Cliquez pour agrandir...

si tu veux bien m'éclairer ca peux servir

cordialement

Philippe

 

Vote positif 0 Vote négatif

Dugenou

XLDnaute Barbatruc

• 28 Août 2013

• #8

Re : Besoin d'aide pour finaliser ma formule

Bonjour,
S'il n'y a pas de différence de résultat entre les 3 "tournantes" : il est inutile de faire le test !
cela donne donc :

Code:

=SOMME(SI($G$15:$AN$45="CP";SI(JOURSEM($E$15:$AL$45;2)>=6;2,5;1);0))

Toujours en matriciel.
Pour le petit mot à Modeste : j'avais écrit

il est impossible de faire un joursem dans un sommeprod

Cliquez pour agrandir...

et c'est faux comme Modeste me l'a justement fait remarquer en privé.
Cordialement

 

Pièces jointes

• fenecpointageV3.xls

  97 KB · Affichages: 39

Vote positif 0 Vote négatif

fenec

XLDnaute Impliqué

• 28 Août 2013

• #9

Re : Besoin d'aide pour finaliser ma formule

Bonjour Dugenou,le forum

Encore merci problème résolu, me permettrais de revenir si problème.

j'étais parti au départ sur sommeprod mais sans joursem donc normal que je n'aboutissais pas.

D'ou ma demande d'aide.

Sans abuser, pourrais tu me montrés par sommeprod et joursem, cela me permettrais encore d'apprendre.

J'apprend énormément grace à vous, un grand merci au forum.

Cordialement

Philippe

 

Vote positif 0 Vote négatif

Dugenou

XLDnaute Barbatruc

• 29 Août 2013

• #10

Re : Besoin d'aide pour finaliser ma formule

Bonjour,
en pj exemple avec sommeprod et joursem mais seulement pour janvier. la formule n'est pas plus simple mais elle n'est pas matricielle

Code:

=SOMMEPROD(($G$15:$G$45="CP")*(JOURSEM($E$15:$E$45;2)>=6)*2,5)+SOMMEPROD(($G$15:$G$45="CP")*(JOURSEM($E$15:$E$45;2)<6)*1)

Qaund on veut traiter tout le tableau d'un coup avec

Code:

=SOMMEPROD(($G$15:$AN$45="CP")*(JOURSEM($E$15:$AL$45;2)>=6)*2,5)+SOMMEPROD(($G$15:$AN$45="CP")*(JOURSEM($E$15:$AL$45;2)<6)*1)

on a un joli ##### car le joursem sur les colonnes sans dates renvoie des erreurs et le sommprod essaye de les traiter (alors que dans la formule de la v3 le si permet de ne traiter que les valeurs sans erreurs)

Cordialement

 

Pièces jointes

• fenecpointageV4.xls

  97 KB · Affichages: 39

Vote positif 0 Vote négatif

Modeste

XLDnaute Barbatruc

• 29 Août 2013

• #11

Re : Besoin d'aide pour finaliser ma formule

Bonjour,

Comme je suis en partie responsable des "fouilles" entreprises par Dugenou, je peux tenter d'expliquer:
Si tu écris "=SOMMEPROD((G15:G45="CP")*((JOURSEM($E$15:$E$45;2)>5)*2,5))", tu obtiendras bien comme résultat le nombre de jours de week-end, en janvier 2013, pour lesquels "CP" est renseigné, multiplié par 2.5
On aurait donc ici déjà un souci pour comptabiliser, en plus, les "CP" pour les autres jours de la semaine.
Au pire, "=SOMMEPROD((G15:G45="CP")*((JOURSEM($E$15:$E$45;2)>5)*2,5))+SOMMEPROD((G15:G45="CP")*((JOURSEM(E15:E45;2)<6)))" permettrait de s'en sortir (mais ça devient un peu plus long!)

Là où ça ne va plus du tout, c'est quand tu essayes de couvrir une plage plus large que la seule colonne E, avec la fonction JOURSEM: comme la colonne F contient des formules qui renvoient des guillemets vides ou d'autres valeurs de type texte, JOURSEM renvoit un message d'erreur ... et en multipliant une matrice de {VRAI;VRAI;VRAI; ...} par une autre matrice qui contiendrait ne fût-ce qu'un seul #VALEUR!, le résultat sera #VALEUR! aussi!
Avec les SI imbriqués, utilisés par Dugenou, je suppose qu'on peut dire que le second SI n'est évalué que si le premier est vrai ... ce qui fonctionne parfaitement dans ton fichier.

Conclusion, rien n'interdit de combiner les fonctions SOMMEPROD et JOURSEM, mais dans le cas présent, ça ne fonctionne absolument pas!

Edit: Arfff! désolé pour la collision, Dugenou 😱

 

Vote positif 0 Vote négatif

Dugenou

XLDnaute Barbatruc

• 29 Août 2013

• #12

Re : Besoin d'aide pour finaliser ma formule

Salut Modeste
Je dirais volontiers que les grands esprits se rencontrent si cela n'allait pas à l'encontre de ton pseudo !

 

Vote positif 0 Vote négatif

Modeste

XLDnaute Barbatruc

• 29 Août 2013

• #13

Re : Besoin d'aide pour finaliser ma formule

Re,

Dugenou à dit:

Je dirais volontiers que les grands esprits se rencontrent si cela n'allait pas à l'encontre de ton pseudo !

Cliquez pour agrandir...

😀😀😀 ... et venant de quelqu'un dont le pseudo est Dugenou, ça craint 😉
trois messages d'écart entre nous, en plus! 😱

 

Vote positif 0 Vote négatif