Pb code VBA - Transfert de données vers une autre feuille

Private Sub CommandButtonTransfert1_Click() 'Transfert des données
Dim F As Worksheet
Set F = Sheets("ACTIONS CORRECTIVES")
Application.ScreenUpdating = False
F.Rows("14:" & F.Rows.Count).Delete 'RAZ
F.Columns("H").Insert
With [A13].CurrentRegion
    .AutoFilter 8, "OUI" 'filtre automatique
    .Copy F.[A13]
    .AutoFilter
End With
F.Columns("H").Delete
With F.[A13].CurrentRegion
    .Value = .Value 'supprime les formules au cas (peu probable) où il y en a
    .Borders.Weight = xlThin 'bordures
    With .Columns(16).Validation
        .Delete
        .Add xlValidateList, Formula1:="0,1,2,3,4" 'liste de validation pour Statut
    End With
    .Cells(1, 16).Validation.Delete 'supprimée sur P13
End With
F.Activate 'facultatif
End Sub

Private Sub CommandButtonTransfert2_Click() 'Transfert des nouvelles cotations
Dim F As Worksheet, i&, lig As Variant
Set F = Sheets("SAISIE DES DONNEES")
Application.ScreenUpdating = False
With [A13].CurrentRegion
    For i = .Rows.Count To 2 Step -1
        If .Cells(i, 16) = 4 Then 'Statut
            lig = Application.Match(.Cells(i, 1), F.Columns(1), 0)
            If IsNumeric(lig) Then
                F.Cells(lig, 1).Resize(, 4) = .Cells(i, 1).Resize(, 4).Value
                F.Cells(lig, 6).Resize(, 2) = .Cells(i, 5).Resize(, 2).Value
                F.Cells(lig, 8).Resize(, 2) = .Cells(i, 12).Resize(, 2).Value 'Sev, Occ
                F.Cells(lig, 12) = .Cells(i, 14) 'Det
                .Rows(i).Delete xlUp 'supprime la ligne
            End If
        End If
    Next
End With
End Sub