Recherche V avec résultats multiples

R@chid

XLDnaute Barbatruc

Supporter XLD

• 29 Janvier 2012

• #2

Re : Recherche V avec résultats multiples

Salut et bienvenu sur XLD,
en A4:

Code:

=SI(LIGNES($1:1)<=NB.SI(Candidatures!$A$2:$A$15;Récap!$C$1);INDEX(Candidatures!B$2:B$15;PETITE.VALEUR(SI(Candidatures!$A$2:$A$15=Récap!$C$1;LIGNE(INDIRECT("1:"&LIGNES(Candidatures!B$2:B$15))));LIGNES($1:1)));"")

@ valider en matricielle par Ctrl+Maj+Entree
@ recopier vers le bas et vers la droite
@ +
@ Rachid

Edit : si les donnees sont bient triees on a pas besoin de formule matricielle.
en A4 :

Code:

=SI(LIGNES($1:1)<=NB.SI(Candidatures!$A$2:$A$15;Récap!$C$1);INDEX(Candidatures!B$2:B$15;EQUIV(Récap!$C$1;Candidatures!$A$2:$A$15;0)+LIGNES($1:1)-1);"")

@ valider par Entree
@ recopier vers le bas et vers la droite
@ + +

 

Pièces jointes

• Exemple_modifie_1.xls

  42.5 KB · Affichages: 68

Dernière édition: 29 Janvier 2012

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 29 Janvier 2012

• #3

Re : Recherche V avec résultats multiples

Bonsoir

Une possibilité parmi d'autres

@ plus

 

Pièces jointes

• Exemple pikty.xls

  36 KB · Affichages: 71

Vote positif 0 Vote négatif

P

piktygirl

XLDnaute Nouveau

• 29 Janvier 2012

• #4

Re : Recherche V avec résultats multiples

Merci beaucoup pour vos réactivités et efficacité!
Je vais tenter de comprendre maintenant merci.

 

Vote positif 0 Vote négatif

P

piktygirl

XLDnaute Nouveau

• 29 Janvier 2012

• #5

Re : Recherche V avec résultats multiples

Rachid_0661, est ce que vous pourriez m'expliquer la seconde formule si ce n'est trop demandé. J'aimerai bien comprendre.

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 29 Janvier 2012

• #6

Re : Recherche V avec résultats multiples

piktygirl à dit:

Rachid_0661, est ce que vous pourriez m'expliquer la seconde formule si ce n'est trop demandé. J'aimerai bien comprendre.

Cliquez pour agrandir...

Re,
LIGNES($1:1) quand on le tire vers le bas va generer une serie d'entiers commencant par 1
NB.SI() c'est pour ne pas depasser le nombre d'occurences de la valeur cherche.
la combinaison INDEX-EQUIV :
INDEX c'est pour specifier la plage de recherche j'ai verouiller juste les lignes et pas les colonnes car on va tirer vers la droite ce qui permet de passer d'une colonne de recherche a l'autre
EQUIV() c'est pour trouver l'equivalent de la valeur cherche dans le tableau de recherche
EQUIV()+LIGNES($1:1)-1 ==> EQUIV()+1-1 ==> EQUIV()+2-1 ==>EQUIV()+3-1 .......
Faire une evaluation de la formule pour bien comprendre
@ +

 

Vote positif 0 Vote négatif

P

piktygirl

XLDnaute Nouveau

• 29 Janvier 2012

• #7

Re : Recherche V avec résultats multiples

Merci beaucoup...

 

Vote positif 0 Vote négatif