Recopie de formule compliquée

[bellande]

bonjour,
La formule que je doit recopier vers le bas est la suivante :
=NB.SI(C$4:C$91;Y$14)

Mais il faudrait qu'elle devienne cela à la ligne suivante :
=NB.SI(D$4😀$91;Y$14)

(j'ai mis un fichier exemple en pièce jointe)

Je sais que pour cela il faudrait que je la tire vers la droite mais le problème
c'est que la plage de départ qui m'intéresse est en horizontale et que la plage dans laquelle je recopie la formule est en verticale.

Y aurait-il une fonction capable d'obtenir une plage à partir d'une autre en indiquant certains paramètres ?

Merci de votre aide

 

[Pierrot93]

Re : Recopie de formule compliquée

Bonjour Bellande,

j'ai pas tout compris, mais pour figer une lettre de colonne ou un numéro de ligne tu mets le signe $ devant soit la lettre pour la colonne, soit le numéro pour la ligne...

En espérant que cela puisse t aider.

bon après midi
@+

 

[mjo]

Re : Recopie de formule compliquée

Bonjour,

A essayer en Y15 :
=NB.SI(INDIRECT(CAR(LIGNE()+52)&4):INDIRECT(CAR(LIGNE()+52)&91);Y$14)

mjo

 

[Monique]

Re : Recopie de formule compliquée

Bonjour,

Une autre méthode :
mettre les dates de la ligne 3 au format date j ou jj

En Y15 :
=SOMMEPROD(($B$4:$T$91=Y$14)*($B$3:$T$3=$X15))
Puis tu copies et tu colles dans tout le tableau

 

[Gorfael]

Re : Recopie de formule compliquée

bonjour,
La formule que je doit recopier vers le bas est la suivante :
=NB.SI(C$4:C$91;Y$14)

Mais il faudrait qu'elle devienne cela à la ligne suivante :
=NB.SI(D$4😀$91;Y$14)

(j'ai mis un fichier exemple en pièce jointe)

Je sais que pour cela il faudrait que je la tire vers la droite mais le problème
c'est que la plage de départ qui m'intéresse est en horizontale et que la plage dans laquelle je recopie la formule est en verticale.

Y aurait-il une fonction capable d'obtenir une plage à partir d'une autre en indiquant certains paramètres ?

Merci de votre aide

Salut
Formule en Y15

=NB.SI(INDIRECT(ADRESSE(4;LIGNE()-12) & ":" & ADRESSE(91;LIGNE()-12));Y$14)

Dans ton problème, pour la plage de recherche, il faut que tu transformes les colonnes, or la seule variable mouvante est la ligne.
Pour ça, il faut utiliser l'instruction ligne() qui donne la ligne où se situe la formule, et la transformer en numéro de colonne. on peut utiliser 2 formules
indirect((CAR(LIGNE()+52) & 4) & ":" & (CAR(LIGNE()+52) & 91))
Mais on est limité à la colonne Z, puisque car(x) donne une lettre de A à Z (Car(27)="0") ou celle qui utilise la fonction adresse() qui n'a pas cette limite.
indirect transforme un texte en une référence de cellule
A+

 

[Monique]

Re : Recopie de formule compliquée

Re,

Ou bien en Y15 (sans rien changer en ligne 3) :
=NB.SI(DECALER($B$4:$B$91;0;LIGNES(Y$15:Y15));Y$14)
(tu peux enlever le 0, en gardant les 2 ;😉

 

[bellande]

Re : Recopie de formule compliquée

bonsoir,
Merci à toutes les personnes qui ont pris du temps pour regarder mon problème.
J'ai désormais plusieurs méthodes qui répondent parfaitement à mon cas.
Je mesure tous les progrès qui me restent à faire pour être à votre niveau.
Merci encore