Simplification de ma formule qui calcule le nombre de semaines travaillées

[BD_QC]

Bonjour à tous.

J'aimerais simplifier ma formule dans la cellule H5.

Dans cette exemple, Benoit a deux fonctions dans son emploi, soit Poste 1 et Poste 2.

À toute les semaines, il peut faire des heures dans 1 des postes ou les 2 postes.

Dans la cellule H5, je veux qu'il calcule combien de semaine Benoit a travaillé au total.

Dans l'exemple du fichier joint, Benoit a travaillé 3 semaines sur 4 (aussitôt qu'il a fait 1 heure ou plus dans un des deux postes, cela compte comme une semaine travaillée).

Présentement, J'ai "réussi" à le faire mais je crois que j'ai prit le moyen le long en terme de formule...

Voici ma formule qui le calcule présentement: =SI(C5+C6>0;1;0)+SI(D5+D6>0;1;0)+SI(E5+E6>0;1;0)+SI(F5+F6>0;1;0)

Je fais la validation semaine par semaine... Lorsque je serai rendu à la 52 semaines de l'année, la formule sera vraiment longue..

Est-ce que quelqu'un pourrait me donner une piste de solution pour abréger ma formule?

Merci beaucoup!!!

 

[Victor21]

Re : Simplification de ma formule qui calcule le nombre de semaines travaillées

Bonjour.

Un peu plis court :

=N(C5+C6>0)+N(D5+D6>0)+N(E5+E6>0)+N(F5+F6>0)

Edit : Bonjour, piga25, JHA 🙂
Autre solution :Une ligne avec les totaux des heures de chaque semaine
et

nb.si(totaux des heures de chaque semaine;">0")

 

[piga25]

Re : Simplification de ma formule qui calcule le nombre de semaines travaillées

Bonjour,

Salut Victor21

Une autre solution :

=NB.SI(Poste1;">=1")+NB.SI(Poste2;">=1")-SOMMEPROD((Poste1>=1)*(Poste2>=1))

Nommer les 52 semaines en Poste1 et Poste2

 

[JHA]

Re : Simplification de ma formule qui calcule le nombre de semaines travaillées

Bonjour à tous,

A essayer

=NB.SI($C$5:$G$6;">"&0)-SOMMEPROD(($C$5:$F$5>0)*($C$6:$F$6>0))

JHA

 

[piga25]

Re : Simplification de ma formule qui calcule le nombre de semaines travaillées

Re,
Bjr JHA

Un peu plus court :

=NB.SI(Salarié;">=1")-SOMMEPROD((Poste1>=1)*(Poste2>=1))

Salarié = Poste1 et Poste2

Il faut bien mettre >=1 car s'il travaille au poste1 0h30 et au poste2 0h00 cela ne doit pas compter une semaine.