problème avec calendrier

[schmittfrançois]

Bonjour,
J'ai un soucis. Je dois faire un tableau avec des dates. En colonne A cellule 1 j'ai la date de réception d'un message d'un client. En colonne B, je dois saisir une date RA qui doit être égale à A1+1. En colonne C, je dois saisir une date RF qui doit être égale à A1+5. Or les dates RA et RF ne peuvent tomber sur un samedi ou un dimanche. Comment puis je construire mon tableau, SVP.

 

[CB60]

Re : problème avec calendrier

Bonsoir
Cette formule peut être

=SI(JOURSEM(A2+1;3)=5;A2+3;SI(JOURSEM(A2+1;3)=6;A2+2;A2+1))

Bonsoir JC,
Pour la formule j'etais un peu faineant, c'est bien joursem, bon l'excuse ( facile) je n'avais pas testé, pour ne pas faire comme JC (he he)

 

[JCGL]

Re : problème avec calendrier

Bonjour à tous,

Pas sur d'avoir tout compris....

=SI(JOURSEM(A2+1;2)=6;A2+3;SI(JOURSEM(A2+1;2)=7;A2+2;A2+1))

A+ à tous

Edition : Si je n'ai pas compris... Nous sommes deux... Salut Bruno 🙂

 

[ROGER2327]

Re : problème avec calendrier

Bonjour à tous...

Soit une date j donnée en A2.

1. Pour j + 1 ouvré :

   [COLOR="DarkSlateGray"]=A2+CHOISIR(JOURSEM(A2;2);1;1;1;1;3;2;1)[/COLOR]

   ou

   [COLOR="DarkSlateGray"]=A2+MAX(1;4-JOURSEM(A2+3;2))[/COLOR]

2. Pour j + 5 ouvré :

   [COLOR="DarkSlateGray"]=A2+CHOISIR(JOURSEM(A2;2);7;6;5;5;5;5;5)[/COLOR]

   ou

   [COLOR="DarkSlateGray"]=A2+MAX(5;8-JOURSEM(A2;2))[/COLOR]

3. Pour j + k ouvré :

   [COLOR="DarkSlateGray"]=A2+MAX([I]k[/I];3+[I]k[/I]-JOURSEM(A2+MOD(2+[I]k[/I];7);2))[/COLOR]

   (les deux exemples précédents sont obtenus avec respectivement k = 1 et k = 5)
   ou simplement, puisque JOURSEM() est périodique de période 7 :

   [COLOR="DarkSlateGray"]=A2+MAX([I]k[/I];3+[I]k[/I]-JOURSEM(A2+2+[I]k[/I];2))[/COLOR]

 

[Cousinhub]

Re : problème avec calendrier

Bonsoir, tout le monde,

Si j'ai bien compris????

=SERIE.JOUR.OUVRE(A2;1)

Peut-être???

Avec de plus la possibilité d'y intégrer les jours fériés (regarde dans l'aide sur cette fonction...)

Bonne soirée

 

[ROGER2327]

Re : problème avec calendrier

Re...

Bonjour bhbh

Bonsoir, tout le monde,

Si j'ai bien compris????

=SERIE.JOUR.OUVRE(A2;[COLOR="Red"][B]1[/B][/COLOR])

Peut-être???

Avec de plus la possibilité d'y intégrer les jours fériés (regarde dans l'aide sur cette fonction...)

Bonne soirée

Cette formule donne le même résultat que celle que je propose avec k=1.
Mais je doute que ce soit ce que cherche schmittfrançois : essayez, par exemple,

=SERIE.JOUR.OUVRE(A2;[COLOR="Red"][B]5[/B][/COLOR])

avec A2=40081 (i.e. 25/9/2009).
Je crois que notre ami aimerait dans ce cas obtenir 40086 (i.e. 30/9/2009).
Mais j'ai peut-être mal lu ou rien compris...​

ROGER2327

 

[Cousinhub]

Re : problème avec calendrier

Re-,

Roger, effectivement, 5 jours, c'est 5 jours....

Maintenant, en toute rigueur, c'est 5 jours pour tout le monde, donc 5 jours ouvrés...

M'enfin, normalement....

A lui de choisir...

Kanakement vôtre.....😀

 

[hoerwind]

Re : problème avec calendrier

Bonjour et bienvenu sur le forum, salut les autres (trop nombreux !)

La première solution qui me venait à l'esprit était celle de bhbh, mais peut-être que la lecture de la question par Roger est la bonne.

Si c'est la cas, une petite formule qui devrait y répondre :
=A2+1+(JOURSEM(A2+1;2)>5)*(8-JOURSEM(A2+1;2))
=A2+5+(JOURSEM(A2+5;2)>5)*(8-JOURSEM(A2+5;2))