VBA Excel: utilisation de DoCmd.CopyObject

[Christian22]

Bonjour à tous,

je souhaite utiliser dans un programme VBA excel03 l'instruction DoCmd.CopyObject pour copier une table access03 d'une base vers une autre base.

Connaissez vous la syntaxe à employer? avez vous des exemples de code?

Merci d'avance

 

[Compte Supprimé 979]

Re : VBA Excel: utilisation de DoCmd.CopyObject

Bonjour Christian22,

Pour faire ce que tu souhaites, voici le code

Sub CopieTbl()
  Dim ApAcc As Object
  Dim VPathBdDDes As String ' Base de données de destination
  Dim NouvNomTbl As String ' Nouveau nom table copiée, a laisser vide si même nom
  Dim NomTblSource As String  ' Nom de la table source
  Dim VPathBdDSce  ' Chemin complet de la BdD SOURCE
  ' Créer une instance d'ACCESS
  Set ApAcc = CreateObject("Access.Application")
  ' Définir le chemin d'accès de la BdD SOURCE et ouvrir celle-ci
  VPathBdDSce = "D:\CheminBase\BdDSource.mdb"
  ApAcc.OpenCurrentDatabase VPathBdDSce
  ' Définir le chemin d'accès de la BdD Destination
  VPathBdDDes = "C:\CheminBase\BdDDestination.mdb"
  ' Définir le nom de la table SOURCE à copier
  NomTblSource = "TblSource"
  ' Définir si on le souhaite le nouveau nom de la table copiée
  NouvNomTbl = ""
  ' Lancer la commande de copie
  ApAcc.DoCmd.CopyObject DestinationDatabase:=VPathBdDDes, NewName:=NouvNomTbl, Sourceobjecttype:=acTable, SourceObjectName:=NomTblSource
  ' Fermer la BdD SOURCE
  ApAcc.CloseCurrentDatabase
  ' Quitter l'instance d'Access
  ApAcc.Quit
  ' Vider la variable mémoire
  Set ApAcc = Nothing
End Sub

Essaye ça 😉

A+

 

[Christian22]

Re : VBA Excel: utilisation de DoCmd.CopyObject

Merci Bruno,

cela fonctionne parfaitement!

+