Probleme Formule RECHERCHEV

[stlduke51]

Bonjour le Forum,

Je viens vers vous car j'ai du mal a trouver la solution pour resoudre mon probleme de recherche dans le fichier joint.
En effet je recherche la valeur intitulé " Sans Réfaction " ( case verte ).

Cette valeur tient compte de la commune D5, qui elle même donne la zone de raccordement D7, de la technique de Branchement D9, et enfin de la puissance D11.

J'ai fait les tableaux en Feuille "Zone", et "Technique et puissance". Ensuite je suis bloqué et je ne trouve pas la formule qui m'irai bien.

Je pense a la formule : RECHERCHEV(...... mais ensuite je suis perdu

Merci de votre aide

 

[Odesta]

Re : Probleme Formule RECHERCHEV

Bonjour. Pour récup le HT :

=INDEX('Technique et Puissance'!D6:G17;EQUIV("ZE"&D7;'Technique et Puissance'!B6:B17;0)+EQUIV(D11;'Technique et Puissance'!C6:C8;0)-1;EQUIV(D9;'Technique et Puissance'!D4:G4;0))

Le TTC

=INDEX('Technique et Puissance'!D6:G17;EQUIV("ZE"&D7;'Technique et Puissance'!B6:B17;0)+EQUIV(D11;'Technique et Puissance'!C6:C8;0)-1;1+EQUIV(D9;'Technique et Puissance'!D4:G4;0))

Cdt

Olivier

 

[stlduke51]

Re : Probleme Formule RECHERCHEV

Bonsoir Odesta,

Merci beaucoup pour cette réponse rapide.
Apparement je partai sur une fausse route avec la Formule RECHERCHEV.

Encore merci.
Steph

 

[JBOBO]

Re : Probleme Formule RECHERCHEV

Bonjour,

Un essai :
en D18 :

=INDIRECT(ADRESSE(SI(D11="3 kVA";EQUIV("ze"&D7;'Technique et Puissance'!B6:B17)+5;SI(D11="12 kVA";EQUIV("ze"&D7;'Technique et Puissance'!B6:B17)+6;EQUIV("ze"&D7;'Technique et Puissance'!B6:B17)+7));EQUIV(D9;Technique;0)+3;;;"Technique et Puissance"))

et en E18 :

=INDIRECT(ADRESSE(SI(D11="3 kVA";EQUIV("ze"&D7;'Technique et Puissance'!B6:B17)+5;SI(D11="12 kVA";EQUIV("ze"&D7;'Technique et Puissance'!B6:B17)+6;EQUIV("ze"&D7;'Technique et Puissance'!B6:B17)+7));EQUIV(D9;Technique;0)+4;;;"Technique et Puissance"))