Somme de plusieurs colonnes avec une seule colonne de critère

[meritein]

Bonjour,
j'y arrive pas. Je souhaite faire la somme de chiffres situés dans plusieurs colonnes avec des critères dans une seule colonne. J'ai regardé somme.si, somme.si.ens sommeprod bdsomme, rien n'a fonctionné. Voudriez-vous m'aider svp à trouver la formule magique ? Merci d'avance.
Je joins un exemple de tableau en précisant que les zones de sélection sont plus étendues que les zones remplies (en d'autres termes la zone critère va de A2 à A33 et la zone de chiffres à sommer de B2 à M33).

 

[Jocelyn]

Bonjour le Forum,
Bonjour merirein,

pas bien sur de ton besoin mais un essai quand même

Cordialement

 

[Patrice33740]

Bonjour,

A revoir

 

[meritein]

Jocelyn, merci pour cette réponse rapide qui donne le résultat escompté à ceci près : dans les zones sélectionnées de sommeprod je souhaiterai y inclure des cellules vides. Est-ce possible ? Dans ton exemple, il n'y a pas de cellules vides sélectionnées.

 

[Jocelyn]

re
Bonjour Patrice 33740,

A priori dans la plage d'addition j'ai bien des cellules vide puisque j'ai pris jusqu'a la colonne M et que de la colonne F à M les cellules sont vides.

à te lire

Cordialement

 

[meritein]

Etrange ! Voici la formule que j'ai écrite
=SOMMEPROD($E$79:$P$286*($B$79:$B$286=Q20)) cela me retourne #VALEUR!.
J'arrive pas à voir si j'ai une erreur de syntaxe.

 

[job75]

Bonjour meritein, Jocelyn, Patrice,

Avec SOMME.SI on peut utiliser des plages illimitées, formule en P2 :

=SOMMEPROD(SOMME.SI(A:A;O2;DECALER(A:A;;COLONNE(B:M)-1)))

Fichier joint.

A+

 

[Jocelyn]

re,

A priori je ne vois pas d'erreur de syntaxe quand tu parles de cellule vide se sont de vrai cellules vide ou des cellules qui contiennent quelque chose comme ""

A tester une autre écriture

=SOMMEPROD(($B$79:$B$286=Q20)*(ESTNUM($E$79:$P$286))*1;$E$79:$P$286)

et autrement une autre formule attention elle est matricielle a valider par les touche CTRL, Maj (au dessus de CTRL) et entrée

=SOMME(si(($B$79:$B$286=Q20)*(ESTNUM($E$79:$P$286));$E$79:$P$286))

Cordialement

EDIT Bonjour job75

 

[meritein]

Effectivement, le problème venait des cellules soi-disant vides qui, en réalité, étaient sans résultat car la formule retournait "". Bien vu. Les 2 codes de texte fonctionnent.
Merci beaucoup et bonne soirée.

 

[mapomme]

Bonjour à tous 🙂,
Une autre formule :

=SOMMEPROD(ESTNUM(B$2:M$30)*( A$2:A$30=O2);B$2:M$30)

edit : je présente mes excuses les plus sincères 😳 à jocelyn dont le message m'avait échappé 😕 et dont la formule est analogue à la formule de ma pomme.

 

[job75]

Bonjour à tous,

Oui ma pomme et si les textes sur B2:M30 ne sont que des textes vides "" :

=SOMMEPROD(( A$2:A$30=O2)*(0&B$2:M$30))

Bonne journée.