SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

[olivewalou]

SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

Bonjour à tous,

Je souhaite mettre en place une fonction SOMME qui selon les 7 critères possibles m'ajouterai la valeur correspondante dans ma somme en fonction des variables leurs correspondants...
j'essaye d'éclaircir et je joints aussi un fichier pour demo:

la somme est en J3 et dépends des critères de F3 qui peut soit arrêter là le calcul,
soit sommer A3, B3, E3, F3, G3, H3, et I3 qui le complique...
le référentiel pour les correspondances des valeurs est en dessous de mon tableau.

On peut y lire que si F3 (l'état) = N alors J3=250, si F3=V ou D alors J3=0 jusque là ça allait,
mais si F3=E alors on Somme les valeurs correspondantes aux critères en A3, B3, E3, F3, G3, H3, et I3 en fonctions de leurs variables...

J'ai donc pensé (peut-être à tord) utiliser une fonction SOMME.SI.ENS mais je m'arrache les cheveux ! 🙄

la disposition de mon tableau de ref n'aide peut-être pas non plus...?

J'entre dans le détail des imbriqués sur mon fichier.


Je ne suis pas une lumière flash en terme d'excel, plutôt une ampoule économique ça éclaire mais c'est long à venir 😛
SVP soyez compréhensif dans votre réponse, imaginez parler à un pur débutant, même si j'ai déjà quelques notions de formules.
UN GRAND MERCI a tous ceux qui font l'effort de répondre sur ce forum, et à ma demande ici particulièrement. 😎


P.S. aux admins, Pour info: le temps de taper ce message j'ai été déconnecté ???
je l'ai heureusement copier avant de prévisualiser et joindre mon fichier.

 

[chris]

Re : SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

Bonjour

Si j'ai bien compris, en J3 à recopier vers le bas :

=SI(F3<>"E";RECHERCHEV(F3;$F$22:$G$24;2;0);INDEX(SI(A3="B";$B$24:$C$38;$D$24:$E$38);EQUIV(E3;$A$24:$A$38;0);EQUIV(B3;SI(A3="B";$B$22:$C$22;$D$22:$E$22);0)))+RECHERCHEV(G3;$F$26:$G$29;2;0)+RECHERCHEV(H3;$F$31:$G$34;2;0)+RECHERCHEV(I3;$F$36:$G$38;2;0)

 

[olivewalou]

Re : SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

MERCI de la réponse 🙂 , je vais tester...
je n'avais pas encore eu à utiliser RECHERCHEV ni EQUIV dans mes feuilles jusqu'à aujourd'hui,
j'espère que cela va fonctionner.
Je posterai un message en retour après le test.

... SUITE AU TEST:

celà fonctionne à part pour la valeur V (ref G23) qui n'est pas reconnue, ça marche avec D et E,
je vais chercher dans le code comment tu as mis le champs correspondant et tenter d'y ajouter cette valeur sans tout casser,... 😛
je test et repost la solution trouvée.

MEGA MERCI POUR LA SOLUTION, je vais pouvoir lâcher le tube d'aspirine 😉

 

[olivewalou]

Re : SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

OK,CHRIS, MERCI, le test avec V est bon je n'ai pas renseigné la bon champs à mon premier test 😛
par contre le fait de choisir V ou D n'empêche pas l'ajout dans la somme totale des valeurs de surcotes en F26:G29, F31:G34 et F36:G38
or j'aurai préféré que si l'état = V ou D alors la somme=0 de façon inconditionnelle
et seulement si état = E faire le calcul...
je sais je pinaille alors que ta formule est déjà top !
Pour avoir ce résultat je dois pour le moment supprimer les valeurs.
(message corrigé, désolé "Chris", j'avais un "Alex" en ligne en tapant le message, je me suis emmêlé les réponses...😛 )

 

[chris]

Re : SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

Re

Il faut déplacer une parenthèse :

=SI(F3<>"E";RECHERCHEV(F3;$F$22:$G$24;2;0);INDEX(SI(A3="B";$B$24:$C$38;$D$24:$E$38);EQUIV(E3;$A$24:$A$38;0);EQUIV(B3;SI(A3="B";$B$22:$C$22;$D$22:$E$22);0))+SI(F3<>"V";RECHERCHEV(G3;$F$26:$G$29;2;0)+RECHERCHEV(H3;$F$31:$G$34;2;0)+RECHERCHEV(I3;$F$36:$G$38;2;0);0))

Attention V est suivi d'un espace dans le tableau du bas : a corriger

C'est qui ALEX ?

 

[olivewalou]

Re : SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

Merci CHRIS, je regarde ce soir...

 

[chris]

Re : SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel

Re

Erreur de recopie : voici la formule avec juste la parenthèse déplacée

=SI(F3<>"E";RECHERCHEV(F3;$F$22:$G$24;2;0);INDEX(SI(A3="B";$B$24:$C$38;$D$24:$E$38);EQUIV(E3;$A$24:$A$38;0);EQUIV(B3;SI(A3="B";$B$22:$C$22;$D$22:$E$22);0))+RECHERCHEV(G3;$F$26:$G$29;2;0)+RECHERCHEV(H3;$F$31:$G$34;2;0)+RECHERCHEV(I3;$F$36:$G$38;2;0))

 

[olivewalou]

Re : SOMME.SI.ENS selon 7 critères à plusieurs variables d'après référentiel [résolu]

Merci beaucoup, j'avais pas eu le temps de m'y replonger de la semaine, je viens de tester c'est fonctionnel.

Je devrais changer le nom de la discussion et la clôturer.