RechercheV-3 critères

[Chubby]

Bonjour à tous,
Ce n'est pas faute d'avoir fouillé ici ou là mais je bute sur un problème de recherche de valeurs selon 3 critères. J'ai vu, plus ou moins compris aussi, des formules matricielles, j'ai vu des index;equiv mais je n'arrive pas à adapter les exemples à mon cas.
J'ai créé des liste de champs pour faciliter la tâche mais l'âne rebute au saut grrrr.
Je vous laisse un petit tableau pour que vous voyez le truc. Cellules grises étant celles saisies, les vertes étant celles trouvées. Laissez moi une piste, un exemple que je sache quelle est la ou les solutions possibles.
Merci encore à tous ici.

 

[Tibo]

Re : RechercheV-3 critères

Bonjour

Que doit retourner ta formule ?

Où (dans quelle colonne) doit-elle être placée ?

A te (re)lire avec davantage de précisions.

@+

 

[JCGL]

Re : RechercheV-3 critères

Bonjour à tous,
Salut Chubby,

Peux-tu essayer :

=SOMMEPROD((Listes!$H$2:$H$85=B2)*(Listes!$K$2:$K$85=D2)*(Listes!$I$2:$I$85=E2)*(Listes!$J$2:$J$85=STXT(F2;2;6)*1)*Listes!$L$2:$L$85)

A + à tous

Edition : Salut Tibo, Salut Jocelyn

 

[Jocelyn]

Re : RechercheV-3 critères

Bonjour le Forum,
Bonjour Chubby, Tibo,

bon alors si j'ai bien compris voila un exemple en fichier joint

attention ce sont des formules matricielles il faut les valider en appuyant simultanément sur les touches CTRL, majuscule au dessus de CTRL et entrée

Oup's Bonjour JCGl désolé pour la collision

 

[Chubby]

Re : RechercheV-3 critères

Bonsoir Tibo, Bonsoir JCGL... la rentrée des experts on dirait ;-)
Merci à vous de vous pencher sur mon problème. Je vais tenter d'être plus clair, je voudrais à partir des données saisies en colonnes B, E et F de l'onglet Tab, faire apparaitre les données correspondantes en colonnes D et G, valeurs que l'on trouve dans l'onglet Listes.
JCGL, ta formule me donne une réf circulaire pour la colonne D, elle fonctionne très bien pour la G avec un petit tour de moulin du pc. J'ai inséré une col supplémentaire pour palier à la réf circulaire de la D... mais même réaction.
Grrrrr

 

[JCGL]

Re : RechercheV-3 critères

Bonjour à tous,

La formule de Jocelyn fonctionne très bien pour les deux colonnes.

A++
A + à tous

 

[Chubby]

Re : RechercheV-3 critères

Bonsoir Jocelyn,
Le temps que je réponde à nos experts et hop tu avais posté... posté et tapé dans le mille. C'est bien ce que je craignais en fait, il y a de la matricielle dans l'air et là j'ai à piocher dans mes neurones pour comprendre ce petit bijou.
Merci Jocelyn, j'espère que tu n'as pas coupé l'herbe sous les pieds aux zotres ... d'ailleurs je vois apparaitre des #N/A dans les cellules mal renseignées, peut on introduire le si(estna? euhhhh histoire de compliquer ;-)
Merci encore

 

[Jocelyn]

Re : RechercheV-3 critères

bon voila la modif

colonne D

=SI(ESTNA(INDEX(Listes!$K$2:$K$84;EQUIV(B2&E2&F2;Listes!$H$2:$H$84&Listes!$I$2:$I$84&"p"&Listes!$J$2:$J$84;0)));"Erreur de saisie";INDEX(Listes!$K$2:$K$84;EQUIV(B2&E2&F2;Listes!$H$2:$H$84&Listes!$I$2:$I$84&"p"&Listes!$J$2:$J$84;0)))

colonne G

=SI(ESTNA(INDEX(Listes!$L$2:$L$84;EQUIV(B2&E2&F2;Listes!$H$2:$H$84&Listes!$I$2:$I$84&"p"&Listes!$J$2:$J$84;0)));"Erreur de saisie";INDEX(Listes!$L$2:$L$84;EQUIV(B2&E2&F2;Listes!$H$2:$H$84&Listes!$I$2:$I$84&"p"&Listes!$J$2:$J$84;0)))

toujours des matricielles

bonne soirée

je joins le fichier la copier coller de la formule a ajouté des espaces dans la formule alors le fichier c'est mieux

 

[mapomme]

Re : RechercheV-3 critères

Bonsoir à tous,

Une autre formule matricielle - excel 2007 ou 2010 - : (D)

=SIERREUR(INDEX(Listes!$K$2:$K$100;EQUIV(1;(B2=Listes!$H$2:$H$100)*(E2=Listes!$I$2:$I$100)*(F2="P"&Listes!$J$2:$J$100);0));"")

Une autre formule matricielle - excel 2007 ou 2010 - : (G)

=SIERREUR(INDEX(Listes!$L$2:$L$100;EQUIV(1;(B2=Listes!$H$2:$H$100)*(E2=Listes!$I$2:$I$100)*(F2="P"&Listes!$J$2:$J$100);0));"")

 

[Chubby]

Re : RechercheV-3 critères

Bonjour Jocelyn, Mapomme et les zotres,
Merci à vous deux pour ces petits bijoux. J'avoue que les matricielles m'effrayent un peu et vous avez répondu à mes attentes... peut être trop d'ailleurs ;-)
Non soyez rassuré je m'en imprègne petit à petit.
Merci encore et bonne journée.
Chubby