XL 2019 Comment extraire séparément plusieures chaines de caractères ou chiffres/nombres depuis une cellule avec libellé complexe alpha numérique

[Renardy]

Bonjour à tous

D'emblée je trouve ce site super il nous permet à tous de progresser avec notre super outil qu'est EXCEL. J' y ai toujours eu reponse à mes (rares) demandes , et je vous remercie.
Voici une autre petite demande que je suis sur, beaucoup sauront resoudre avec la formule XTFC avec laquelle j'ai un peu de mal..

>>> Je souhaiterai extraire vers des cellules sur des colonnes adjacentes distinctes des "morceaux" de données (soit lettres, soit chiffres ), contenus entre parenthese dans un libellé global 'une cellule de la colonne B.
Voir l'exemple ci joint.

Merci pour votre aide concernant les formules à créer dans les colonnes C, D, E et F

bien cordialement

 

[Staple1600]

Bonjour patricktoulon

[aparté]
Si on parle de méditation, alors méditons entre croissants et café un samedi matin d'été

Qui utilise encore des PC sous Windows 95 et Excel 97 ?

Qu'on le veuille ou non, le "progrès" oblige à l'upgrade, non ?

(cf 3G,4G, 5G WIFI 5 , 6/6E , 7 écrans cathodiques -> écrans LCD etc...)

Le problème serait plutôt pourquoi ne pas vouloir des dernières versions d'Excel ?

PS: FILTRE.XML ne fonctionne pas avec Excel 2003, Excel 2007 et Excel 2010

FILTRE.XML (FILTRE.XML, fonction)
Excel pour Microsoft 365 Excel 2021 Excel 2019 Excel 2016 Excel 2013

[/aparté]

 

[Staple1600]

Re

Histoire de meubler l'après-midi et d'éviter tout l'exubérance médiatique autour des JO
Deux variantes de formules avec FILTRE.XML
=SUBSTITUE(TRANSPOSE(FILTRE.XML("<t><s>"&SUBSTITUE(STXT(B3;CHERCHE("(";B3)+1;99);";";"</s><s>")&"</s></t>";"//s[position()>=1]"));")";"")

=SUBSTITUE(TRANSPOSE(FILTRE.XML("<t><s>"&SUBSTITUE(STXT(B5;CHERCHE("(";B5)+1;99);";";"</s><s>")&"</s></t>";"//s[not(preceding::*=.)]"));")";"")

PS: avec 365, FILTRE.XML se propage sur une colonne (d'où l'emploi de TRANSPOSE)
La saisie des formules se fait dans donc dans une seule cellule
(pas besoin de recopier vers la droite)

 

[Staple1600]

Re

Et histoire de réduire un peu la formule
en colonne C

=STXT(B3;CHERCHE("(";B3)+1;CHERCHE(";";B3)-CHERCHE("(";B3)-1)

et en colonne D

=SUBSTITUE(TRANSPOSE(FILTRE.XML("<t><s>"&SUBSTITUE(B3;";";"</s><s>")&"</s></t>";"//s["&{2;3;4}&"]"));")";"")

Une variante sans le SUBSTITUE pour remplacer le ) final

=TRANSPOSE(FILTRE.XML("<t><s>"&SUBSTITUE(STXT(GAUCHE(B3;NBCAR(B3)-1);CHERCHE(";";B3)+2;99);";";"</s><s>")&"</s></t>";"//s["&{1;2;3}&"]"))

 

[patricktoulon]

bonjour @Staple1600
la formule transpose ne fonctionne pas sur 2013 même en matricielle

 

[Staple1600]

Re

@patricktoulon
Comme expliqué précédemment, c'est le fait d'utiliser O365(*) qui m'oblige à utiliser TRANSPOSE
(*propagation)
Voir exemple ci-dessous

 

[patricktoulon]

re
ok chez moi en supprimant transpose
horizontalement sur 3 cellules ou verticalement ca ne fonctionne pas
et si j'essaie de valider en matriciel j'ai le premier dans les 3 cellules

 

