Réduire le nombre d'arguments d'une formule à base de SI(ET...)

[Jibz]

Bonjour à tous !

Je lis le forum depuis pas mal de temps, c'est une source d'informations inépuisable !

Je poste ici car je tombe souvent sur un problème récurrent sous Excel...

Tout d'abord le contexte : je veux vérifier si un poids est compris dans un certain intervalle, et renvoyer la valeur de cet intervalle si le test est positif. Sinon, je recherche dans l'intervalle supérieur, et ainsi de suite.

Voici ma formule :

SI(ET(BJ4>=70,5;BJ4<=99);"71-99";SI(ET(BJ4>=100;BJ4<=299;);"100-299";SI(ET(BJ4>=300;BJ4<=499;);"300-499");SI(ET(BJ4>=500;BJ4<=999;);"500-999");SI(BJ4>999;)"1000+";)))

BJ4 est la cellule contenant la valeur "Poids".

Les intervalles que je veux afficher sont les suivants :

71-99
100-299
300-499
500-999
1000+

Ma question est : comment réduire le nombre d'arguments de cette formule ? Excel me dit qu'il y a trop d'arguments, et je veux bien le croire !

Merci d'avance 🙂

 

[gilbert_RGI]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

bonjour

comme ceci peut-être ?

=SI(ET(BJ4>=70,5;BJ4<=99);"71-99";SI(ET(BJ4>=100;BJ4<=299);"100-299";SI(ET(BJ4>=300;BJ4<=499);"300-499";SI(ET(BJ4>=500;BJ4<=999);"500-999";SI(BJ4>999;"1000+";"")))))

 

[Jibz]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Merci beaucoup !

J'essaie de comprendre la différence avec ma formule qui ne marche pas... Tu as seulement rajouté le ;"" avant toutes les parenthèses à la fin de la formule, c'est ça ?

 

[gilbert_RGI]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

non il y avait des parentheses en trop et des ; manquaient

SI(test_logique;valeur_si_vrai;valeur_si_faux)

ET(valeur_logique1;[valeur_logique2]; ...)

pour vérifier aidez vous de l'aide voir image

 

[Jibz]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

D'accord !

Merci encore 🙂

 

[Salmander]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Une autre solution consiste à ne pas imbriquer les SI : dans le type de formule que tu proposes, les conditions ne se chevauchent pas et donc, on peut effectuer chaque test et concaténer l’ensemble des résultats (chaque test propose le résultat si OUI et une chaine vide si NON), ce qui permet une bien plus grande quantité de valeurs.

=SI(ET(BJ4>=70,5;BJ4<=99);"71-99";"")&SI(ET(BJ4>=100;BJ4<=299);"100-299";"")&SI(ET(BJ4>=300;BJ4<=499);"300-499";"")&SI(ET(BJ4>=500;BJ4<=999);"500-999";"")&SI(BJ4>999;"1000+";"")

 

[Vilain]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Salut à tous,

Quelle bonne idée Salamander, je n'y avais jamais pensé...
Merci pour cette astuce.

A plus

 

[Jibz]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Ah malin, le & permet donc d'accoller des formules sans les rendre dépendantes entre elles ?

 

[Salmander]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Oui, le & est l'équivalent de la fonction CONCATENER()

 

[R@chid]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Bonsoir @ tous,
Un fichier exemple exprimant ce que tu veux faire exactement...
On peut faire plus simple peut etre
Amicalement

 

[R@chid]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Bonsoir @ tous,
Voir PJ.
C'est plus simple comme ca peut etre???
Amicalement

Edit : tu peux faire simple sur mon fichier en B2 :

=SIERREUR(RECHERCHEV(A2;F2:H6;3;1);"")

 

[haonv]

Re : Réduire le nombre d'arguments d'une formule à base de SI(ET...)

Bonsoir à tous ,

Pourquoi ne pas se passer de "et" avec :

=SI(A2>999;"1000+";SI(A2>499;"500-999";SI(A2>299;"300-499";SI(A2>99;"100-299";SI(A2>70;"71-99";"")))))

Une petite variante à la solution de Rachid sur le fichier joint.

Amicalement