Souci de formule imbriquée

[Nanard]

Bonjour le forum, bonjour aux excellents, excelliens

Voici mon problème:

Je coince sur une formule imbriquée, dans une cellule j'ai les mois de l'année janv, fév....etc

dans celle d'à côté la formule imbriqée seulement je ne peux pas imbriquer les 12 mois de l'année, seulement 7...

Merci aux rois des formules de m'éclairer, je sais qu'il y en a et pas des moindres

Par avance merci

Nanard

 

[Chris]

Bonjour
Comment as-tu obtenu les mois ?
En texte ou en date ?

Chris

 

[Pascal76]

Bonjour

Regarde ce lien

Lien supprimé

Bon courage

Pascal

 

[Nanard]

Bonjour Chris, pascal,

En texte, je regarde le fil

Merci

Nanard

 

[Bernard]

Bonjour Nanard et le forum

Une solution récupérée sur le forum :

Concaténer les si en plus :

=SI(A1="Janvier";1;SI(A1="Février";2;SI(A1="Mars";3;SI(A1="Avril";4;SI(A1="Mai";5;SI(A1="Juin";6;SI(A1="Juillet";7;"")))))))&SI(A1="Août";8;SI(A1="Septembre";9;SI(A1="Octobre";10;SI(A1="Novembre";11;SI(A1="Décembre";12;"")))))

Cordialement

Bernard

 

[Nanard]

Re: toujours Souci de formule imbriquée

Rebonjour à tout le forum,
j'ai suivi le fil, et pense que la solution de jean-marie est appropriée, seulement !!!
J'ai une liste déroulante avec les mois(janv,fév...)
La liste des mois est nommée sur une autre feuil
Il doit y avoir un blème dans ma formule, si quelqu'un peu m'éclairer, voici ma formule:

=SI(ET(E15="janvier";RECHERCHEV($A$1;$A$31:$W$534;9;0)&SI(ET(E15="Février";RECHERCHEV($A$1;$A$31:$W$534;10;0)&SI(ET(E15="Mars";RECHERCHEV($A$1;$A$31:$W$534;11;0)&SI(ET(E15="Avril";RECHERCHEV($A$1;$A$31:$W$534;12;0)&SI(ET(E15="Mai";RECHERCHEV($A$1;$A$31:$W$534;13;0)&SI(ET(E15="Juin";RECHERCHEV($A$1;$A$31:$W$534;14;0)&SI(ET(E15="Juillet";RECHERCHEV($A$1;$A$31:$W$534;15;0)&SI(ET(E15="Août";RECHERCHEV($A$1;$A$31:$W$534;16;0)&SI(ET(E15="Septembre";RECHERCHEV($A$1;$A$31:$W$534;17;0)&SI(ET(E15="Octobre";RECHERCHEV($A$1;$A$31:$W$534;18;0)&SI(ET(E15="Novembre";RECHERCHEV($A$1;$A$31:$W$534;19;0)&SI(ET(E15="Décembre";RECHERCHEV($A$1;$A$31:$W$534;20;0))))))))))))

j'ai une erreur à RECHERCHEV après avril!!

Merci de m'aider
Nanard

 

[Monique]

Re: toujours Souci de formule imbriquée

Bonjour,

A essayer, pour voir
Si, en F1:F12, tu as les 12 mois de l'année
=INDEX($A$31:$W$534;EQUIV($A$1;A31:A534;0);EQUIV(E15;$F$1:$F$12;0)+8)

Tu dis que tu as nommé ta liste des mois sur une autre feuille, admettons "Mois"
=INDEX($A$31:$W$534;EQUIV($A$1;A31:A534;0);EQUIV(E15;Mois;0)+8)

EQUIV(E15;Mois;0)+8 te donne le n° de colonne du tableau A31:W534
(le +8, c'est parce que, dans ta formule, janvier c'est recherchev dans la 9è colonne, février c'est la 10è, etc)

 

[Nanard]

Bonjour Monique,

Permet moi de te faire un gros kiss, effectivement tu es la reine pour résoudre les soucis liés aux formules

Il faudra que je me penche un peu + sur la fonction equiv, index ça va...

J'ai ajouté ceci dans la formule pour ne pas écrire les mois dans les cellules F1:F12

=INDEX($A$31:$W$534;EQUIV($A$1;A31:A534;0);EQUIV(E15;Liste!$B$1:$B$12;0)+8)

Merci monique tu es vraimment la meilleure

@ +

Nanard

 

[Monique]

Re,

A la place de "Liste!$B$1:$B$12", tu peux mettre le nom de la plage qui contient les 12 mois.

Sinon : l'équivalent de ta formule, peut-être,
si les valeurs recherchées sont numériques,
cette formule doit être l'équivalent de la tienne,
mais non limitée par les si :
=(E15="janvier")*RECHERCHEV($A$1;$A$31:$W$534;9;0)+(E15="Février")*RECHERCHEV($A$1;$A$31:$W$534;10;0)+(E15="Mars")*RECHERCHEV($A$1;$A$31:$W$534;11;0)+(E15="Avril")*RECHERCHEV($A$1;$A$31:$W$534;12;0)+(E15="Mai")*RECHERCHEV($A$1;$A$31:$W$534;13;0)+(E15="Juin")*RECHERCHEV($A$1;$A$31:$W$534;14;0)+(E15="Juillet")*RECHERCHEV($A$1;$A$31:$W$534;15;0)+(E15="Août")*RECHERCHEV($A$1;$A$31:$W$534;16;0)+(E15="Septembre")*RECHERCHEV($A$1;$A$31:$W$534;17;0)+(E15="Octobre")*RECHERCHEV($A$1;$A$31:$W$534;18;0)+(E15="Novembre")*RECHERCHEV($A$1;$A$31:$W$534;19;0)+(E15="Décembre")*RECHERCHEV($A$1;$A$31:$W$534;20;0)
le * correspond au ET des formules conditionnelles.

Avec le & à la place du +, cette formule te renvoie 0002400000000 sous forme de texte pour 24 au mois d'avril