saisies semi-automatiques sur 2 colonnes

[pol95]

bonjour,

j'ai une colonne B où j'ai des noms de laboratoire, j'ai une colonne D où j'ai les numéros clients, je voudrais quand je tape le nom d'un labo (déjà référencé) dans la colonne B que s'affiche automatiquement le numéro client correspondant dans la colonne D.

merci de votre aide

 

[kjin]

Re : saisies semi-automatiques sur 2 colonnes

Bonjour Pol95, bonjour à tous,
Avec la formule rechercheV sans doute, référencés oui mais où et comment ? sans plus de précision...difficile
Bonne journée
kjin

 

[jp14]

Re : saisies semi-automatiques sur 2 colonnes

Bonjour et Bonne année

Ci joint une macro évènementielle

Private Sub Worksheet_Change(ByVal Target As Range)
Dim ad As String
Dim cel As Range
If Target.Value = "" Then Exit Sub
If Not Application.Intersect(Target, Range("b1:b65536")) Is Nothing Then
    If Sheets(ActiveSheet.Name).Range(Target.Address).Offset(0, 1) <> "" Then Exit Sub

    ad = ""

    Set cel = Sheets(ActiveSheet.Name).Range("b1:b" & (Target.Row - 1)).Find(Target.Value, LookIn:=xlValues, SearchOrder:=xlByRows, lookat:=xlWhole) ' on recherche ligne par ligne
    If Not cel Is Nothing Then
        ad = cel.Address
    Else
        Set cel = Sheets(ActiveSheet.Name).Range("b" & (Target.Row + 1) & ":b65536").Find(Target.Value, LookIn:=xlValues, SearchOrder:=xlByRows, lookat:=xlWhole)
        If Not cel Is Nothing Then ad = cel.Address
    End If
    If ad <> "" Then
        Target.Offset(0, 1) = Sheets(ActiveSheet.Name).Range(ad).Offset(0, 1)
    End If
End If
End Sub

A tester


JP

 

[Robert]

Re : saisies semi-automatiques sur 2 colonnes

Bonjour le fil, bonjour le forum,

pratiquement à l'identique de JP, je me permets de t'envoyer une autre macro événementielle :

Private Sub Worksheet_Change(ByVal Target As Range)
 
Dim valeur As String 'déclare la variable valeur
Dim valad As String 'déclare la variable valad
Dim rech As Range 'déclare la variable rech
Dim num As Variant 'déclare la variable num
 
If Application.Intersect(Target, Columns(2)) Is Nothing Then Exit Sub 'si le changement n'a pas lieu dans la colonne B, sort de la procédure
If Target.Value = "" Then Target.Offset(0, 2).Value = "": Exit Sub 'si la cellule est effacéé, la cellule de la colonne D sera efacée aussi
valeur = Target.Value 'définit la variable valeur
valad = Target.Address 'définit la variable valad
 
With ActiveSheet.Range("B1:B" & Range("B65536").End(xlUp).Row) 'prend en compte les cellules éditée de la colonne B
    Set rech = .Find(valeur, , xlValues, xlWhole) 'définit la variable rech
    If Not rech Is Nothing And rech.Address <> valad Then 'condition : s'il il existe au moins une seconde occurance de valeur
        num = rech.Offset(0, 2).Value 'définit la variable num
        Target.Offset(0, 2).Value = num 'recopie la variable num
    End If 'fin de la condition
End With 'fin de la prise en compte des cellules éditées de la colonne B
 
End Sub

 

[pol95]

Re : saisies semi-automatiques sur 2 colonnes

c'est la première fois que j'utilise une macro, comment faire pour la rentrée, j'ai office 2002, je vais dans Microsoft Visual Basic, je rentre la fonction que vous avez donnée dans module1 puis comment l'activer ?
dans outils>macro>macros... je ne trouve pas ma macro "Worksheet_Change"

merci de m'aider

 

[Pierrot93]

Re : saisies semi-automatiques sur 2 colonnes

Bonsoir à tous

il s'agit de macros événementielles, tu dois la placer dans le module de la feuille, pour faire cela => click droit sur le nom de l'onglet => visualiser le code et tu colles le code dans la fenêtre qui s'est ouverte.

Attention, tu ne peux avoir qu'une seule procédure gérant un même type d'événement pour une feuille donnée.

bonne soirée
@+

 

[pol95]

Re : saisies semi-automatiques sur 2 colonnes

merci, ça marche impec mais Ctrl+F pour rechercher ne trouve plus aucun mot, la fenêtre s'ouvre mais il ne trouve plus rien si la macro est activée ?

 

[Pierrot93]

Re : saisies semi-automatiques sur 2 colonnes

Re

je viens de tester les 2 macros et chez moi cela fonctionne, il faudrait voir si tu ne recherches pas le résultat d'une formule....

Le fait d'utiliser la fonction "Find" dans vba, modifies les options de la fonctions recherche.

@+