somme de cellules a intervalles reguliers

[nenoo]

bonjour,
je voudrais savoir comment faire pour faire une somme de plusieurs cellules a intervalles reguliers.
dans mon tableau j'ai des nombres de jours dans les cases B2, D2, F2, H2, J2...
quelqu'un pourrait il m'aider ?
je n'ai jamais fais de macro je ne sais pas vraiment comment ca marche.

merci beaucoup

 

[JHA]

Re : somme de cellules a intervalles reguliers

Bonsoir,

sans macro, je te propose:
=SOMMEPROD((MOD(COLONNE($B2:$J2);2)=0)*($B2:$J2))

JHA

 

[ROGER2327]

Re : somme de cellules a intervalles reguliers

Bonjour nenoo

Pour sommer les cellules B2, D2, F2, H2, J2 :

[COLOR="DarkSlateGray"][B]=SOMME(SI(MOD(COLONNE(B:J);2);0;B2:J2))[/B][/COLOR]

(Formule matricielle à valider par Ctrl + Maj + Entrée.)​

ROGER2327
#3552

Lundi 9 Merdre 137 (Vidange, V)
7 Prairial An CCXVIII
2010-W21-3T21:15:39Z

 

[job75]

Re : somme de cellules a intervalles reguliers

Bonjour neno, JHA, Roger,

La formule de JHA est plus simple, mais suppose que toutes les cellules de la plage soient des nombres ou soient vides.

Sinon comme Roger, si des cellules contiennent du texte :

=SOMMEPROD(SI(MOD(COLONNE(B:IV);2)=0;B2:IV2))

A+

 

[BOISGONTIER]

Re : somme de cellules a intervalles reguliers

Bonjour,

Num+texte

=SOMMEPROD(--(MOD(COLONNE(B2:IV2);2)=0);B2:IV2)

JB

 

[nenoo]

Re : somme de cellules a intervalles reguliers

bonjour,
merci a vous tous, mes cellules n'etaient composees que de nombre donc la formule de JHA fonctionne tres bien!
merci beaucoup =D

 

[job75]

Re : somme de cellules a intervalles reguliers

Bonjour le fil, le forum,

Merci à JB d'avoir rappelé que la fonction SOMMEPROD peut avoir plusieurs arguments, autorisant les valeurs Texte.

Mais on peut encore simplifier la formule :

=SOMMEPROD(1-MOD(COLONNE(B2:IV2);2);B2:IV2)

Elle est donc plus simple (2 octets mémoire de moins), et plus générale, que celle de JHA.

A+

 

[nenoo]

Re : somme de cellules a intervalles reguliers

ok Merci job75 =)