Recherche V avec résultats multiples

[piktygirl]

Bonjour,

Je souhaiterais réaliser une rechercheV en fonction d'une référence qui apparait plusieurs fois dans mon tableau.
Quand je fais la manip seul le premier résultat ressort or je souhaiterais voir apparaitre tous les résultats. Pouvez vous m'aider?
Voici un exemple en PJ.
Par avance merci

 

[R@chid]

Re : Recherche V avec résultats multiples

Salut et bienvenu sur XLD,
en A4:

=SI(LIGNES($1:1)<=NB.SI(Candidatures!$A$2:$A$15;Récap!$C$1);INDEX(Candidatures!B$2:B$15;PETITE.VALEUR(SI(Candidatures!$A$2:$A$15=Récap!$C$1;LIGNE(INDIRECT("1:"&LIGNES(Candidatures!B$2:B$15))));LIGNES($1:1)));"")

@ valider en matricielle par Ctrl+Maj+Entree
@ recopier vers le bas et vers la droite
@ +
@ Rachid

Edit : si les donnees sont bient triees on a pas besoin de formule matricielle.
en A4 :

=SI(LIGNES($1:1)<=NB.SI(Candidatures!$A$2:$A$15;Récap!$C$1);INDEX(Candidatures!B$2:B$15;EQUIV(Récap!$C$1;Candidatures!$A$2:$A$15;0)+LIGNES($1:1)-1);"")

@ valider par Entree
@ recopier vers le bas et vers la droite
@ + +

 

[CISCO]

Re : Recherche V avec résultats multiples

Bonsoir

Une possibilité parmi d'autres

@ plus

 

[piktygirl]

Re : Recherche V avec résultats multiples

Merci beaucoup pour vos réactivités et efficacité!
Je vais tenter de comprendre maintenant merci.

 

[piktygirl]

Re : Recherche V avec résultats multiples

Rachid_0661, est ce que vous pourriez m'expliquer la seconde formule si ce n'est trop demandé. J'aimerai bien comprendre.

 

[R@chid]

Re : Recherche V avec résultats multiples

Rachid_0661, est ce que vous pourriez m'expliquer la seconde formule si ce n'est trop demandé. J'aimerai bien comprendre.

Re,
LIGNES($1:1) quand on le tire vers le bas va generer une serie d'entiers commencant par 1
NB.SI() c'est pour ne pas depasser le nombre d'occurences de la valeur cherche.
la combinaison INDEX-EQUIV :
INDEX c'est pour specifier la plage de recherche j'ai verouiller juste les lignes et pas les colonnes car on va tirer vers la droite ce qui permet de passer d'une colonne de recherche a l'autre
EQUIV() c'est pour trouver l'equivalent de la valeur cherche dans le tableau de recherche
EQUIV()+LIGNES($1:1)-1 ==> EQUIV()+1-1 ==> EQUIV()+2-1 ==>EQUIV()+3-1 .......
Faire une evaluation de la formule pour bien comprendre
@ +

 

[piktygirl]

Re : Recherche V avec résultats multiples

Merci beaucoup...