Problème formule SI ET, je galère

[tazdu53]

Bonjour,

Je souhaite rédiger une formule me permettant de réaliser une hausse en fonction d’un code matière.
Je m’explique, les codes article sont numériques et se décomposent de la manière suivante :
110.21.SI.0010.004

Le code 21 désigne la matière, celle-ci peut être augmentée de xx% tous les ans.

Mais le même code article peut être réalisé avec une autre matière (20, 21, 61, 64) (voir tableau ci-joint).

Est-ce que quelqu’un pourrait m’aider s’il vous plait ?

 

[thebenoit59]

Re : Problème formule SI ET, je galère

Bonjour Tazdu53.

En J9 :

=E9*1+(INDEX($F$9:$G$12;EQUIV(CNUM(STXT(I9;5;2));$F$9:$F$12;0);2))

Ne s'applique que si ton code matière correspond au 5ème et 6ème caractère de ton code produit.

 

[excfl]

Re : Problème formule SI ET, je galère

Bonjour le forum,

Message supprimé.

 

[JHA]

Re : Problème formule SI ET, je galère

Bonour à tous,

A essayer en "J9"

=$E9*(1+INDEX($G$9:$G$12;EQUIV(STXT(I9;5;2)*1;$F$9:$F$12;0)))

puis copier vers le bas

JHA

 

[excfl]

Re : Problème formule SI ET, je galère

Re,

J9 :

=E9*(1+RECHERCHEV(--STXT(D9;5;2);$F$9:$G$12;2;0))

 

[JHA]

Re : Problème formule SI ET, je galère

Re,

Si tes codes produits ne sont pas dans le même ordre en colonne "D" & "J":

=DECALER($D$8;EQUIV(I9;$D$9:$D$14;0);1)*(1+INDEX($G$9:$G$12;EQUIV(STXT(I9;5;2)*1;$F$9:$F$12;0)))

JHA

 

[tazdu53]

Re : Problème formule SI ET, je galère

Merci à tous vous êtes super performant, en quelques heures vous m'avez donné plusieurs solutions, alors que moi je galère à comprendre comment faire des formules. Merci à tous pour votre temps passé.

 

[tazdu53]

Re : Problème formule SI ET, je galère

Votre formule marche mais j'ai voulu l'adapter eu fichier initial et j'ai du raté une marche car j'arrive plus à la refaire en fonction de mon besoin.
Pouvez vous regarder et me dire où ça pose problème s'il vous plait?

 

[thebenoit59]

Re : Problème formule SI ET, je galère

Avec le fichier nous regarderons 😉

 

[tazdu53]

Re : Problème formule SI ET, je galère

oups j'ai oublié

 

[thebenoit59]

Re : Problème formule SI ET, je galère

Il doit sans aucun doute y avoir plus simple, mais je ne vois pas comment faire. Tes premières données ont un code Texte et le reste un code Numérique, alors j'ai modifié ma formule.

=SI(ESTNUM(CNUM(STXT(A2;5;2)));'TARIF O 16'!F2*1+(INDEX(HAUSSE!$C$2:$D$198;EQUIV(CNUM(STXT(A2;5;2));HAUSSE!$C$2:$C$198;0);2));'TARIF O 16'!F2*1+(INDEX(HAUSSE!$C$2:$D$198;EQUIV(STXT(A2;5;2);HAUSSE!$C$2:$C$198;0);2)))

Je te conseille de nommer les plages de cellules pour plus de facilité.
J'ai estimé que 2017 est exactement dans le même ordre que 2016.

 

[excfl]

Re : Problème formule SI ET, je galère

F2 :

=sierreur('tarif o 16'!f2*(1+recherchev(stxt(a2;5;2);hausse!$c$2:$d$198;2;0));('tarif o 16'!f2*(1+recherchev(--stxt(a2;5;2);hausse!$c$2:$d$198;2;0))))

 

[JHA]

Re : Problème formule SI ET, je galère

Bonsoir à tous,

A essayer, Il manque quelques codes dans l'onglet 2017.
Si tu utilises Excel 2003 il faut utiliser si(esterreur()) sinon pour les versions supérieures sierreur() en "F2":

=DECALER('TARIF O 16'!$A$1;EQUIV($A2;'TARIF O 16'!$A$2:$A$1758;0);5)*(SIERREUR(1+INDEX(HAUSSE!$D$2:$D$198;EQUIV(STXT(A2;5;2);HAUSSE!$C$2:$C$198;0));1+INDEX(HAUSSE!$D$2:$D$198;EQUIV(STXT(A2;5;2)*1;HAUSSE!$C$2:$C$198;0))))

JHA

 

[excfl]

Re : Problème formule SI ET, je galère

Un comparatif des résultats :

 

[thebenoit59]

Re : Problème formule SI ET, je galère

Il va falloir que je voie pour quelle raison ma formule ne donne pas les bons résultats :/.
Désolé pour l'erreur 😕