[patricktoulon]

rectification en enlevant le transpose j'ai un résultat en matriciel vertical

 

[patricktoulon]

re
et en horizontal il faut déplacer le transpose a l’opértion supérieur c'est a dire là ici en l’occurrence en premier (ca transpose le tout)

=TRANSPOSE(SUBSTITUE(FILTRE.XML("<t><s>"&SUBSTITUE(B3;";";"</s><s>")&"</s></t>";"//s["&{2;3;4}&"]");")";""))

 

[patricktoulon]

et en une seule formule en matricielle horizontal

=TRANSPOSE(SUBSTITUE(FILTRE.XML(SUBSTITUE(SUBSTITUE(SUBSTITUE("<R>"&$B3&"</R>";"(";"<B>");")";"</B>");";";"</B><B>");"//B["&{1;2;3;4}&"]");")";""))

bref j'ai le même résultat que celle à étendre sauf que là je sélectionne la ligne(4 cellules pour la même formule)

 

[Staple1600]

Re

@patricktoulon

et en horizontal il faut déplacer le transpose a l’opértion supérieur c'est a dire là ici en l’occurrence en premier (ca transpose le tout)

C'est ce que j'ai fait non ?
Voir copie d'écran du message#20
Et notamment la formule D12
Je suppose que tu n'avais pas affiché l'image en grand dans ton navigateur

 

[patricktoulon]

non ce n'est pas tout à fait ce que tu a fait
ton transpose n'est pas au bon endroit pour chez moi j'ai #Erreur dans les 3
et puis j'ai laissé ton dernier substitue de ")" par ";" , il faut l'enlever

=TRANSPOSE(FILTRE.XML(SUBSTITUE(SUBSTITUE(SUBSTITUE("<R>"&$B3&"</R>";"(";"<B>");")";"</B>");";";"</B><B>");"//B["&{1;2;3;4}&"]"))

en gros avec les 3 substitue j'obtiens un code XML valide

un root( <R>) , son texte , et les 4 childs(<B>)

autrement dit je traite les 4 valeurs in One shot de la même manière qu'avec mon premier exemple d'ailleurs

 

[Staple1600]

Re


@patricktoulon
Tu n'utilises pas Excel 365, non ?

J'ai testé mes formules avant de les poster sur le forum
Je sais donc qu'elles sont fonctionnelles

Je m'étais arrêté sur celle-ci
=TRANSPOSE(FILTRE.XML("<t><s>"&SUBSTITUE(STXT(GAUCHE(B3;NBCAR(B3)-1);CHERCHE(";";B3)+2;99);";";"</s><s>")&"</s></t>";"//s["&{1;2;3}&"]"))

Mais comme je voulais réduire la formule, j'ai opté pour deux formules en C12 et D12
(comme le montre ma copie d'écran)

Précisions:
ma syntaxe "//s["&{1;2;3}&"]" ou celle-ci "//s[not(preceding::*=.)]" n'ont rien à voir avec ton 1er exemple

Et puisque je suis sur O365, il est plus simple et compréhensible d'utiliser celle-ci
(que j'ai également mise sur ma précédente copie écran)
=FRACTIONNER.TEXTE(TEXTE.APRES(B3;"(");{";";")"};;VRAI)

 

[mapomme]

Bonsoir à tout le monde ,

Perso, je propose la formule suivante pour O365 :
=LET(a;FRACTIONNER.TEXTE(TEXTE.APRES(TEXTE.AVANT(B3;")");"(");";");SIERREUR(1*a;a)) qui respecte le type de valeur (texte ou nombre).

 

[Renardy]

re
Bonsoir
le problème avec toutes ces versions c'est que selon le pc (et/ou) la version d'office, ca ne fonctionnera pas la mienne avec filtre.xml fonctionne dans toutes ainsi que toutes les propositions VBA
ce n'est pas un détail à négliger
à méditer

yes , je garde précieusement toutes les versions Merci à vous