Microsoft 365 Userform avec liste déroulante et réslutat

Pounet95 à dit:

Bonjour,
Ca fait plaisir d'avoir un retour. Ce n'est hélas pas toujours le cas !
Le principal est que la base soit posée et que l'appropriation se fasse.

La cellule à cibler est celle de la colonne M ligne "ligPays"
Pour cela j'ai modifié ligpays en ligpays(3) et créé une variable cible de type Range
Reste à la faire "ressortir" dans le tableau
Bonne continuation
PS : le module 3 ne sert à rien: il a été créé lors d'un enregistrement de macro. Il peut être supprimé.

VB:

Option Explicit

Dim strPays             As String
Dim strType             As String
Dim strMoteur           As String
Dim strFournisseur(3)   As String
Dim nbJours             As Integer


Sub Calculs()
    Dim strPays         As String
    Dim ligPays(3)      As Long
    Dim CoûtMoyenTot(3) As Double
    Dim CoûtMoyenMIN    As Double
    Dim i               As Integer          'indice de boucle
    Dim j               As Integer          'idem
    Dim cible           As Range            'cellule cible
   
    strFournisseur(1) = "RentaCar"
    strFournisseur(2) = "EuropeCar"
    strFournisseur(3) = "Hertz"

    On Error Resume Next
    Application.CutCopyMode = False
   
    With UserForm1
        strPays = .Controls("combo_Pays").Value
        strMoteur = .Controls("combo_Moteur").Value
        strType = .Controls("combo_Type").Value
        nbJours = Val(.Controls("txt_nb_Jours").Text)
    End With
   
    'pour chaque Loueur,mettre à jour la ligne correspondant au Pays
    For i = 1 To 3
        Range("Tarifs_" & strFournisseur(i)).Select
        ligPays(i) = Selection.Find(What:=strPays, After:=ActiveCell, LookIn:=xlValues, LookAt:=xlWhole, _
                        SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False).Row
        'Mettre les valeurs dans les cellules correspondantes au pays
        'Coût véhicule choisi en fonction du carburant moteur
        Select Case strMoteur
        Case "Essence"
            'et en fonction du type Berline ou Coupé
            If strType = "Berline" Then
                Range("I" & ligPays(i)) = Range("C" & ligPays(i))
            Else
                Range("I" & ligPays(i)) = Range("D" & ligPays(i))
            End If
        Case "Electrique"
            'et en fonction du type Berline ou Coupé
            If strType = "Berline" Then
                Range("I" & ligPays(i)) = Range("E" & ligPays(i))
            Else
                Range("I" & ligPays(i)) = Range("F" & ligPays(i))
            End If
        Case "Diesel"
            'et en fonction du type Berline ou Coupé
            If strType = "Berline" Then
                Range("I" & ligPays(i)) = Range("G" & ligPays(i))
            Else
                Range("I" & ligPays(i)) = Range("H" & ligPays(i))
            End If
        End Select
        'Nombre de jours de location
        Range("J" & ligPays(i)) = nbJours
        'Récupère le coût moyen
        CoûtMoyenTot(i) = Range("M" & ligPays(i))
    Next i
    'Meilleure offre
    'Le MIN de chacune des valeurs MIN du coût moyen total des loueurs
    CoûtMoyenMIN = 99999
    For i = 1 To 3
        If CoûtMoyenTot(i) < CoûtMoyenMIN And CoûtMoyenTot(i) > 0 Then
            CoûtMoyenMIN = CoûtMoyenTot(i)
            j = i
            Set cible = Range("M" & ligPays(j))
        End If
    Next i
    UserForm1.Controls("lbl_Loueur").Caption = strFournisseur(j) & "      " & Format(CoûtMoyenMIN, "€ ####.00")
    'Cellule cible à mettre en forme
    cible.Select
End Sub

Cliquez pour agrandir...