XL 2019 somme de plusieurs colonnes suivant un critère sur plusieurs onglets

[patmarchi]

Bonjour,

J’ai 13 onglets, soit janvier, février, etc… et une feuille récap

Je cherche a récupérer les valeurs d’un texte colonne C sur l’ensemble des 12 mois

Or les valeurs recherchées peuvent être sur 3 colonnes D,E,F

J’ai cette formule

=SOMMEPROD(SOMME.SI(INDIRECT("'"&TEXTE(DATE(ANNEE(AUJOURDHUI());LIGNE($1:$12);1);"mmmm")&"'!C3:C50");"*"&H7&"*";INDIRECT("'"&TEXTE(DATE(ANNEE(AUJOURDHUI());LIGNE($1:$12);1);"mmmm")&"'!D3😀50")))

Elle fonctionne si la recherche se fait sur une seule colonne

Mais si je fais la recherche sur 3 colonnes cela ne fonctionne pas

=SOMMEPROD(SOMME.SI(INDIRECT("'"&TEXTE(DATE(ANNEE(AUJOURDHUI());LIGNE($1:$12);1);"mmmm")&"'!C3:C50");"*"&H7&"*";INDIRECT("'"&TEXTE(DATE(ANNEE(AUJOURDHUI());LIGNE($1:$12);1);"mmmm")&"'!E3😀50")))

Quelqu’un pourrait-il m’aider

Merci par avance

 

[cp4]

Bonjour,

@patmarchi : Sans fichier tu peux attendre fort longtemps voire jamais une solution.

Bonne journée.

 

[patmarchi]

oups tout à fait
désolé
erreur rectifiée

 

[Cousinhub]

Bonjour,
Sans formule, mais en utilisant Power Query (pour rassembler les mois) et un Tableau Croisé Dynamique (pour mettre en forme le résultat)
Regarde dans le fichier joint.
J'ai inséré un TS (Tableau Structuré) par mois, avec 5 colonnes (date, motif, CB, Espèces et Chèques)
Ce sera à adapter à ton fichier réel.
Bonne journée

 

[job75]

Bonjour patmarchi, cp4, bhbh,

Pour traiter les 3 colonnes D E F utiliser :

=SOMMEPROD(SOMME.SI(INDIRECT("'"&TEXTE(DATE(ANNEE(AUJOURDHUI());LIGNE($1:$12);1);"mmmm")&"'!C3:C50");"*"&H7&"*";DECALER(INDIRECT("'"&TEXTE(DATE(ANNEE(AUJOURDHUI());LIGNE($1:$12);1);"mmmm")&"'!D3:D50");;COLONNE($A:$C)-1)))

SOMMEPROD travaille sur une matrice de 12 lignes et 3 colonnes.

Contrairement aux apparences tous les nombres sont positifs...

A+

 

[patmarchi]

merci pour ton aide,
mais je ne souhaite récupérer que certaines rubriques de détail, j'avais bien pensé au tcd mais c'est un peu lourd pour une utilisation par une personne non exceliste

 

[patmarchi]

Merci Job75,
cela fonctionne parfaitement, par contre je ne comprends pas ce que tu as ajouté en fin de formule
mais bon, merci encore

 

[ALS35]

Bonjour à tous,
Déjà en utilisant une plage pour les noms des feuilles cela simplifie les formules.
Et librement adapté du site de Jacques Boisgontier (une mine !) avec les noms des feuilles en K1:K12 :

=SOMMEPROD(SOMME.SI(INDIRECT("'"&$K$1:$K$12&"'!C3:C50");B3;DECALER(INDIRECT("'"&$K$1:$K$12&"'!D3:D50");0;{0.1.2})))

Cordialement

 

[job75]

par contre je ne comprends pas ce que tu as ajouté en fin de formule

COLONNE($A:$C)-1 est un vecteur ligne.

Avec DECALER il permet de décaler D3: D50 de 0 1 ou 2 colonnes vers la droite.

Bonjour ALS35.

 

[patmarchi]

ok merci job75